mod_atmos_component.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!> module Atmosphere component
!!
!! @par Description
!!          Atmosphere component module
!!
!! @author Yuta Kawai, Team SCALE
!!
!<
!-------------------------------------------------------------------------------
#include "scaleFElib.h"
module mod_atmos_component
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  use scale_prof
  use scale_prc
 
  use scale_mesh_base, only: meshbase
  use scale_mesh_base2d, only: meshbase2d
  use scale_mesh_base3d, only: meshbase3d
  use scale_localmesh_2d, only: localmesh2d
  use scale_localmesh_3d, only: localmesh3d
  use scale_localmeshfield_base, only: &
    localmeshfieldbase, localmeshfieldbaselist
  use scale_model_component, only: modelcomponent
  use scale_model_mesh_manager, only: modelmesh3d
 
  use mod_atmos_mesh, only: atmosmesh
  use mod_atmos_mesh_rm, only: atmosmeshrm
  use mod_atmos_mesh_gm, only: atmosmeshgm
 
  use mod_atmos_vars, only: &
    atmosvars, atmosvarscontainer, &
    atm_vars_container_primary_id
 
  use mod_atmos_dyn, only: atmosdyn
  use mod_atmos_phy_sfc, only: atmosphysfc
  use mod_atmos_phy_tb , only: atmosphytb
  use mod_atmos_phy_mp , only: atmosphymp
  use mod_atmos_phy_rd , only: atmosphyrd
  use mod_atmos_phy_cp , only: atmosphycp
  use mod_atmos_phy_bl, only: atmosphybl
  use mod_cpl_component, only: couplercomponent
 
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public type & procedure
  !
 
  !> Derived type to manage atmospheric component
  type, extends(modelcomponent), public :: atmoscomponent
    type(atmosvars) :: vars             !< Object to mange variables with atmospheric component
 
    character(len=H_SHORT) :: mesh_type !< Type name of mesh atmospheric component
    class(atmosmesh), pointer :: mesh   !< Pointer of mesh atmospheric component
    type(atmosmeshrm) :: mesh_rm        !< Object to manage mesh for the case of regional mode
    type(atmosmeshgm) :: mesh_gm        !< Object to manage mesh for the case of global mode
 
    type(atmosdyn) :: dyn_proc          !< Object to manage dynamical process
    type(atmosphysfc) :: phy_sfc_proc   !< Object to manage surface process
    type(atmosphytb ) :: phy_tb_proc    !< Object to manage sub-grid scale turbulence process
    type(atmosphymp ) :: phy_mp_proc    !< Object to manage cloud microphysics process
    type(atmosphyrd ) :: phy_rd_proc    !< Object to manage radiation process
    type(atmosphycp ) :: phy_cp_proc    !< Object to manage cumulus parameterization process
    type(atmosphybl ) :: phy_bl_proc    !< Object to manage PBL turbulence parameterization process
 
    type(couplercomponent), pointer :: coupler_ptr !< Pointer of coupler component
  contains
    procedure, public :: setup => atmos_setup 
    procedure, public :: setup_vars => atmos_setup_vars  
    procedure, public :: set_coupler => atmos_set_coupler  
    procedure, public :: calc_tendency => atmos_calc_tendency
    procedure, public :: calc_tendency_from_sflux => atmos_calc_tendency_from_sflux
    procedure, public :: update => atmos_update
    procedure, public :: set_surface => atmos_set_surface
    procedure, public :: get_surface => atmos_get_surface
    procedure, public :: finalize => atmos_finalize
  end type atmoscomponent
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  !-----------------------------------------------------------------------------
contains
 
  !> Setup an object to mange atmospheric component
