dcdatetimegt.f90

Go to the documentation of this file.

!= 利用者定義演算子 (>) のための関数
!= Functions for user defined operation (>)
!
! Authors::   Yasuhiro MORIKAWA
! Version::   $Id: dcdatetimegt.f90,v 1.1 2009-05-25 10:01:34 morikawa Exp $
! Tag Name::  $Name:  $
! Copyright:: Copyright (C) GFD Dennou Club, 2000-2005. All rights reserved.
! License::   See COPYRIGHT[link:../../COPYRIGHT]
!
  logical function dcdatetime_gt_tt(time1, time2) result(result)
    !
    ! 2 つの引数の日時を比較します.
    ! 1 つ目の引数に格納される日時が 2 つ目の引数に格納される日時
    ! よりも進んでいる場合, .true. が返ります.
    !
    use dc_date_generic, only: eval, evalsclsec, zonetodiff
    use dc_date_types, only: dc_datetime, dc_difftime
    use dc_scaledsec, only: dc_scaled_sec, &
      & operator(==), operator(<), operator(>), operator(<=), operator(>=), &
      & operator(+), operator(-), operator(*), operator(/), &
      & modulo, int, abs, sign
    implicit none
    type(dc_datetime), intent(in):: time1, time2
    type(dc_scaled_sec):: year1, year2, time1_sec, time2_sec
  continue
    call eval(time1, sclyear=year1)
    call eval(time2, sclyear=year2)
    if (year1 > year2) then
      result = .true.
    elseif (year1 < year2) then
      result = .false.
    else
      time1_sec = evalsclsec(time1) + evalsclsec(zonetodiff(time1 % zone))
      time2_sec = evalsclsec(time2) + evalsclsec(zonetodiff(time2 % zone))
      if (time1_sec > time2_sec) then
        result = .true.
      else
        result = .false.
      end if
    end if
  end function dcdatetime_gt_tt

  logical function dcdatetime_gt_ff(diff1, diff2) result(result)
    !
    ! 2 つの引数の日時差を比較します.
    ! 1 つ目の引数に格納される日時差が 2 つ目の引数に格納される日時差
    ! よりも大きい場合, .true. が返ります.
    !
    use dc_date_generic, only: evalsec
    use dc_date_types, only: cyclic_mdays
    use dc_scaledsec, only: &
      & operator(<), operator(>), operator(<=), operator(>=), operator(==)
    use dc_date_types, only: dc_datetime, dc_difftime
    implicit none
    type(dc_difftime), intent(in):: diff1, diff2
  continue
    if ( diff1 % day_seconds == diff2 % day_seconds ) then

      if ( diff1 % mon > diff2 % mon ) then
        result = .true.  ; return
      elseif ( diff1 % mon < diff2 % mon ) then
        result = .false. ; return
      end if
      if ( diff1 % day > diff2 % day ) then
        result = .true.  ; return
      elseif ( diff1 % day < diff2 % day ) then
        result = .false. ; return
      end if
      if ( diff1 % sec > diff2 % sec ) then
        result = .true.  ; return
      elseif ( diff1 % sec < diff2 % sec ) then
        result = .false. ; return
      end if
      result = .false.
    else

      if (evalsec(diff1) > evalsec(diff2)) then
        result = .true.
      else
        result = .false.
      end if
    end if
  end function dcdatetime_gt_ff

  logical function dcdatetime_gt_fi(diff, factor) result(result)
    !
    ! 2 つの引数の日時差を比較します.
    ! 1 つ目の引数に格納される日時差が 2 つ目の引数に格納される日時差
    ! よりも大きい場合, .true. が返ります.
    !
    use dc_date_generic, only: evalsec
    use dc_date_types, only: cyclic_mdays, dc_datetime, dc_difftime
    implicit none
    type(dc_difftime), intent(in):: diff
    integer, intent(in):: factor
  continue
    result = evalsec(diff) > factor
  end function dcdatetime_gt_fi

  logical function dcdatetime_gt_if(factor, diff) result(result)
    !
    ! 2 つの引数の日時差を比較します.
    ! 1 つ目の引数に格納される日時差が 2 つ目の引数に格納される日時差
    ! よりも大きい場合, .true. が返ります.
    !
    use dc_date_generic, only: evalsec
    use dc_date_types, only: cyclic_mdays, dc_datetime, dc_difftime
    implicit none
    integer, intent(in):: factor
    type(dc_difftime), intent(in):: diff
  continue
    result = factor > evalsec(diff)
  end function dcdatetime_gt_if