物理過程のみの計算のための力学過程

A dynamics for calculation with physical processes only

Note that Japanese and English are described in parallel.

Procedures List

NAMELIST

Methods

DynamicsPhysicsOnly DynamicsPhysicsOnlyInit UGeo VGeo WHeight WMagnitude WTimeInit dynamics_physicsonly_inited module_name version xyz_CorPar

Included Modules

gridset composition dc_types dc_message timeset dc_trace constants axesset namelist_util dc_iounit

Public Instance methods

DynamicsPhysicsOnly( xyz_Exner, xy_SurfHeight, xyz_Height, xyz_DUDtPhy, xyz_DVDtPhy, xyz_DTempDtPhy, xyzf_DQMixDtPhy, xy_PsB, xyz_UB, xyz_VB, xyz_TempB, xyzf_QMixB, xy_PsN, xyz_UN, xyz_VN, xyz_TempN, xyzf_QMixN, xy_PsA, xyz_UA, xyz_VA, xyz_TempA, xyzf_QMixA )

Subroutine :

xyz_Exner(0:imax-1, 1:jmax, 1:kmax) : real(DP), intent(in)

xy_SurfHeight(0:imax-1, 1:jmax) : real(DP), intent(in)

xyz_Height(0:imax-1, 1:jmax, 1:kmax) : real(DP), intent(in)

xyz_DUDtPhy(0:imax-1, 1:jmax, 1:kmax) :

real(DP), intent(in)

:	$ left(DP{u}{t}right)^{phy} $ . 外力項 (物理過程) による東西風速変化. Eastward wind tendency by external force terms (physical processes)

xyz_DVDtPhy(0:imax-1, 1:jmax, 1:kmax) :

real(DP), intent(in)

:	$ left(DP{v}{t}right)^{phy} $ . 外力項 (物理過程) による南北風速変化. Northward wind tendency by external force terms (physicalprocesses)

xyz_DTempDtPhy(0:imax-1, 1:jmax, 1:kmax) :

real(DP), intent(in)

:	$ left(DP{T}{t}right)^{phy} $ . 外力項 (物理過程) による温度変化. Temperature tendency by external force terms (physical processes)

xyzf_DQMixDtPhy(0:imax-1, 1:jmax, 1:kmax, 1:ncmax) :

real(DP), intent(in)

:	$ left(DP{q}{t}right)^{phy} $ . 外力項 (物理過程) による比湿変化. Temperature tendency by external force terms (physical processes)

xy_PsB(0:imax-1, 1:jmax) :

real(DP), intent(in )

:	$ p_s $ . 地表面気圧 (半整数レベル). Surface pressure (half level)

xyz_UB(0:imax-1, 1:jmax, 1:kmax) :

real(DP), intent(in )

:	$ u $ . 東西風速. Eastward wind

xyz_VB(0:imax-1, 1:jmax, 1:kmax) :

real(DP), intent(in )

:	$ v $ . 南北風速. Northward wind

xyz_TempB(0:imax-1, 1:jmax, 1:kmax) :

real(DP), intent(in )

:	$ T $ . 温度 (整数レベル). Temperature (full level)

xyzf_QMixB(0:imax-1, 1:jmax, 1:kmax, 1:ncmax) :

real(DP), intent(in )

:	$ q $ . 比湿. Specific humidity

xy_PsN(0:imax-1, 1:jmax) :

real(DP), intent(in)

:	$ p_s (t) $ . 地表面気圧. Surface pressure

xyz_UN(0:imax-1, 1:jmax, 1:kmax) :

real(DP), intent(in)

:	$ u (t) $ . 東西風速. Eastward wind

xyz_VN(0:imax-1, 1:jmax, 1:kmax) :

real(DP), intent(in)

:	$ v (t) $ . 南北風速. Northward wind

xyz_TempN(0:imax-1, 1:jmax, 1:kmax) :

real(DP), intent(in)

:	$ T (t) $ . 温度. Temperature

xyzf_QMixN(0:imax-1, 1:jmax, 1:kmax, 1:ncmax) :

real(DP), intent(in)

:	$ q (t) $ . 比湿. Specific humidity

xy_PsA(0:imax-1, 1:jmax) :

real(DP), intent(out)

:	$ p_s $ . 地表面気圧 (半整数レベル). Surface pressure (half level)

xyz_UA(0:imax-1, 1:jmax, 1:kmax) :

