gdncvarcreated.f90

Go to the documentation of this file.

!
!= netCDF ファイルへ次元変数作成
!
! Authors::   Eizi TOYODA, Yasuhiro MORIKAWA
! Version::   $Id: gdncvarcreated.f90,v 1.3 2009-10-11 07:36:34 morikawa Exp $
! Tag Name::  $Name:  $
! Copyright:: Copyright (C) GFD Dennou Club, 2000-2005. All rights reserved.
! License::   See COPYRIGHT[link:../../COPYRIGHT]
!
! 以下のサブルーチン、関数は gtdata_netcdf_generic から gtdata_netcdf_generic#Create
! として提供されます。

subroutine gdncvarcreated(var, url, xtype, length, overwrite, err)
  !
  !== 次元変数作成
  !
  ! 変数 URL *url* に次元変数を作成します.
  ! 次元変数の長さを *length* に与えます.
  ! 返される引数 *var* には変数 ID などの情報が格納されます.
  !
  ! *overwrite* に .true. を設定すると上書き可能なモードになります.
  ! デフォルトは上書き不可です.
  ! *err* を与える場合, 次元変数生成時にエラーが生じても
  ! プログラムを終了せず, *err* に .false. が返ります.
  !
  use gtdata_netcdf_types, only: gd_nc_variable, gd_nc_variable_search
  use gtdata_netcdf_internal, only: vtable_add
  use dc_string, only: strieq
  use dc_types, only: string
  use dc_url, only: urlsplit
  use dc_trace, only: beginsub, endsub, dbgmessage
  use netcdf, only: nf90_noerr, nf90_float, nf90_int, nf90_double, nf90_char, &
    & nf90_def_var, nf90_def_dim
  use gtdata_netcdf_file_generic, only: gdncfileopen, gdncfiledefinemode
  use dc_error, only: storeerror, gt_enomem
  implicit none
  type(gd_nc_variable), intent(out):: var
  character(len = *), intent(in):: url
  character(len = *), intent(in):: xtype
  integer, intent(in):: length
  logical, intent(in), optional:: overwrite
  logical, intent(out), optional:: err
  type(gd_nc_variable_search):: ent
  character(len = string):: filename, varname, cause_c
  integer:: stat
  integer:: nc_xtype
  character(len = *), parameter:: subname = "GDNcVarCreateD"
continue
  call beginsub(subname, 'url=<%c>, xtype=<%c>, length=<%d>', &
    & c1=trim(url), c2=trim(xtype), i=(/length/))
  cause_c = trim(url)
  !
  ! --- ファイルを用意 ---
  call urlsplit(url, file=filename, var=varname)
  call gdncfileopen(ent%fileid, filename, stat=stat, writable=.true., &
    & overwrite=overwrite)
  if (stat /= nf90_noerr) goto 999
  stat = gdncfiledefinemode(ent%fileid)
  if (stat /= nf90_noerr) goto 999
  !
  ! --- 型の決定 ---
  nc_xtype = nf90_float
  if (strieq(xtype, "double") .or. strieq(xtype, "DOUBLEPRECISION")) then
    nc_xtype = nf90_double
  endif
  if (strieq(xtype, "int") .or. strieq(xtype, "INTEGER")) then
    nc_xtype = nf90_int
  endif
  if (strieq(xtype, "char") .or. strieq(xtype, "CHARACTER")) then
    nc_xtype = nf90_char
  endif
  !
  ! --- 次元変数の作成 ---
  stat = nf90_def_dim(ent%fileid, trim(varname), len=length, dimid=ent%dimid)
  if (stat /= nf90_noerr) goto 999
  stat = nf90_def_var(ent%fileid, trim(varname), &
    & xtype=nc_xtype, dimids=(/ent%dimid/), varid=ent%varid)
  if (stat /= nf90_noerr) goto 999
  !
  stat = vtable_add(var, ent)
  if (stat /= nf90_noerr) goto 999

999 continue
  call storeerror(stat, subname, err, cause_c=cause_c)
  if (stat /= nf90_noerr) var = gd_nc_variable(-1)
  call endsub(subname, 'stat=%d', i=(/stat/))
end subroutine gdncvarcreated