dc_clock::dcclockresult Interface Reference

Private Member Functions
subroutine	dcclockresult0 (clks, unit, total_auto, clk_total, total_name, err)

Detailed Description

Definition at line 159 of file dc_clock.f90.

Member Function/Subroutine Documentation

dcclockresult0()

subroutine dc_clock::dcclockresult::dcclockresult0 ( type(clock), dimension(:), intent(in)  clks, integer, intent(in), optional  unit, logical, intent(in), optional  total_auto, type(clock), intent(in), optional  clk_total, character(*), intent(in), optional  total_name, logical, intent(out), optional  err  )

private

Definition at line 535 of file dc_clock.f90.

    !
    !=== CPU 時間の総計を表示
    !
    ! CPU 時間の総計を表示します. *clks* へ, CLOCK 変数の配列を
    ! 与えてください. プログラムの最後で呼び出されることを
    ! 想定しています. *unit* には出力先の装置番号を
    ! 与えてください. *unit* を与えない場合, 標準出力へ表示されます.
    !
    ! 引数 *total_auto* に .true. を与えると, *clks* を全て足し合わせた
    ! 合計値を自動的に表示します. 下記の引数 *clk_total* が与えられている
    ! 場合は *clk_total* が優先されます.
    !
    ! 引数 *clk_total* に CLOCK 変数を与えると, この変数を合計値と
    ! して表示します.
    !
    ! 引数 *total_name* に文字型変数を与えると, 総計メッセージの
    ! 冒頭にこの文字列を出力します.
    !
    ! 第一引数 *clk* に対して DCClockCreate による初期化が行われていない場合,
    ! エラーを発生させます. *err* を与える場合には *err* に .true. が返り,
    ! プログラムは続行されます.
    !
    use dc_types, only: stdout, string, dp
    use dc_message, only: messagenotify
    use dc_string, only: printf, tochar, cprintf
    use dc_date, only: evalsec
    use dc_error, only: storeerror, dc_enotinit, dc_noerr
    implicit none
    type(clock), intent(in):: clks(:)
    integer, intent(in), optional:: unit
    logical, intent(in), optional:: total_auto
    type(clock), intent(in), optional:: clk_total
    logical, intent(out), optional:: err
    character(*), intent(in), optional:: total_name
    integer:: out_unit, i, clks_size, ra
    character(20):: clk_name
    character(STRING):: cause_c
    character(STRING):: total_name_work
    type(clock):: clk_auto_total
    logical:: total_print_complete
    real(DP):: elapsed_time_val_cor
    integer:: stat
    character(*), parameter:: total_time_mes = '       TOTAL TIME = '
    integer:: myrank_mpi, nprocs_mpi
    character(*), parameter:: subname = 'DCClockResult'
  continue
    call beginsub(subname)
    stat = dc_noerr
    cause_c = 'CLOCK'
    clks_size = size(clks)
    do i = 1, clks_size
      if (.not. clks(i) % initialized) then
        call messagenotify('W', subname, 'Call Create before Result in dc_clock.')
        call dbgmessage('Ignored because input argument was not initialized.')
        stat = dc_enotinit
        goto 999
      end if
    end do
    if (present(unit)) then
      out_unit = unit
    else
      out_unit = stdout
    end if
    if (present(total_name)) then
      total_name_work = ' (' // trim(total_name) // ')'
    else
      total_name_work = ''
    end if
    myrank_mpi = -1
    nprocs_mpi = 1
    do ra = 0, nprocs_mpi - 1
      call printf(out_unit, '')
      if ( myrank_mpi < 0 ) then
        call printf(out_unit, &
          & ' ############## CPU TIME SUMMARY%c################', &
          & c1=trim(total_name_work) // ' ')
      else
        call printf(out_unit, &
          & ' ####### CPU TIME SUMMARY%c#### [rank=%06d] ####', &
          & c1=trim(total_name_work) // ' ', &
          & i = (/myrank_mpi/) )
      end if
      do i = 1, clks_size
        clk_name = clks(i) % name
        elapsed_time_val_cor = clks(i) % elapsed_time
        if (elapsed_time_val_cor < 0.0_dp) elapsed_time_val_cor = 0.0_dp
        call printf(out_unit, &
          & ' %c%c  %c', c1=clk_name, &
          & c2=trim(result_value_form(elapsed_time_val_cor)), &
          & c3=trim(fit_unit_value(clks(i) % elapsed_time)))
      end do
      total_print_complete = .false.
      if (present(clk_total)) then
        if (clk_total % initialized) then
          call printf(out_unit, &
            & ' ------------------------------------------------')
          elapsed_time_val_cor = clk_total % elapsed_time
          if (elapsed_time_val_cor < 0.0_dp) elapsed_time_val_cor = 0.0_dp
          call printf(out_unit, &
            & ' %c%c  %c', c1=total_time_mes, &
            & c2=trim(result_value_form(elapsed_time_val_cor)), &
            & c3=trim(fit_unit_value(clk_total % elapsed_time)))
          total_print_complete = .true.
        end if
      end if
      if (present(total_auto) .and. .not. total_print_complete) then
        if (total_auto) then
          clk_auto_total = clks(1)
          if (clks_size > 1) then
            do i = 2, clks_size
              clk_auto_total = clk_auto_total + clks(i)
            end do
          end if
          call printf(out_unit, &
            & ' ------------------------------------------------')
          elapsed_time_val_cor = clk_auto_total % elapsed_time
          if (elapsed_time_val_cor < 0.0_dp) elapsed_time_val_cor = 0.0_dp
          call printf(out_unit, &
            & ' %c%c  %c', c1=total_time_mes, &
            & c2=trim(result_value_form(elapsed_time_val_cor)), &
            & c3=trim(fit_unit_value(clk_auto_total % elapsed_time)))
        end if
      end if
      call dbgmessage('total results, output to device number %d', &
        & i=(/out_unit/))
    end do
999 continue
    call storeerror(stat, subname, err, cause_c)
    call endsub(subname)

---

The documentation for this interface was generated from the following file:

• dc_utils/dc_clock.f90