real(DP), intent(out)

:	$ u $ . 東西風速. Eastward wind

xyz_VA(0:imax-1, 1:jmax, 1:kmax) :

real(DP), intent(out)

:	$ v $ . 南北風速. Northward wind

xyz_TempA(0:imax-1, 1:jmax, 1:kmax) :

real(DP), intent(out)

:	$ T $ . 温度 (整数レベル). Temperature (full level)

xyzf_QMixA(0:imax-1, 1:jmax, 1:kmax, 1:ncmax) :

real(DP), intent(out)

:	$ q $ . 比湿. Specific humidity

[Source]

  subroutine DynamicsPhysicsOnly( xyz_Exner, xy_SurfHeight, xyz_Height, xyz_DUDtPhy, xyz_DVDtPhy, xyz_DTempDtPhy, xyzf_DQMixDtPhy, xy_PsB, xyz_UB, xyz_VB, xyz_TempB, xyzf_QMixB, xy_PsN, xyz_UN, xyz_VN, xyz_TempN, xyzf_QMixN, xy_PsA, xyz_UA, xyz_VA, xyz_TempA, xyzf_QMixA )

    ! モジュール引用 ; USE statements
    !

    ! 時刻管理
    ! Time control
    !
    use timeset, only: DelTime, TimeN, TimesetClockStart, TimesetClockStop

    ! デバッグ用ユーティリティ
    ! Utilities for debug
    !
    use dc_trace, only: DbgMessage, BeginSub, EndSub

    ! 組成に関わる配列の設定
    ! Settings of array for atmospheric composition
    !
    use composition, only: ncmax, CompositionInqFlagAdv

