dc_url::urlsplit Interface Reference

Private Member Functions
subroutine	url_split_c (fullname, file, var, attr, iorange)

Detailed Description

Definition at line 60 of file dc_url.f90.

Member Function/Subroutine Documentation

url_split_c()

subroutine dc_url::urlsplit::url_split_c ( character(len = *), intent(in)  fullname, character(len = *), intent(out), optional  file, character(len = *), intent(out), optional  var, character(len = *), intent(out), optional  attr, character(len = *), intent(out), optional  iorange  )

private

Definition at line 254 of file dc_url.f90.

    !
    ! fullname で与えられる変数 URL を、ファイル名 file、 変数名 var、
    ! 属性名 attr、入出力範囲指定 iorange に分解して返します。
    ! 見つからない成分には空文字列が代入されます。
    !
    use dc_types, only: string
    character(len = *), intent(in):: fullname
    character(len = *), intent(out), optional:: file, var, attr, iorange
    character(len = STRING):: varpart
    integer:: atmark, colon, comma
    character(len = *), parameter:: varname_set &
      = "0123456789eEdD+-=^,.:_" &
      // "ABCDEFGHIJKLMNOPQRSTUVWXYZ" &
      // "abcdefghijklmnopqrstuvwxyz"
  continue
    ! まず URL と変数属性指定 (? または @ 以降) を分離する。
    ! URL は @ を含みうるため、最後の @ 以降に対して変数属性
    ! として許されない文字（典型的には '/'）が含まれていたら
    ! 当該 @ は URL の一部とみなす。
    atmark = index(fullname, gt_question)
    if (atmark == 0) then
      atmark = index(fullname, gt_atmark, back=.true.)
      if (atmark /= 0) then
        if (verify(trim(fullname(atmark+1: )), varname_set) /= 0) then
          atmark = 0
        endif
      endif
    endif
    if (atmark == 0) then
      ! 変数属性指定はなかった。
      if (present(file)) file = fullname
      if (present(var)) var = ''
      if (present(attr)) attr = ''
      if (present(iorange)) iorange = ''
      return
    endif
    varpart = fullname(atmark+1: )
    ! 変数属性指定があった。
    if (present(file)) file = fullname(1: atmark - 1)
    ! 範囲指定を探索する。
    comma = index(varpart, gt_comma)
    if (comma /= 0) then
      ! 範囲指定がみつかった。
      if (present(var)) var = varpart(1: comma - 1)
      if (present(attr)) attr = ''
      if (present(iorange)) iorange = varpart(comma + 1: )
      return
    endif
    if (present(iorange)) iorange = ''
    ! 範囲指定がなかったので、属性名の検索をする。
    colon = index(varpart, gt_colon)
    if (colon == 0) then
      if (present(var)) var = varpart
      if (present(attr)) attr = ''
      varpart = ''
      return
    endif
    if (present(var)) var = varpart(1: colon - 1)
    if (present(attr)) attr = varpart(colon + 1: )
    varpart = ''

---

The documentation for this interface was generated from the following file:

• dc_utils/dc_url.f90