*"表題 第１次元の部分切出し GTOOL3(GPXRDC)
*
*"履歴 90/08/18 沼口  敦
*
*
*********************************************************************
*"         << 第１次元の部分切出し >>
*********************************************************************
      SUBROUTINE GPXRDC
     I         ( HHEAD , GDATA , IXSEL1 , IXSEL2 ,
     I           HEDIT , HETTL ,
     O           HHEADO, GDATAO                    )
*
      CHARACTER  HHEAD  ( * )*(*)        !" ヘッダー(入力)
      REAL       GDATA  ( * )            !" データ(入力)
      INTEGER    IXSEL1                  !" 切り出す第1次元の格子
      INTEGER    IXSEL2                  !" 切り出す第1次元の格子
      CHARACTER  HEDIT       *(*)        !" 編集略記号
      CHARACTER  HETTL       *(*)        !" 編集タイトル
      CHARACTER  HHEADO ( * )*(*)        !" ヘッダー(出力)
      REAL       GDATAO ( * )            !" データ(出力)
*
#ifdef SYS_IBMS
      INCLUDE    (GZSIZE)                !" NCC, NDC
#else
#include         "gzsize.F"              !" NCC, NDC
#endif
      CHARACTER  HAXIS       *(NCC)      !" 軸名称
      CHARACTER  HEDITD      *(NCC)      !" 編集略記号
      CHARACTER  HETTLD      *(NCC)      !" 編集タイトル
      LOGICAL    OCYCL                   !" サイクリックか？
*
*"         < 1. 大きさの取得 >
*
      CALL GUSMIS ( HHEAD )
*
      CALL GUQSIZ
     I         ( HHEAD ,
     O           IXSTR , IXEND , IXDIM ,
     O           IYSTR , IYEND , IYDIM ,
     O           IZSTR , IZEND , IZDIM  )
*
      IXDIMC = IXSEL2-IXSEL1+1
      CALL GUSZCK ( HHEADO, IXDIMC*IYDIM*IZDIM )
*
      CALL GHCGET ( HHEAD, 'AITM1 ', HAXIS  )
      CALL GUQAXD
     I         ( HAXIS ,
     O           IADIM , OCYCL  )
*
*"         < 2. データ詰め替え >
*
      CALL GHPGET ( HHEAD, 'MISS', VMISS )
*
      DO 2100 IX = IXSEL1, IXSEL2
         IF ( OCYCL ) THEN
            IXI = MOD( IX-IXSTR, IADIM ) + 1
         ELSE
            IXI = IX-IXSTR+1
         ENDIF
*
         IF ( ( 1.LE.IXI ).AND.( IXI.LE.IXDIM ) ) THEN
            CALL VRSET
     I         ( GDATA ( IXI         ),
     O           GDATAO( IX-IXSEL1+1 ),
     I           IYDIM*IZDIM, IXDIM , IXDIMC )
         ELSE
           CALL RSET
     O        ( GDATAO( IX-IXSEL1+1 ),
     I          IYDIM*IZDIM , IXDIMC, VMISS )
         ENDIF
*
 2100 CONTINUE
*
*"         < 3. ヘッダー変更 >
*
      CALL GHCOPY ( HHEAD, HHEADO )
      CALL GHPSET ( HHEADO, 'ASTR1', IXSEL1 )
      CALL GHPSET ( HHEADO, 'AEND1', IXSEL2 )
*
      IF ( ( IXSTR .EQ. IXSEL1 ).AND.( IXEND .EQ. IXSEL2 ) ) RETURN
*
      IF      ( HEDIT .EQ. ' ' ) THEN
         CALL GUEAXN
     I               ( HAXIS , 'XR'   , '-reduce',
     I                 IXSEL1, IXSEL2 ,
     O                 HEDITD, HETTLD          )
         CALL GHEADD ( HHEADO, HEDITD, HETTLD )
      ELSE IF ( HEDIT .NE. 'NUL' ) THEN
         CALL GHEADD ( HHEADO, HEDIT  , HETTL   )
      ENDIF
*
      RETURN
      END
*********************************************************************
*"         << 第１次元の部分切出し >>
*********************************************************************
      SUBROUTINE GMXRDC
     I         ( HHEAD , GDATA ,
     I           IXSEL1, IXSEL2,
     I           HEDIT , HETTL  )
*
      CHARACTER  HHEAD  ( * )*(*)        !" ヘッダー(入力)
      REAL       GDATA  ( * )            !" データ(入力)
      INTEGER    IXSEL1                  !" 切り出す第1次元の格子
      INTEGER    IXSEL2                  !" 切り出す第1次元の格子
      CHARACTER  HEDIT       *(*)        !" 編集略記号
      CHARACTER  HETTL       *(*)        !" 編集タイトル
*
      COMMON     /GMWORK/ GDATAW
      REAL       GDATAW ( 1 )            !" データ(ワーク)
#ifdef SYS_IBMS
      INCLUDE    (GZSIZE)                !" NCC, NDC
#else
#include         "gzsize.F"              !" NCC, NDC
#endif
      CHARACTER  HHEADW ( NDC )*(NCC)    !" ヘッダー(ワーク)
*
      CALL       GMCSIZ ( HHEADW )
      CALL       GPXRDC
     I         ( HHEAD , GDATA , IXSEL1 , IXSEL2 ,
     I           HEDIT , HETTL ,
     O           HHEADW, GDATAW                    )
*
      CALL       GPFSET
     I         ( HHEADW, GDATAW,
     I           ' '   , ' '   ,
     O           HHEAD , GDATA   )
*
      RETURN
      END