!!$    ! 質量の補正
!!$    ! Mass fixer
!!$    !
!!$    use mass_fixer, only: MassFixerColumn


    ! 宣言文 ; Declaration statements
    !

    real(DP), intent(in):: xyz_Exner      (0:imax-1, 1:jmax, 1:kmax)
    real(DP), intent(in):: xy_SurfHeight  (0:imax-1, 1:jmax)
    real(DP), intent(in):: xyz_Height     (0:imax-1, 1:jmax, 1:kmax)

    real(DP), intent(in):: xyz_DUDtPhy    (0:imax-1, 1:jmax, 1:kmax)
                              ! $ \left(\DP{u}{t}\right)^{phy} $ .
                              ! 外力項 (物理過程) による東西風速変化.
                              ! Eastward wind tendency by external force terms (physical processes)
    real(DP), intent(in):: xyz_DVDtPhy    (0:imax-1, 1:jmax, 1:kmax)
                              ! $ \left(\DP{v}{t}\right)^{phy} $ .
                              ! 外力項 (物理過程) による南北風速変化.
                              ! Northward wind tendency by external force terms (physicalprocesses)
    real(DP), intent(in):: xyz_DTempDtPhy (0:imax-1, 1:jmax, 1:kmax)
                              ! $ \left(\DP{T}{t}\right)^{phy} $ .
                              ! 外力項 (物理過程) による温度変化.
                              ! Temperature tendency by external force terms (physical processes)
    real(DP), intent(in):: xyzf_DQMixDtPhy (0:imax-1, 1:jmax, 1:kmax, 1:ncmax)
                              ! $ \left(\DP{q}{t}\right)^{phy} $ .
                              ! 外力項 (物理過程) による比湿変化.
                              ! Temperature tendency by external force terms (physical processes)
    real(DP), intent(in ):: xy_PsB(0:imax-1, 1:jmax)
                              ! $ p_s $ . 地表面気圧 (半整数レベル). 
                              ! Surface pressure (half level)
    real(DP), intent(in ):: xyz_UB(0:imax-1, 1:jmax, 1:kmax)
                              ! $ u $ . 東西風速. Eastward wind
    real(DP), intent(in ):: xyz_VB(0:imax-1, 1:jmax, 1:kmax)
                              ! $ v $ . 南北風速. Northward wind
    real(DP), intent(in ):: xyz_TempB(0:imax-1, 1:jmax, 1:kmax)
                              ! $ T $ . 温度 (整数レベル). 
                              ! Temperature (full level)
    real(DP), intent(in ):: xyzf_QMixB(0:imax-1, 1:jmax, 1:kmax, 1:ncmax)
                              ! $ q $ .     比湿. Specific humidity
    real(DP), intent(in):: xy_PsN    (0:imax-1, 1:jmax)
                              ! $ p_s (t) $ .   地表面気圧. Surface pressure
    real(DP), intent(in):: xyz_UN   (0:imax-1, 1:jmax, 1:kmax)
                              ! $ u (t) $ .     東西風速. Eastward wind
    real(DP), intent(in):: xyz_VN   (0:imax-1, 1:jmax, 1:kmax)
                              ! $ v (t) $ .     南北風速. Northward wind
    real(DP), intent(in):: xyz_TempN (0:imax-1, 1:jmax, 1:kmax)
                              ! $ T (t) $ .     温度. Temperature
    real(DP), intent(in):: xyzf_QMixN(0:imax-1, 1:jmax, 1:kmax, 1:ncmax)
                              ! $ q (t) $ .     比湿. Specific humidity
    real(DP), intent(out):: xy_PsA(0:imax-1, 1:jmax)
                              ! $ p_s $ . 地表面気圧 (半整数レベル). 
                              ! Surface pressure (half level)
    real(DP), intent(out):: xyz_UA(0:imax-1, 1:jmax, 1:kmax)
                              ! $ u $ . 東西風速. Eastward wind
    real(DP), intent(out):: xyz_VA(0:imax-1, 1:jmax, 1:kmax)
                              ! $ v $ . 南北風速. Northward wind
    real(DP), intent(out):: xyz_TempA(0:imax-1, 1:jmax, 1:kmax)
                              ! $ T $ . 温度 (整数レベル). 
                              ! Temperature (full level)
    real(DP), intent(out):: xyzf_QMixA(0:imax-1, 1:jmax, 1:kmax, 1:ncmax)
                              ! $ q $ .     比湿. Specific humidity


    ! 作業変数
    ! Work variables
    !
    real(DP) :: xyz_PotTempB     (0:imax-1, 1:jmax, 1:kmax)

    real(DP) :: xyz_W            (0:imax-1, 1:jmax, 1:kmax)

    real(DP) :: xyz_DUDtAdv      (0:imax-1, 1:jmax, 1:kmax)
    real(DP) :: xyz_DVDtAdv      (0:imax-1, 1:jmax, 1:kmax)
    real(DP) :: xyz_DPotTempDtAdv(0:imax-1, 1:jmax, 1:kmax)
    real(DP) :: xyzf_DQMixDtAdv  (0:imax-1, 1:jmax, 1:kmax, 1:ncmax)

    real(DP) :: xyz_UT           (0:imax-1, 1:jmax, 1:kmax)
    real(DP) :: xyz_VT           (0:imax-1, 1:jmax, 1:kmax)

    integer :: kp
    integer :: kn

    integer:: i               ! 経度方向に回る DO ループ用作業変数
                              ! Work variables for DO loop in longitude
    integer:: j               ! 緯度方向に回る DO ループ用作業変数
                              ! Work variables for DO loop in latitude
    integer:: k
    integer:: n

    ! 実行文 ; Executable statement
    !

    ! 初期化確認
    ! Initialization check
    !
    if ( .not. dynamics_physicsonly_inited ) then
      call MessageNotify( 'E', module_name, 'This module has not been initialized.' )
    end if


    ! 計算時間計測開始
    ! Start measurement of computation time
    !
    call TimesetClockStart( module_name )


    xyz_PotTempB = xyz_TempB / xyz_Exner

    if ( TimeN >= WTimeInit ) then
      if ( WHeight > 0.0_DP ) then
        do k = 1, kmax
          xyz_W(:,:,k) = WMagnitude * min( xyz_Height(:,:,k) - xy_SurfHeight, WHeight ) / WHeight
        end do
      else
        xyz_W = 0.0_DP
      end if
    else
      xyz_W = 0.0_DP
    end if

    do k = 1, kmax

      do j = 1, jmax
        do i = 0, imax-1