!OCL SERIAL
  subroutine atmos_setup( this )
    use scale_const, only: &
      undef8 => const_undef8
    
    use scale_atmos_hydrometeor, only: &
      atmos_hydrometeor_dry,   &
      atmos_hydrometeor_regist    
    use scale_atmos_thermodyn, only: &
      atmos_thermodyn_setup
    use scale_atmos_saturation, only: &
      atmos_saturation_setup
 
    use scale_file_history_meshfield, only: &
      file_history_meshfield_setup  
    use scale_time_manager, only: &
      time_manager_regist_component
 
    implicit none
    
    class(atmoscomponent), intent(inout), target :: this
 
    logical :: ACTIVATE_FLAG = .true. !< Flag whether atmospheric component is activated
 
    real(DP) :: TIME_DT                             = undef8  !< Timestep value of atmospheric component
    character(len=H_SHORT) :: TIME_DT_UNIT          = 'SEC'   !< Timestep unit of atmospheric component
    real(DP) :: TIME_DT_RESTART                     = undef8  !< Timestep value when outputting restart file for atmospheric component
    character(len=H_SHORT) :: TIME_DT_RESTART_UNIT  = 'SEC'   !< Timestep unit when outputting restart file for atmospheric component
 
    logical :: ATMOS_DYN_DO    = .true.  !< Flag whether dynamics process is considered
    logical :: ATMOS_PHY_SF_DO = .false. !< Flag whether surface process is considered
    logical :: ATMOS_PHY_TB_DO = .false. !< Flag whether SGS turbulent process is considered
    logical :: ATMOS_PHY_MP_DO = .false. !< Flag whether cloud microphysics process is considered
    logical :: ATMOS_PHY_RD_DO = .false. !< Flag whether radiation process is considered
    logical :: ATMOS_PHY_CP_DO = .false. !< Flag whether cumulus parameterization process is considered
    logical :: ATMOS_PHY_BL_DO = .false. !< Flag whether PBL turbulence parameterization process is considered
    character(len=H_SHORT) :: ATMOS_MESH_TYPE = 'REGIONAL'  !< Name of mesh type for atmospheric component ('REGIONAL' or 'GLOBAL')
 
    logical :: ATMOS_USE_QV    = .false. !< Flag whether QV is used although cloud microphysics is not considered
 
 
    namelist / param_atmos / &
      activate_flag,         &
      time_dt,               &
      time_dt_unit,          &
      time_dt_restart,       &
      time_dt_restart_unit,  &
      atmos_mesh_type,       &
      atmos_dyn_do,          &
      atmos_phy_sf_do,       &
      atmos_phy_tb_do,       &
      atmos_phy_mp_do,       &    
      atmos_phy_rd_do,       &
      atmos_phy_cp_do,       &
      atmos_phy_bl_do,       &
      atmos_use_qv
    
    integer :: ierr
    !--------------------------------------------------
    call prof_rapstart( 'ATM_setup', 1)
    log_info('AtmosComponent_setup',*) 'Atmosphere model components '
    
    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_atmos,iostat=ierr)
    if( ierr < 0 ) then !--- missing
      log_info("ATMOS_setup",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
      log_error("ATM_setup",*) 'Not appropriate names in namelist PARAM_ATMOS. Check!'
      call prc_abort
    endif
    log_nml(param_atmos)
 
    !************************************************
    call this%ModelComponent_Init('ATMOS', activate_flag )
    if ( .not. activate_flag ) return
 
    !- Setup time manager
 
    call this%time_manager%Init( this%GetComponentName(), &
      time_dt, time_dt_unit,                              &
      time_dt_restart, time_dt_restart_unit               ) 
    
    call time_manager_regist_component( this%time_manager )
    
    !- Setup mesh & file I/O for atmospheric component
 
    this%mesh_type = atmos_mesh_type
    select case( this%mesh_type )
    case('REGIONAL')
      call this%mesh_rm%Init()
      call file_history_meshfield_setup( mesh3d_=this%mesh_rm%mesh )
      this%mesh => this%mesh_rm
    case('GLOBAL')
      call this%mesh_gm%Init()
      call file_history_meshfield_setup( meshcubedsphere3d_=this%mesh_gm%mesh )
      this%mesh => this%mesh_gm
    case default
      log_error("ATM_setup",*) 'Unsupported type of mesh is specified. Check!', this%mesh_type
      call prc_abort    
    end select
    
    !- setup common tools for atmospheric model
 
    call atmos_thermodyn_setup
    call atmos_saturation_setup
 
    !- Setup each processes in atmospheric model ------------------------------------
 
    !- Setup the module for atmosphere / physics / surface
    call this%phy_sfc_proc%ModelComponentProc_Init( 'AtmosPhysSfc', atmos_phy_sf_do )
    call this%phy_sfc_proc%setup( this%mesh, this%time_manager )
    
    !- Setup the module for atmosphere / physics / cloud microphysics
    call this%phy_mp_proc%ModelComponentProc_Init( 'AtmosPhysMp', atmos_phy_mp_do )
    call this%phy_mp_proc%setup( this%mesh, this%time_manager )
 
    !-- Regist qv if needed
    if ( atmos_hydrometeor_dry .and. atmos_use_qv ) then
      log_info("ATMOS_setup",*) "Regist QV"
      call atmos_hydrometeor_regist( 0, 0,                                 & ! (in)
        (/'QV'/),                                                          & ! (in)
        (/'Ratio of Water Vapor mass to total mass (Specific humidity)'/), & ! (in)
        (/'kg/kg'/),                                                       & ! (in)
        this%phy_mp_proc%vars%QS                                           ) ! (out)
      
      this%phy_mp_proc%vars%QA = 1
      this%phy_mp_proc%vars%QE = this%phy_mp_proc%vars%QS    
    end if
 
    !- Setup the module for atmosphere / dynamics 
    call this%dyn_proc%ModelComponentProc_Init( 'AtmosDyn', atmos_dyn_do )
    call this%dyn_proc%setup( this%mesh, this%time_manager )
 
    !- Setup the module for atmosphere / physics / turbulence
    call this%phy_tb_proc%ModelComponentProc_Init( 'AtmosPhysTb', atmos_phy_tb_do )
    call this%phy_tb_proc%setup( this%mesh, this%time_manager )
    call this%phy_tb_proc%SetDynBC( this%dyn_proc%dyncore_driver%boundary_cond )
 
    !- Setup the module for atmosphere / physics / radiation
    call this%phy_rd_proc%ModelComponentProc_Init( 'AtmosPhysRd', atmos_phy_rd_do )
    call this%phy_rd_proc%setup( this%mesh, this%time_manager )
 
    !- Setup the module for atmosphere / physics / cumulus parameterization
    call this%phy_cp_proc%ModelComponentProc_Init( 'AtmosPhysCp', atmos_phy_cp_do )
    call this%phy_cp_proc%setup( this%mesh, this%time_manager )
 
    !- Setup the module for atmosphere / physics / PBL turbulence parameterization
    call this%phy_bl_proc%ModelComponentProc_Init( 'AtmosPhysBl', atmos_phy_bl_do )
    call this%phy_bl_proc%setup( this%mesh, this%time_manager )
    call this%phy_bl_proc%SetDynBC( this%dyn_proc%dyncore_driver%boundary_cond )
 
    !- Setup
 
    log_newline
    log_info('AtmosComponent_setup',*) 'Finish setup of each atmospheric component.'
 
    call prof_rapend( 'ATM_setup', 1)
 
    return
  end subroutine atmos_setup
 
  !> Setup variables with the atmospheric component
!OCL SERIAL
  subroutine atmos_setup_vars( this )
    use mod_atmos_phy_sfc_vars, only: &
      sfctemp_id => atmos_phy_sf_svar_temp_id, &
      sfc_alb_id => atmos_phy_sf_svar_alb_id
    implicit none
    class(atmoscomponent), intent(inout) :: this
    !----------------------------------------------------------
 
    call prof_rapstart( 'ATM_setup_vars', 1)
 
    log_info('AtmosComponent_setup_vars',*) 'Atmosphere model components '
 
    call this%vars%Init( this%mesh )
 
    !- Cloud microphysics component
    if ( this%phy_mp_proc%IsActivated() ) then
      call this%phy_mp_proc%vars%Setup( this%mesh )
      call this%phy_mp_proc%Set_primary_atmvars_container( this%vars%container )
 
      call this%vars%Regist_physvar_manager( mp_auxvars2d_manager=this%phy_mp_proc%vars%auxvars2D_manager )
      call this%vars%Setup_container( this%phy_mp_proc%atm_var_container_typeid, this%mesh )
    end if
    !- Surface component
    if ( this%phy_sfc_proc%IsActivated() ) then
      call this%phy_sfc_proc%vars%Setup( this%mesh )
 
      call this%vars%Setup_container( this%phy_sfc_proc%atm_var_container_typeid, this%mesh )
    end if
    !- Turbulence component
    if ( this%phy_tb_proc%IsActivated() ) then
      call this%phy_tb_proc%vars%Setup( this%mesh )
    end if
    !- Radiation component
    if ( this%phy_rd_proc%IsActivated() ) then
      if ( .not. this%phy_sfc_proc%IsActivated() ) then
        log_error('ATM_setup_vars',*) 'ATMOS_PHY_RD_DO requires ATMOS_PHY_SF_DO to provide SFC_TEMP.'
        call prc_abort
      end if
      call this%phy_rd_proc%vars%Setup( this%mesh )
      call this%phy_rd_proc%SetSfcVars( this%phy_sfc_proc%vars%SFC_VARS(sfctemp_id), &
                                        this%phy_sfc_proc%vars%SFC_VARS(sfc_alb_id) )
    end if
    !- Cumulus parameterization component
    if ( this%phy_cp_proc%IsActivated() ) then
      call this%phy_cp_proc%vars%Setup( this%mesh )
      call this%vars%Regist_physvar_manager( cp_auxvars2d_manager=this%phy_cp_proc%vars%auxvars2D_manager )
 
      if ( this%phy_mp_proc%IsActivated() ) then
        call this%phy_mp_proc%Set_CP_tends_manager( this%phy_cp_proc%vars%tends_manager )
      end if      
    end if
    !- PBL component
    if ( this%phy_bl_proc%IsActivated() ) then
      call this%phy_bl_proc%vars%Setup( this%mesh )
    end if
 
    call prof_rapend( 'ATM_setup_vars', 1)
    return
  end subroutine atmos_setup_vars
 
  !> Set coupler component to the atmospheric component
!OCL SERIAL
  subroutine atmos_set_coupler( this, coupler )
    implicit none
    class(atmoscomponent), intent(inout) :: this
    class(couplercomponent), target, intent(inout) :: coupler
    !----------------------------------------------------------
    this%coupler_ptr => coupler
 
    if ( this%phy_sfc_proc%IsActivated() ) then
      call this%phy_sfc_proc%set_coupler_flag( coupler%IsActivated() )
    end if
    return
  end subroutine atmos_set_coupler
 
  !> Calculate tendencies with the atmospheric component
!OCL SERIAL
  subroutine atmos_calc_tendency( this, force )
    use scale_tracer, only: qa
    use scale_atm_dyn_dgm_nonhydro3d_common, only: &
      phytend_num1 => phytend_num, &
      dens_tp => phytend_dens_id,  &
      momx_tp => phytend_momx_id,  &
      momy_tp => phytend_momy_id,  &
      momz_tp => phytend_momz_id,  &
      rhot_tp =>  phytend_rhot_id, &
      rhoh_p => phytend_rhoh_id    
    use mod_atmos_vars, only: &
      atmosvars_getlocalmeshphytends
 
    implicit none
    class(atmoscomponent), intent(inout) :: this
    logical, intent(in) :: force
 
    class(meshbase), pointer :: mesh
    class(localmesh3d), pointer :: lcmesh
    type(localmeshfieldbaselist) :: tp_list(PHYTEND_NUM1)
    type(localmeshfieldbaselist) :: tp_qtrc(QA)
 
    integer :: tm_process_id
    logical :: is_update
    integer :: n
    integer :: v
    integer :: iq
    integer :: ke, p
    integer :: Np
 
    class(atmosvarscontainer), pointer :: vars_primary_container
    class(atmosvarscontainer), pointer :: vars_container
    
    !------------------------------------------------------------------
    
    call prof_rapstart( 'ATM_tendency', 1)
    !LOG_INFO('AtmosComponent_calc_tendency',*)
 
    call this%mesh%GetModelMesh( mesh )
    call this%vars%Get_container( atm_vars_container_primary_id, & ! (in)
      vars_primary_container ) ! (out)
    
    !########## Get Surface Boundary from coupler ##########    
    call this%Get_surface()
    
    
    !########## calculate tendency ##########
 
    !* Exchange halo data ( for physics )
    call prof_rapstart( 'ATM_exchange_prgv', 2)
    call this%vars%container%PROGVARS_manager%MeshFieldComm_Exchange()
    if ( qa > 0 ) call this%vars%container%QTRCVARS_manager%MeshFieldComm_Exchange()
    call prof_rapend( 'ATM_exchange_prgv', 2)
 
 
    !- Reset tendencies of physics
 
    !$acc data create( tp_list, tp_qtrc )
 
    do n=1, mesh%LOCAL_MESH_NUM
      call atmosvars_getlocalmeshphytends( n, mesh, this%vars%container%PHYTENDS_manager , & ! (in)
        tp_list(dens_tp)%ptr, tp_list(momx_tp)%ptr, tp_list(momy_tp)%ptr,                  & ! (out)
        tp_list(momz_tp)%ptr, tp_list(rhot_tp)%ptr, tp_list(rhoh_p )%ptr, tp_qtrc,         & ! (out)
        lcmesh                                                                             ) ! (out)
      !$acc enter data attach( tp_list(DENS_tp)%ptr, tp_list(MOMX_tp)%ptr, tp_list(MOMY_tp)%ptr, tp_list(MOMZ_tp)%ptr, tp_list(RHOT_tp)%ptr, tp_list(RHOH_p )%ptr, lcmesh )
 
      np = lcmesh%refElem%Np
      !$omp parallel private(v,iq,ke)
 
      !$omp do collapse(2)
      do v=1, phytend_num1
        !$acc parallel loop gang present( tp_list(v)%ptr%val ) async(1)
        do ke=lcmesh%NeS, lcmesh%NeE
          !$acc loop vector
          do p=1, np
            tp_list(v)%ptr%val(p,ke) = 0.0_rp
          end do
        end do
      end do
      if ( qa > 0 ) then
#ifdef _OPENACC        
        do iq=1, qa
          !$acc enter data attach( tp_qtrc(iq)%ptr )
        end do
#endif        
        !$omp do collapse(2)
        do iq=1, qa
          !$acc parallel loop gang present( tp_qtrc(iq)%ptr%val ) async(1)
          do ke=lcmesh%NeS, lcmesh%NeE
            !$acc loop vector
            do p=1, np
              tp_qtrc(iq)%ptr%val(p,ke) = 0.0_rp
            end do
          end do
        end do
        !$omp end do
      end if
      !$omp end parallel
    end do
    !$acc wait(1)
    !$acc end data
 
    !- Preprocessing for variables before calculating physics tendencies
 
    call prof_rapstart('ATM_PreOptrForPhys', 1)
    call this%vars%PreprocOperationForPhys( this%dyn_proc%dyncore_driver )
    call prof_rapend('ATM_PreOptrForPhys', 1)
 
    !- Cumulus parameterization
 
    if ( this%phy_cp_proc%IsActivated() ) then
      call prof_rapstart('ATM_Cumulus', 1)
      tm_process_id = this%phy_cp_proc%tm_process_id
      is_update = this%time_manager%Do_process(tm_process_id) .or. force
 
      call this%vars%Get_container( this%phy_cp_proc%atm_var_container_typeid, & ! (in)
        vars_container ) ! (out)
      
      call this%phy_cp_proc%calc_tendency( &
        this%mesh, vars_container%PROGVARS_manager, vars_container%QTRCVARS_manager, &
        vars_container%AUXVARS_manager, vars_primary_container%PHYTENDS_manager, is_update   )
      call prof_rapend('ATM_Cumulus', 1)
    end if
 
    !- Cloud Microphysics
 
    if ( this%phy_mp_proc%IsActivated() ) then
      call prof_rapstart('ATM_Microphysics', 1)
      tm_process_id = this%phy_mp_proc%tm_process_id
      is_update = this%time_manager%Do_process(tm_process_id) .or. force
 
      call this%vars%Get_container( this%phy_mp_proc%atm_var_container_typeid, & ! (in)
        vars_container ) ! (out)
      
      call this%phy_mp_proc%calc_tendency( &
        this%mesh, vars_container%PROGVARS_manager, vars_container%QTRCVARS_manager, &
        vars_container%AUXVARS_manager, vars_primary_container%PHYTENDS_manager, is_update   )
      call prof_rapend('ATM_Microphysics', 1)
    end if
    
    !- Radiation
 
    if ( this%phy_rd_proc%IsActivated() ) then
      call prof_rapstart('ATM_Radiation', 1)
      tm_process_id = this%phy_rd_proc%tm_process_id
      is_update = this%time_manager%Do_process(tm_process_id) .or. force
 
      call this%vars%Get_container( this%phy_rd_proc%atm_var_container_typeid, & ! (in)
        vars_container ) ! (out)
      
      call this%phy_rd_proc%calc_tendency( &
        this%mesh, vars_container%PROGVARS_manager, vars_container%QTRCVARS_manager, &
        vars_container%AUXVARS_manager, vars_primary_container%PHYTENDS_manager, is_update   )
      call prof_rapend('ATM_Radiation', 1)
    end if
 
    !- Turbulence
 
    if ( this%phy_tb_proc%IsActivated() ) then
      call prof_rapstart('ATM_Turbulence', 1)
      tm_process_id = this%phy_tb_proc%tm_process_id
      is_update = this%time_manager%Do_process(tm_process_id) .or. force
 
      call this%vars%Get_container( atm_vars_container_primary_id, & ! (in)
        vars_container ) ! (out)
      
      call this%phy_tb_proc%calc_tendency( &
        this%mesh, vars_container%PROGVARS_manager, vars_container%QTRCVARS_manager, &
        vars_container%AUXVARS_manager, vars_primary_container%PHYTENDS_manager, is_update   )
      call prof_rapend('ATM_Turbulence', 1)
    end if
 
 
    if ( .not. this%coupler_ptr%IsActivated() ) then
    
      !- Surface flux
      
      if ( this%phy_sfc_proc%IsActivated() ) then
        call prof_rapstart('ATM_SurfaceFlux', 1)
        tm_process_id = this%phy_sfc_proc%tm_process_id
        is_update = this%time_manager%Do_process(tm_process_id) .or. force
 
        call this%vars%Get_container( this%phy_sfc_proc%atm_var_container_typeid, & ! (in)
          vars_container ) ! (out)
        
        call this%phy_sfc_proc%calc_tendency( &
          this%mesh, vars_container%PROGVARS_manager, vars_container%QTRCVARS_manager, &
          vars_container%AUXVARS_manager, vars_primary_container%PHYTENDS_manager, is_update   )
        call prof_rapend('ATM_SurfaceFlux', 1)
      end if
      
      !- Planetary boundary layer
 
      if ( this%phy_bl_proc%IsActivated() ) then
        call prof_rapstart('ATM_PBL', 1)
        tm_process_id = this%phy_bl_proc%tm_process_id
        is_update = this%time_manager%Do_process(tm_process_id) .or. force
 
        call this%vars%Get_container( this%phy_bl_proc%atm_var_container_typeid, & ! (in)
          vars_container ) ! (out)
        
        call this%phy_bl_proc%calc_tendency( &
          this%mesh, vars_container%PROGVARS_manager, vars_container%QTRCVARS_manager, &
          vars_container%AUXVARS_manager, vars_primary_container%PHYTENDS_manager, is_update   )
        call prof_rapend('ATM_PBL', 1)
      end if
 
    end if
 
    !* setup surface condition
    call this%set_surface( countup=.true. )
 
    call prof_rapend( 'ATM_tendency', 1)
    return  
  end subroutine atmos_calc_tendency
 
!> Calculate tendencies with surface flux based on surface quantities managed by coupler component
!OCL SERIAL
  subroutine atmos_calc_tendency_from_sflux( this, force )
    use scale_tracer, only: qa
    use scale_atm_dyn_dgm_nonhydro3d_common, only: &
      phytend_num1 => phytend_num, &
      dens_tp => phytend_dens_id,  &
      momx_tp => phytend_momx_id,  &
      momy_tp => phytend_momy_id,  &
      momz_tp => phytend_momz_id,  &
      rhot_tp =>  phytend_rhot_id, &
      rhoh_p => phytend_rhoh_id    
    use mod_atmos_vars, only: &
      atmosvars_getlocalmeshphytends
 
    implicit none
    class(atmoscomponent), intent(inout) :: this
    logical, intent(in) :: force
 
    integer :: tm_process_id
    logical :: is_update
 
    class(atmosvarscontainer), pointer :: vars_primary_container
    class(atmosvarscontainer), pointer :: vars_container
    !------------------------------------------------------------
 
    if ( .not. this%coupler_ptr%IsActivated() ) return
 
    call this%vars%Get_container( atm_vars_container_primary_id, & ! (in)
      vars_primary_container ) ! (out)
 
    !########## Get Surface Boundary from coupler ##########    
    call this%Get_surface()
 
    !- Surface flux
    
    if ( this%phy_sfc_proc%IsActivated() ) then
      call prof_rapstart('ATM_SurfaceFlux', 1)
      tm_process_id = this%phy_sfc_proc%tm_process_id
      is_update = this%time_manager%Do_process(tm_process_id) .or. force
 
      call this%vars%Get_container( this%phy_sfc_proc%atm_var_container_typeid, & ! (in)
        vars_container ) ! (out)
      
      call this%phy_sfc_proc%calc_tendency( &
        this%mesh, vars_container%PROGVARS_manager, vars_container%QTRCVARS_manager, &
        vars_container%AUXVARS_manager, vars_primary_container%PHYTENDS_manager, is_update   )
      call prof_rapend('ATM_SurfaceFlux', 1)
    end if
    
    !- Planetary boundary layer
 
    if ( this%phy_bl_proc%IsActivated() ) then
      call prof_rapstart('ATM_PBL', 1)
      tm_process_id = this%phy_bl_proc%tm_process_id
      is_update = this%time_manager%Do_process(tm_process_id) .or. force
 
      call this%vars%Get_container( this%phy_bl_proc%atm_var_container_typeid, & ! (in)
        vars_container ) ! (out)
      
      call this%phy_bl_proc%calc_tendency( &
        this%mesh, vars_container%PROGVARS_manager, vars_container%QTRCVARS_manager, &
        vars_container%AUXVARS_manager, vars_primary_container%PHYTENDS_manager, is_update   )
      call prof_rapend('ATM_PBL', 1)
    end if
    return
  end subroutine atmos_calc_tendency_from_sflux
 
  !> Update variables with the atmospheric component
!OCL SERIAL
  subroutine atmos_update( this )
    implicit none
    class(atmoscomponent), intent(inout) :: this
    
    integer :: tm_process_id
    logical :: is_update
    integer :: inner_itr
 
    class(atmosvarscontainer), pointer :: vars_container    
    !--------------------------------------------------
    call prof_rapstart( 'ATM_update', 1)
 
    !########## Dynamics ########## 
 
    call this%vars%Get_container( atm_vars_container_primary_id, & ! (in)
      vars_container ) ! (out)
        
    if ( this%dyn_proc%IsActivated() ) then
      call prof_rapstart('ATM_Dynamics', 1)
      tm_process_id = this%dyn_proc%tm_process_id
      is_update = this%time_manager%Do_process( tm_process_id )
 
      log_progress(*) 'atmosphere / dynamics'   
      do inner_itr=1, this%time_manager%Get_process_inner_itr_num( tm_process_id )
        call this%dyn_proc%update( &
          this%mesh, vars_container%PROGVARS_manager, vars_container%QTRCVARS_manager, &
          vars_container%AUXVARS_manager, vars_container%PHYTENDS_manager, is_update   )
      end do
      call prof_rapend('ATM_Dynamics', 1)
    end if
    
    !########## Calculate diagnostic variables ##########  
 
    call vars_container%Calc_diagnostics()
    call vars_container%AUXVARS_manager%MeshFieldComm_Exchange()
 
    !########## Adjustment ##########
    ! Microphysics
    ! Aerosol
    ! Lightning
 
    !########## Reference State ###########
 
    !#### Check values #################################
    call this%vars%Check()
 
    call prof_rapend('ATM_update', 1)
    return  
  end subroutine atmos_update
 
  !> Set atmospheric quantites to coupler component
!OCL SERIAL
  subroutine atmos_set_surface( this, countup )
    use scale_atmos_hydrometeor, only: &
      atmos_hydrometeor_dry, &
      i_qv    
    use scale_atm_dyn_dgm_nonhydro3d_common, only: &
      prgvar_ddens_id, prgvar_momz_id, prgvar_momx_id, prgvar_momy_id, &
      auxvar_denshydro_id, auxvar_rtot_id, auxvar_pres_id
    use mod_atmos_vars, only: &
      atmosvars_getlocalmeshsfcvar
    use mod_atmos_vars_container, only: &
      prec_engi_id => atmos_auxvars2d_prec_engi_id
    use mod_atmos_phy_mp_vars, only: &
      atmosphympvars_getlocalmeshfields_sfcflx
    use mod_atmos_phy_cp_vars, only: &
      atmosphycpvars_getlocalmeshfields_sfcflx
    use mod_atmos_phy_rd_vars, only: &
      rd_sflx_lw_dif_id => atmos_phy_rd_aux2d_sflx_lw_dn_id, &
      rd_sflx_sw_dir_id => atmos_phy_rd_aux2d_sflx_sw_dn_id
    use mod_cpl_component, only: couplercomponent
    implicit none
    class(atmoscomponent), intent(inout) :: this
    logical, intent(in) :: countup
 
    class(meshbase), pointer :: mesh
    class(meshbase2d), pointer :: mesh2D
    class(localmesh2d), pointer :: lcmesh
    integer :: n
    integer :: ke
 
    class(localmeshfieldbase), pointer :: PREC, PREC_ENGI
    class(localmeshfieldbase), pointer :: SFLX_rain_MP, SFLX_snow_MP, SFLX_ENGI_MP
    class(localmeshfieldbase), pointer :: SFLX_rain_CP, SFLX_snow_CP, SFLX_ENGI_CP
 
    integer :: iq
    !--------------------------------------------------
 
    call prof_rapstart( 'ATM_sfc_exch', 1)
 
    call this%mesh%GetModelMesh( mesh )  
    select type(mesh)
    class is (meshbase3d)
      call mesh%GetMesh2D( mesh2d )
    end select
 
    !- Sum up precipitation and energy fluxes from cloud microphysics and cumulus parameterization components
 
    do n=1, mesh2d%LOCAL_MESH_NUM
      call atmosvars_getlocalmeshsfcvar( n, &
        mesh2d, this%vars%container%AUXVARS2D_manager, & ! (in)
        prec, prec_engi, lcmesh                        ) ! (out)
 
      !$omp parallel do private(ke)
      do ke=lcmesh%NeS, lcmesh%NeE
        prec     %val(:,ke) = 0.0_rp
        prec_engi%val(:,ke) = 0.0_rp
      end do
 
      if ( this%phy_mp_proc%IsActivated() ) then
        call atmosphympvars_getlocalmeshfields_sfcflx( n, &
          mesh2d, this%phy_mp_proc%vars%auxvars2D_manager, & ! (in)
          sflx_rain_mp, sflx_snow_mp, sflx_engi_mp         ) ! (out)
 
        !$omp parallel do private(ke)
        do ke=lcmesh%NeS, lcmesh%NeE
          prec     %val(:,ke) = prec     %val(:,ke) + sflx_rain_mp%val(:,ke) + sflx_snow_mp%val(:,ke)
          prec_engi%val(:,ke) = prec_engi%val(:,ke) + sflx_engi_mp%val(:,ke)
        end do
      end if
 
      if ( this%phy_cp_proc%IsActivated() ) then
        call atmosphycpvars_getlocalmeshfields_sfcflx( n, &
          mesh2d, this%phy_cp_proc%vars%auxvars2D_manager, & ! (in)
          sflx_rain_cp, sflx_snow_cp, sflx_engi_cp         ) ! (out)
 
        !$omp parallel do private(ke)
        do ke=lcmesh%NeS, lcmesh%NeE
          prec     %val(:,ke) = prec     %val(:,ke) + sflx_rain_cp%val(:,ke) + sflx_snow_cp%val(:,ke)
          prec_engi%val(:,ke) = prec_engi%val(:,ke) + sflx_engi_cp%val(:,ke)
        end do
      end if
    end do
 
    if ( this%coupler_ptr%IsActivated() ) then
      if ( atmos_hydrometeor_dry ) then
        iq = 0
      else
        iq = i_qv
      end if    
      call this%coupler_ptr%vars%PutAtm( &
        this%vars%container%PROG_VARS(prgvar_ddens_id),     &
        this%vars%container%PROG_VARS(prgvar_momz_id),      &
        this%vars%container%PROG_VARS(prgvar_momx_id),      &
        this%vars%container%PROG_VARS(prgvar_momy_id),      &
        this%vars%container%QTRC_VARS(iq),                  &
        this%vars%container%AUX_VARS(auxvar_pres_id),       &
        this%vars%container%AUX_VARS(auxvar_rtot_id),       &
        this%vars%container%AUX_VARS(auxvar_denshydro_id),  &
        this%phy_rd_proc%vars%auxvars2D(rd_sflx_sw_dir_id), &
        this%phy_rd_proc%vars%auxvars2D(rd_sflx_lw_dif_id), &
        this%vars%container%AUX_VARS2D(prec_engi_id),       &
        countup )
    end if
 
    call prof_rapend( 'ATM_sfc_exch', 1)
 
    return
  end subroutine atmos_set_surface
 
  !> Get surface quantities from coupler component
!OCL SERIAL
  subroutine atmos_get_surface( this )
    use mod_atmos_vars, only: &
      atmosvars_getlocalmeshsfcvar
    use mod_atmos_phy_sfc_vars, only: &
      sfctemp_id => atmos_phy_sf_svar_temp_id, &
      sfcalb_id => atmos_phy_sf_svar_alb_id,   &
      sflx_mw_id => atmos_phy_sf_sflx_mw_id,   &
      sflx_mu_id => atmos_phy_sf_sflx_mu_id,   &
      sflx_mv_id => atmos_phy_sf_sflx_mv_id,   &
      sflx_sh_id => atmos_phy_sf_sflx_sh_id,   &
      sflx_lh_id => atmos_phy_sf_sflx_lh_id,   &
      sflx_qv_id => atmos_phy_sf_sflx_qv_id
    use mod_cpl_component, only: couplercomponent      
    implicit none
    class(atmoscomponent), intent(inout), target :: this
    !--------------------------------------------------
 
    if ( .not. this%coupler_ptr%IsActivated() ) return
 
    call prof_rapstart( 'ATM_sfc_exch', 1)
    call this%coupler_ptr%vars%Get_SFC_ATM( &
      this%phy_sfc_proc%vars%SFC_VARS(sfctemp_id), &
      this%phy_sfc_proc%vars%SFC_VARS(sfcalb_id),  &
      this%phy_sfc_proc%vars%SFC_FLX(sflx_mw_id),  &
      this%phy_sfc_proc%vars%SFC_FLX(sflx_mu_id),  &
      this%phy_sfc_proc%vars%SFC_FLX(sflx_mv_id),  &
      this%phy_sfc_proc%vars%SFC_FLX(sflx_sh_id),  &
      this%phy_sfc_proc%vars%SFC_FLX(sflx_lh_id),  &
      this%phy_sfc_proc%vars%SFC_FLX(sflx_qv_id)   )
    call prof_rapend( 'ATM_sfc_exch', 1)
    return
  end subroutine atmos_get_surface
 
  !> Finalize an object to manage the atmospheric component
!OCL SERIAL
  subroutine atmos_finalize( this )
    implicit none
    class(atmoscomponent), intent(inout) :: this
    !--------------------------------------------------
 
    log_info('AtmosComponent_finalize',*)
 
    if ( .not. this%IsActivated() ) return
 
    call this%dyn_proc%finalize()
    call this%phy_sfc_proc%finalize()
    call this%phy_tb_proc%finalize()
    call this%phy_mp_proc%finalize()
    call this%phy_rd_proc%finalize()
    call this%phy_cp_proc%finalize()
    call this%phy_bl_proc%finalize()
    call this%vars%Final()
 
    select case( this%mesh_type )
    case('REGIONAL')
      call this%mesh_rm%Final()
    case('GLOBAL')
      call this%mesh_gm%Final()
    end select  
    this%mesh => null()
 
    call this%time_manager%Final()
 
    return  
  end subroutine atmos_finalize
 
end module mod_atmos_component