la_module

    function a_AvrLat_ya(ya_data)
      !
      ! 2 次元緯度鉛直格子点データの緯度(Y)方向平均.
      !
      ! 実際には格子点データ各点毎に y_Y_Weight をかけた総和を計算し, 
      ! y_Y_Weight の総和で割ることで平均している. 
      !
      real(8), intent(in) :: ya_data(:,:)
      !(in)  緯度鉛直格子点データ(1:jm,:)

      real(8)             :: a_AvrLat_ya(size(ya_data,2))
      !(out) 平均値

      a_AvrLat_ya = a_IntLat_ya(ya_data)/sum(y_Lat_weight)

    end function a_AvrLat_ya

    function a_IntLat_ya(ya_data)
      !
      ! 2 次元緯度鉛直格子点データの緯度方向積分.
      !
      ! 実際には格子点データ各点毎に y_Y_Weight をかけた総和を計算している. 
      !
      real(8), intent(in) :: ya_data(:,:)
      !(in)  緯度鉛直格子点データ(1:jm,:)

      real(8)             :: a_IntLat_ya(size(ya_data,2))
      !(out) 積分値
      
      integer :: k

      do k=1,size(ya_data,2)
         a_IntLat_ya(k) = sum(ya_data(:,k) * y_Lat_weight)
      end do

    end function a_IntLat_ya

    function a_Interpolate_la(la_data,alat)
      !
      ! 緯度 alat における関数値を
      ! そのルジャンドル変換係数 la_data から補間計算する
      !
      real(8), intent(IN) :: la_data(:,:)
      ! スペクトルデータ(0:nm,:)

      real(8), intent(IN) :: alat
      ! 補間する位置(緯度)

      real(8)             :: a_Interpolate_la(size(la_data,2))
      ! 補間した値
      
      integer               :: k

      do k=1,size(la_data,2)
         a_Interpolate_la(k) = Interpolate_l(la_data(:,k),alat)
      end do

    end function a_Interpolate_la

    function la_DivLat_ya(ya_data)
      !
      ! 格子点データに発散型緯度微分 1/cosφ・∂(f cosφ)/∂φ を作用させて
      ! スペクトルデータに変換して返す(多層用).. 
      !
      real(8), intent(in)  :: ya_data(:,:)
      !(in) 入力格子点データ(1:jm,:)

      real(8)              :: la_DivLat_ya(0:nm,size(ya_data,2))
      !(out) 格子点データを発散型緯度微分したスペクトルデータ

      integer              :: k

      do k=1,size(ya_data,2)
         la_DivLat_ya(:,k) = l_DivLat_y(ya_data(:,k))
      end do

    end function la_DivLat_ya

    function la_DivMu_ya(ya_data)
      !
      ! 格子点データに発散型緯度微分 ∂/∂μ (μ=sinφ)を作用させて
      ! スペクトルデータに変換して返す(多層用).
      !
      real(8), intent(in)  :: ya_data(:,:)
      !(in) 入力格子点データ(1:jm,:)

      real(8)              :: la_DivMu_ya(0:nm,size(ya_data,2))
      !(out) 格子点データを発散型緯度微分したスペクトルデータ

      integer              :: k

      do k=1,size(ya_data,2)
         la_DivMu_ya(:,k) = l_DivMu_y(ya_data(:,k))
      end do

    end function la_DivMu_ya

    function la_LaplaInv_la(la_data)
      !
      ! 入力スペクトルデータに逆ラプラシアン
      !
      !    ▽^{-2}
      !      =[1/cosφ・∂/∂φ(cosφ∂/∂φ)]^{-1}
      !
      ! を作用する(多層用). 
      !
      ! スペクトルデータの逆ラプラシアンとは, 対応する格子点データに
      ! 逆ラプラシアンを作用させたデータのスペクトル変換のことである. 
      !
      real(8), intent(in)  :: la_data(:,:)
      !(in) 入力スペクトルデータ(0:nm,:)

      real(8)              :: la_LaplaInv_la(0:nm,size(la_data,2))
      !(out) スペクトルデータの逆ラプラシアン

      integer               :: k

      do k=1,size(la_data,2)
         la_LaplaInv_la(:,k) = l_LaplaInv_l(la_data(:,k))
      end do
    end function la_LaplaInv_la

    function la_Lapla_la(la_data)
      !
      ! 入力スペクトルデータにラプラシアン
      !
      !    ▽^2 = 1/cosφ・∂/∂φ(cosφ∂/∂φ)
      !
      ! を作用する(多層用). 
      !
      ! スペクトルデータのラプラシアンとは, 対応する格子点データに
      ! ラプラシアンを作用させたデータのスペクトル変換のことである. 
      !
      real(8), intent(in)  :: la_data(:,:)
      !(in) 入力スペクトルデータ(0:nm,:)

      real(8)              :: la_Lapla_la(0:nm,size(la_data,2))
      !(out) 入力スペクトルデータのラプラシアン

      integer               :: k

      do k=1,size(la_data,2)
         la_Lapla_la(:,k) = l_Lapla_l(la_data(:,k))
      end do
      
    end function la_Lapla_la

    subroutine la_initial(n_in,j_in,l_init)
      !
      ! スペクトル変換の格子点数, 波数を設定する.
      !
      ! 他の関数を呼ぶ前に, 最初にこのサブルーチンを呼んで初期設定を
      ! しなければならない. 
      !
      integer,intent(in) :: j_in              !(in) 格子点数(南北)
      integer,intent(in) :: n_in              !(in) 切断波数の設定
      logical,intent(in),optional :: l_init   !(in) l_initial の call スイッチ

      if ( .not. present(l_init) ) then
         call l_Initial(n_in,j_in)
      else if ( l_init ) then
         call l_Initial(n_in,j_in)
      endif

      jm = j_in 
       nm = n_in

      call MessageNotify( 'M','la_initial','la_module (2013/02/24) is initialized')

    end subroutine la_initial

    function la_ya(ya_data)
      !
      ! 格子データからスペクトルデータへ変換する(多層用).
      !
      real(8), intent(in)   :: ya_data(:,:)
      !(in) スペクトルデータ(1:jm,:)

      real(8)               :: la_ya(0:nm,size(ya_data,2))
      !(out) 格子点データ

      integer               :: k

      do k=1,size(ya_data,2)
         la_ya(:,k) = l_y(ya_data(:,k))
      end do

    end function la_ya

    function ya_GradLat_la(la_data)
      !
      ! スペクトルデータに勾配型緯度微分 ∂/∂φ を作用させて
      ! 格子点データに変換して返す(多層用).
      !
      real(8), intent(in)  :: la_data(:,:)
      !(in) 入力スペクトルデータ(0:nm,:)

      real(8)              :: ya_GradLat_la(1:jm,size(la_data,2))
      !(out) スペクトルデータを勾配型緯度微分した格子点データ

      integer               :: k

      do k=1,size(la_data,2)
         ya_GradLat_la(:,k) = y_GradLat_l(la_data(:,k))
      end do

    end function ya_GradLat_la

    function ya_GradMu_la(la_data)
      !
      ! スペクトルデータに勾配型緯度微分 (1-μ^2)∂/∂μ  (μ=sinφ)
      ! を作用させて格子点データに変換して返す(多層用).. 
      !
      real(8), intent(in)  :: la_data(:,:)
      !(in) 入力スペクトルデータ(0:nm,:)

      real(8)              :: ya_GradMu_la(1:jm,size(la_data,2))
      !(out) スペクトルデータを勾配型緯度微分した格子点データ

      integer              :: k

      do k=1,size(la_data,2)
         ya_GradMu_la(:,k) = y_GradMu_l(la_data(:,k))
      end do

    end function ya_GradMu_la

    function ya_la(la_data)
      !
      ! スペクトルデータから格子データへ変換する(多層用).
      !
      real(8), intent(in)   :: la_data(:,:)
      !(in) スペクトルデータ(0:nm,:)

      real(8)               :: ya_la(1:jm,size(la_data,2))
      !(out) 格子点データ

      integer               :: k

      do k=1,size(la_data,2)
         ya_la(:,k) = y_l(la_data(:,k))
      end do

    end function ya_la