!!$          kp = max( k - 1, 1    )
!!$          kn = min( k + 1, kmax )
          if ( xyz_W(i,j,k) >= 0.0_DP ) then
            kp = max( k - 1, 1    )
            kn = kp + 1
          else
            kn = min( k + 1, kmax )
            kp = kn - 1
          end if
          xyz_DUDtAdv(i,j,k) = - xyz_W(i,j,k) * ( xyz_UB    (i,j,kn) - xyz_UB    (i,j,kp) ) / ( xyz_Height(i,j,kn) - xyz_Height(i,j,kp) )
          xyz_DVDtAdv(i,j,k) = - xyz_W(i,j,k) * ( xyz_VB    (i,j,kn) - xyz_VB    (i,j,kp) ) / ( xyz_Height(i,j,kn) - xyz_Height(i,j,kp) )
          xyz_DPotTempDtAdv(i,j,k) = - xyz_W(i,j,k) * ( xyz_PotTempB(i,j,kn) - xyz_PotTempB(i,j,kp) ) / ( xyz_Height  (i,j,kn) - xyz_Height  (i,j,kp) )
          do n = 1, ncmax
            if ( CompositionInqFlagAdv( n ) ) then
              xyzf_DQMixDtAdv(i,j,k,n) = - xyz_W(i,j,k) * ( xyzf_QMixB(i,j,kn,n) - xyzf_QMixB(i,j,kp,n) ) / ( xyz_Height(i,j,kn)   - xyz_Height(i,j,kp)   )
            else
              xyzf_DQMixDtAdv(i,j,k,n) = 0.0_DP
            end if
          end do

        end do
      end do

    end do


    xy_PsA = xy_PsB


    xyz_UT = xyz_UB + ( xyz_DUDtAdv + xyz_DUDtPhy ) * 2.0d0 * DelTime
    xyz_VT = xyz_VB + ( xyz_DVDtAdv + xyz_DVDtPhy ) * 2.0d0 * DelTime
    xyz_UA = (   xyz_UT + 2.0_DP * DelTime * xyz_CorPar * ( xyz_VT - VGeo + 2.0_DP * DelTime * xyz_CorPar * UGeo ) ) / ( 1.0_DP + ( 2.0_DP * DelTime * xyz_CorPar )**2 )
    xyz_VA = (   xyz_VT - 2.0_DP * DelTime * xyz_CorPar * ( xyz_UT - UGeo - 2.0_DP * DelTime * xyz_CorPar * VGeo ) ) / ( 1.0_DP + ( 2.0_DP * DelTime * xyz_CorPar )**2 )


!!$    xyz_TempA  = xyz_TempB  + xyz_DTempDtPhy  * 2.0d0 * DelTime
    xyz_TempA = xyz_PotTempB + ( xyz_DPotTempDtAdv + xyz_DTempDtPhy / xyz_Exner ) * 2.0d0 * DelTime
    xyz_TempA = xyz_TempA * xyz_Exner

    xyzf_QMixA = xyzf_QMixB + ( xyzf_DQMixDtAdv + xyzf_DQMixDtPhy ) * 2.0d0 * DelTime
    xyzf_QMixA = max( xyzf_QMixA, 0.0_DP )


  end subroutine DynamicsPhysicsOnly

DynamicsPhysicsOnlyInit( )

Subroutine :

This procedure input/output NAMELIST#dynamics_physicsonly_nml .

[Source]

  subroutine DynamicsPhysicsOnlyInit

    ! モジュール引用 ; USE statements
    !

    ! 物理定数設定
    ! Physical constants settings
    !
    use constants, only: Omega
                              ! $ \Omega $ [s-1].
                              ! 回転角速度.
                              ! Angular velocity

    ! 座標データ設定
    ! Axes data settings
    !
    use axesset, only : y_Lat

    ! NAMELIST ファイル入力に関するユーティリティ
    ! Utilities for NAMELIST file input
    !
    use namelist_util, only: namelist_filename, NmlutilMsg, NmlutilAryValid

    ! ファイル入出力補助
    ! File I/O support
    !
    use dc_iounit, only: FileOpen


    ! 宣言文 ; Declaration statements
    !

    integer:: unit_nml        ! NAMELIST ファイルオープン用装置番号. 
                              ! Unit number for NAMELIST file open
    integer:: iostat_nml      ! NAMELIST 読み込み時の IOSTAT. 
                              ! IOSTAT of NAMELIST read

