*"表題 第１次元の格子選択 GTOOL3(GPXSEL)
*
*"履歴 90/08/17 沼口  敦
*
*
*********************************************************************
*"         << 第１次元の格子選択 >>
*********************************************************************
      SUBROUTINE GPXSEL
     I         ( HHEAD , GDATA , IXSEL  ,
     I           HEDIT , HETTL ,
     O           HHEADO, GDATAO          )
*
      CHARACTER  HHEAD  ( * )*(*)        !" ヘッダー(入力)
      REAL       GDATA  ( * )            !" データ(入力)
      INTEGER    IXSEL                   !" 選択する第1次元の格子
      CHARACTER  HEDIT       *(*)        !" 編集略記号
      CHARACTER  HETTL       *(*)        !" 編集タイトル
      CHARACTER  HHEADO ( * )*(*)        !" ヘッダー(出力)
      REAL       GDATAO ( * )            !" データ(出力)
*
#ifdef SYS_IBMS
      INCLUDE    (GZSIZE)                !" NCC, NDC
#else
#include         "gzsize.F"              !" NCC, NDC
#endif
      CHARACTER  HITM        *(NCC)
      CHARACTER  HAXIS       *(NCC)
      CHARACTER  HEDITD      *(NCC)      !" 編集略記号
      CHARACTER  HETTLD      *(NCC)      !" 編集タイトル
      LOGICAL    OCYCL                   !" サイクリックか？
*
*"         < 1. 大きさの取得 >
*
      CALL GUSMIS ( HHEAD )
*
      CALL GUQSIZ
     I         ( HHEAD ,
     O           IXSTR , IXEND , IXDIM ,
     O           IYSTR , IYEND , IYDIM ,
     O           IZSTR , IZEND , IZDIM  )
*
      CALL GUSZCK ( HHEADO, IYDIM*IZDIM )
*
      CALL GHCGET( HHEAD, 'AITM1', HAXIS )
      CALL GUQAXD
     I         ( HAXIS ,
     O           IADIM , OCYCL  )
*
*"         < 2. データ詰め替え >
*
      IF ( OCYCL ) THEN
         IXI = MOD( IXSEL-IXSTR, IADIM ) + 1
      ELSE
         IXI = IXSEL-IXSTR+1
      ENDIF
*
      IF ( ( 1.LE.IXI ).AND.( IXI.LE.IXDIM ) ) THEN
         CALL VRSET
     I        ( GDATA ( IXI ),
     O          GDATAO ,
     I          IYDIM*IZDIM  , IXDIM   , 1    )
      ELSE
         CALL GHPGET( HHEAD , 'MISS', VMISS )
         CALL RSET  ( GDATAO, IYDIM*IZDIM, VMISS )
      ENDIF
*
*"         < 3. ヘッダー変更 >
*
      CALL GHCOPY ( HHEAD, HHEADO )
      CALL GHCGET ( HHEAD , 'AITM2', HITM  )
      CALL GHCSET ( HHEADO, 'AITM1', HITM  )
      CALL GHCGET ( HHEAD , 'AITM3', HITM  )
      CALL GHCSET ( HHEADO, 'AITM2', HITM  )
      CALL GHPSET ( HHEADO, 'ASTR2', IZSTR )
      CALL GHPSET ( HHEADO, 'AEND2', IZEND )
      CALL GHPSET ( HHEADO, 'ASTR1', IYSTR )
      CALL GHPSET ( HHEADO, 'AEND1', IYEND )
      CALL GHCSET ( HHEADO, 'AITM3', ' '   )
      CALL GHPSET ( HHEADO, 'ASTR3', 1     )
      CALL GHPSET ( HHEADO, 'AEND3', 1     )
*
      IF ( ( IXSTR .EQ. IXSEL ).AND.( IXEND .EQ. IXSEL ) ) RETURN
*
*"         < 4. 編集記述を設定  >
*
      IF      ( HEDIT .EQ. ' ' ) THEN
         CALL GUEAXN
     I               ( HAXIS , 'XS'   , '-select',
     I                 IXSEL , IXSEL  ,
     O                 HEDITD, HETTLD          )
         CALL GHEADD ( HHEADO, HEDITD, HETTLD )
      ELSE IF ( HEDIT .NE. 'NUL' ) THEN
         CALL GHEADD ( HHEADO, HEDIT  , HETTL   )
      ENDIF
*
      RETURN
      END
*********************************************************************
*"         << 第１次元の格子選択 >>
*********************************************************************
      SUBROUTINE GMXSEL
     M         ( HHEAD , GDATA ,
     I           IXSEL ,
     I           HEDIT , HETTL  )
*
      CHARACTER  HHEAD  ( * )*(*)        !" ヘッダー(入力)
      REAL       GDATA  ( * )            !" データ(入力)
      INTEGER    IXSEL                   !" 選択する第1次元の格子
      CHARACTER  HEDIT       *(*)        !" 編集略記号
      CHARACTER  HETTL       *(*)        !" 編集タイトル
*
      COMMON     /GMWORK/ GDATAW
      REAL       GDATAW ( 1 )            !" データ(ワーク)
#ifdef SYS_IBMS
      INCLUDE    (GZSIZE)                !" NCC, NDC
#else
#include         "gzsize.F"              !" NCC, NDC
#endif
      CHARACTER  HHEADW ( NDC )*(NCC)    !" ヘッダー(ワーク)
*
      CALL       GMCSIZ ( HHEADW )
      CALL       GPXSEL
     I         ( HHEAD , GDATA , IXSEL  ,
     I           HEDIT , HETTL ,
     O           HHEADW, GDATAW          )
*
      CALL       GPFSET
     I         ( HHEADW, GDATAW,
     I           ' '   , ' '   ,
     O           HHEAD , GDATA   )
*
      RETURN
      END