dc_string::replace Interface Reference

Private Member Functions
recursive character(strlen) function	replace (string, from, to, recursive, start_pos)

Detailed Description

Definition at line 128 of file dc_string.f90.

Constructor & Destructor Documentation

replace()

recursive character(strlen) function dc_string::replace::replace ( character(*), intent(in)  string, character(*), intent(in)  from, character(*), intent(in)  to, logical, intent(in), optional  recursive, integer, intent(in), optional  start_pos  )

private

Definition at line 1264 of file dc_string.f90.

    !
    ! 文字列 *string* に文字列 *from* が含まれる場合, その部分を文字列 *to*
    ! に置換して返します. 文字列 *from* が含まれない場合は *string*
    ! をそのまま返します. *from* が複数含まれる場合, 先頭の *from*
    ! のみが置換されます.
    !
    ! 全ての *from* を *to* へ変換したい場合には,
    ! オプショナル引数 *recursive* に .true. を与えてください.
    !
    ! デフォルトでは, 文字列の最初から検索を行います.
    ! オプショナル引数 *start_pos* を与える場合,
    ! *start_pos* 文字目から検索を行います.
    !
    ! If a string *from* is included in *string*, the string is
    ! replace to *to*, and the replaced string is returned.
    ! If a string *from* is not included, *string* is returned
    ! without change.
    ! When multiple *from* are included, only first *from* is replaced.
    !
    ! In order to replace all *from* to *to*, give ".true." to
    ! optional argument *recursive*.
    !
    ! By default, the string is searched from the top.
    ! If optional argument *start_pos* is given,
    ! the search is started from *start_pos*.
    !
    use dc_types, only: strlen => string
    implicit none
    character(STRLEN):: result
    character(*), intent(in):: string, from, to
    logical, intent(in), optional:: recursive
    integer, intent(in), optional:: start_pos
    integer:: sp
    integer:: i, isa, isb, iea, ieb
    integer:: ir
  continue
    if ( present(start_pos) ) then
      sp = start_pos
    else
      sp = 1
    end if
    if ( sp < 1 ) then
      sp = 1
    end if

    result = string
    i = index(result(sp:), from)
    if (i == 0) return
    i = i + sp - 1
    isa = i + len(from)
    isb = i + len(to)
    if (len(to) < len(from)) then
      iea = len(result)
      ieb = len(result) + len(to) - len(from)
    else
      iea = len(result) + len(from) - len(to)
      ieb = len(result)
    endif
    if (len(to) /= len(from)) result(isb:ieb) = result(isa:iea)
    result(i:i+len(to)-1) = to

    !-----------------------------------
    !  再帰的処理
    !  Recursive process
    ir = index(result(i+len(to):), from)
    if ( len_trim(from) == 0 ) then
      ir = index(trim(result(i+len(to):)), from)
    end if
    if (ir /= 0) then
      if ( present(recursive) ) then
        if ( recursive ) then
          result = replace( string = result, &
            &               from = from, to = to, &
            &               recursive = recursive, &
            &               start_pos = i+len(to) )
        end if
      end if
    end if

---

The documentation for this interface was generated from the following file:

• dc_utils/dc_string.f90