!!$    integer:: i               ! 経度方向に回る DO ループ用作業変数
!!$                              ! Work variables for DO loop in longitude
    integer:: j               ! 緯度方向に回る DO ループ用作業変数
                              ! Work variables for DO loop in latitude
    integer:: k


    ! NAMELIST 変数群
    ! NAMELIST group name
    !
    namelist /dynamics_physicsonly_nml/ UGeo, VGeo, WMagnitude, WHeight, WTimeInit
          !
          ! デフォルト値については初期化手続 "surface_flux_bulk#SurfFluxInit" 
          ! のソースコードを参照のこと. 
          !
          ! Refer to source codes in the initialization procedure
          ! "surface_flux_bulk#SurfFluxInit" for the default values. 
          !

    ! 実行文 ; Executable statement
    !


    if ( dynamics_physicsonly_inited ) return


    ! デフォルト値の設定
    ! Default values settings
    !
    UGeo = 0.0_DP
    VGeo = 0.0_DP

    WMagnitude = 0.0_DP
    WHeight    = 0.0_DP
!!$    WMagnitude = - 0.005_DP
!!$    WHeight    =   1000.0_DP
    WTimeInit  = 0.0_DP

    ! NAMELIST の読み込み
    ! NAMELIST is input
    !
    if ( trim(namelist_filename) /= '' ) then
      call FileOpen( unit_nml, namelist_filename, mode = 'r' ) ! (in)

      rewind( unit_nml )
      read( unit_nml, nml = dynamics_physicsonly_nml, iostat = iostat_nml )              ! (out)
      close( unit_nml )

      call NmlutilMsg( iostat_nml, module_name ) ! (in)
    end if


    allocate( xyz_CorPar(0:imax-1, 1:jmax, 1:kmax) )

    do k = 1, kmax
      do j = 1, jmax
        xyz_CorPar(:,j,k) = 2.0_DP * Omega * sin( y_Lat(j) )
      end do
    end do

!!$    ! ヒストリデータ出力のためのへの変数登録
!!$    ! Register of variables for history data output
!!$    !
!!$    call HistoryAutoAddVariable( 'TauX', &
!!$      & (/ 'lon ', 'lat ', 'time' /), &
!!$      & 'surface stress(x)  ', 'N m-2' )
!!$
!!$    call HistoryAutoAddVariable( 'TauY', &
!!$      & (/ 'lon ', 'lat ', 'time' /), &
!!$      & 'surface stress(y)  ', 'N m-2' )
!!$
!!$    call HistoryAutoAddVariable( 'Sens', &
!!$      & (/ 'lon ', 'lat ', 'time' /), &
!!$      & 'sensible heat flux', 'W m-2' )
!!$
!!$    call HistoryAutoAddVariable( 'EVap', &
!!$      & (/ 'lon ', 'lat ', 'time' /), &
!!$      & 'latent heat flux  ', 'W m-2' )

    ! 印字 ; Print
    !
    call MessageNotify( 'M', module_name, '----- Initialization Messages -----' )

    call MessageNotify( 'M', module_name, '  UGeo = %f', d = (/ UGeo /) )
    call MessageNotify( 'M', module_name, '  VGeo = %f', d = (/ VGeo /) )
    call MessageNotify( 'M', module_name, '  WMagnitude = %f', d = (/ WMagnitude /) )
    call MessageNotify( 'M', module_name, '  WHeight    = %f', d = (/ WHeight    /) )
    call MessageNotify( 'M', module_name, '  WTimeInit  = %f', d = (/ WTimeInit  /) )
    call MessageNotify( 'M', module_name, '-- version = %c', c1 = trim(version) )

    dynamics_physicsonly_inited = .true.

  end subroutine DynamicsPhysicsOnlyInit

Private Instance methods

UGeo

*Variable* :
`UGeo` :	`real(DP) , save`

VGeo

*Variable* :
`VGeo` :	`real(DP) , save`

WHeight

*Variable* :
`WHeight` :	`real(DP) , save`

WMagnitude

*Variable* :
`WMagnitude` :	`real(DP) , save`

WTimeInit

*Variable* :
`WTimeInit` :	`real(DP) , save`

dynamics_physicsonly_inited

Variable :

dynamics_physicsonly_inited = .false. :

logical, save

:	初期設定フラグ. Initialization flag

module_name

Constant :

module_name = ‘dynamics_physicsonly‘ :

character(*), parameter

:	モジュールの名称. Module name

version

Constant :

version = ’$Name: dcpam5-20140314 $’ // ’$Id: dynamics_physicsonly.f90,v 1.5 2014-02-04 10:23:11 yot Exp $’ :

character(*), parameter

:	モジュールのバージョン Module version

xyz_CorPar

*Variable* :
`xyz_CorPar(:,:,:)` :	`real(DP), allocatable, save`