mod_atmos_phy_bl.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!> module Atmosphere / Physics / Planetary Boundary Layer
!!
!! @par Description
!!          Module for planetary boundary layer (PBL) turbulence parameterization
!!
!! @author Yuta Kawai, Team SCALE
!!
!<
!-------------------------------------------------------------------------------
#include "scaleFElib.h"
module mod_atmos_phy_bl
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !  
  use scale_precision
  use scale_prc
  use scale_io
  use scale_prof
  use scale_const, only: &
    undef8 => const_undef8
 
  use scale_element_line, only: lineelement
  use scale_mesh_base, only: meshbase
  use scale_mesh_base2d, only: meshbase2d
  use scale_mesh_base3d, only: meshbase3d
 
  use scale_localmesh_base, only: localmeshbase
  use scale_localmesh_2d, only: localmesh2d
  use scale_localmesh_3d, only: localmesh3d
  use scale_element_base, only: elementbase, &
    elementbase1d, elementbase2d, elementbase3d
 
  use scale_meshfield_base, only: &
    meshfieldbase, meshfield3d
  use scale_localmeshfield_base, only: &
    localmeshfieldbase, localmeshfieldbaselist
 
  use scale_model_mesh_manager, only: modelmeshbase
  use scale_model_var_manager, only: modelvarmanager
  use scale_model_component_proc, only:  modelcomponentproc
 
  use scale_atm_dyn_dgm_bnd, only: atmdynbnd
 
  use mod_atmos_phy_bl_vars, only: atmosphyblvars
  use mod_atmos_vars_container, only: &
    atmosvarscontainer
    
 
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public type & procedure
  !
 
  !> Derived type to manage a component of planetary boundary layer (PBL) turbulence parameterization in atmospheric model
  !!
  type, extends(modelcomponentproc), public :: atmosphybl
    integer :: bl_typeid         !< Type id of PBL turbulence parameterization scheme
    type(atmosphyblvars) :: vars !< Object to manage variables with PBL turbulence parameterization
 
    integer :: atm_var_container_typeid     !< Type ID of variable container for PBL turbulence parameterization
 
    real(rp) :: dtsec !< Timestep for PBL turbulence parameterization
 
    type(lineelement) :: v_elem1d
    type(atmdynbnd), pointer :: dyn_bnd  !< Pointer to object for treating boundary conditions with atmospheric dynamics  
    real(rp) :: c_ip                     !< Parameter for symmetric interior penalty method in DGM
    logical :: use_delta_form            !< Flag to use delta form in the vertical implicit time integration of PBL scheme
  contains
    procedure :: setup => atmosphybl_setup
    procedure :: calc_tendency => atmosphybl_calc_tendency
    procedure :: update => atmosphybl_update
    procedure :: finalize => atmosphybl_finalize
    procedure, public :: setdynbc => atmosphybl_setdynbc
  end type atmosphybl
 
  !-----------------------------------------------------------------------------
  !++ Public parameters & variables
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
 
  integer, parameter :: bl_typeid_mynn_level2 = 1 !< Type ID of MYNN Level 2 PBL scheme
contains
 
!> Setup a component of planetary boundary layer (PBL) turbulence parameterization in atmospheric model
!!
!! @param model_mesh Object to manage computational mesh of atmospheric model 
!! @param tm_parent_comp Object to mange a temporal scheme in a parent component
!!
  subroutine atmosphybl_setup( this, model_mesh, tm_parent_comp )
    use scale_tracer, only: qa
    use mod_atmos_mesh, only: atmosmesh
    use scale_time_manager, only: time_manager_component
 
    use scale_atm_phy_bl_dgm_mynn_lv2, only: &
      atm_phy_bl_dgm_mynn_lv2_init
    use mod_atmos_vars, only: atm_vars_container_primary_id
    implicit none
    class(atmosphybl), intent(inout) :: this
    class(modelmeshbase), target, intent(in) :: model_mesh
    class(time_manager_component), intent(inout) :: tm_parent_comp
 
    real(dp) :: time_dt                             = undef8 !< Timestep for PBL turbulence parameterization
    character(len=H_SHORT) :: time_dt_unit          = 'SEC'  !< Unit of timestep
 
    character(len=H_MID) :: bl_type = 'NONE'      !< Type of a PBL turbulence parameterization scheme
    integer :: atm_var_container_typeid           
    real(rp) :: c_ip = 1.0_rp                     !< Parameter for symmetric interior penalty method in DGM
    logical :: use_delta_form = .false.           !< Flag to use delta form in the vertical implicit time integration of PBL scheme
 
    namelist /param_atmos_phy_bl/ &
      time_dt,                  &
      time_dt_unit,             &
      bl_type,                  &
      atm_var_container_typeid, &
      c_ip,                     &
      use_delta_form
 
    class(atmosmesh), pointer     :: atm_mesh
    class(meshbase), pointer      :: ptr_mesh
    class(localmesh3d), pointer :: lcmesh3d
    class(elementbase3d), pointer :: elem3d
 
    integer :: ierr
 
    integer :: qs_bl, qe_bl, qa_bl
    !-----------------------------------------------------
 
    if (.not. this%IsActivated()) return
 
    log_newline
    log_info("ATMOS_PHY_BL_setup",*) 'Setup'
 
    atm_var_container_typeid = atm_vars_container_primary_id
 
    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_atmos_phy_bl,iostat=ierr)
    if( ierr < 0 ) then !--- missing
      log_info("ATMOS_PHY_BL_setup",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
      log_error("ATMOS_PHY_BL_setup",*) 'Not appropriate names in namelist PARAM_ATMOS_PHY_BL. Check!'
      call prc_abort
    endif
    log_nml(param_atmos_phy_bl)
 
    this%atm_var_container_typeid = atm_var_container_typeid
    this%C_IP = c_ip
    this%use_delta_form = use_delta_form
        
    !- Get atmospheric mesh --------------------------------------------------
 
    call model_mesh%GetModelMesh( ptr_mesh )
    select type(model_mesh)
    class is (atmosmesh)
      atm_mesh => model_mesh
    end select
 
    !--- Register this component in the time manager
    
    call tm_parent_comp%Regist_process( 'ATMOS_PHY_BL', time_dt, time_dt_unit, & ! (in)
      this%tm_process_id )                                                       ! (out) 
    
    this%dtsec = tm_parent_comp%process_list(this%tm_process_id)%dtsec
 
    !--- Set the type of PBL turbulence parameterization
 
    select case( bl_type )
    case( 'MYNN_LEVEL2' )
      this%BL_TYPEID = bl_typeid_mynn_level2
      qs_bl = qa
      qa_bl = 0
 
      call atm_phy_bl_dgm_mynn_lv2_init( atm_mesh%ptr_mesh )
    case default
      log_error("ATMOS_PHY_BL_setup",*) 'Not appropriate PBL turbulence parameterization type. Check!'
      call prc_abort
    end select
 
    qe_bl = qs_bl + qa_bl - 1
 
    !- Initialize the variables 
    call this%vars%Init( model_mesh, qs_bl, qe_bl, qa_bl )
 
    !-
    call this%v_elem1D%Init( atm_mesh%ptr_mesh%refElem3D%PolyOrder_v, .false. ) 
 
    return
  end subroutine atmosphybl_setup
 
!> Calculate tendencies associated with PBL turbulence parameterization in atmospheric model
!!
!!
!! @param model_mesh Object to manage computational mesh of atmospheric model 
!! @param prgvars_list Object to manage prognostic variables with atmospheric dynamical core
!! @param trcvars_list Object to manage auxiliary variables 
!! @param forcing_list Object to manage forcing terms
!! @param is_update Flag to speicfy whether the tendencies are updated in this call
!!
!OCL SERIAL
  subroutine atmosphybl_calc_tendency( &
    this, model_mesh, prgvars_list, trcvars_list, &
    auxvars_list, forcing_list, is_update         )
    use scale_tracer, only: &
      tracer_advc, qa
    use scale_atm_phy_bl_dgm_mynn_lv2, only: &
      atm_phy_bl_dgm_mynn_lv2_cal_vviscdiffcoef
    use scale_atm_phy_bl_dgm_common, only: &
      atm_phy_bl_dgm_common_calc_tendency
 
    use mod_atmos_vars, only: &
      atmosvars_getlocalmeshprgvars,     &
      atmosvars_getlocalmeshphyauxvars,  &
      atmosvars_getlocalmeshqtrcvarlist, & 
      atmosvars_getlocalmeshphytends      
    use mod_atmos_phy_bl_vars, only: &
      atmosphyblvars_getlocalmeshfields_tend, &
      rhou_tp_id => atmos_phy_bl_rhou_t_id, &
      rhov_tp_id => atmos_phy_bl_rhov_t_id, &
      rhot_tp_id => atmos_phy_bl_rhot_t_id, &
      tke_id => atmos_phy_bl_diag_tke_id,   &
      nu_id => atmos_phy_bl_diag_nu_id,     &
      kh_id => atmos_phy_bl_diag_kh_id
 
    implicit none
    class(atmosphybl), intent(inout) :: this
    class(modelmeshbase), intent(in) :: model_mesh
    class(modelvarmanager), intent(inout) :: prgvars_list
    class(modelvarmanager), intent(inout) :: trcvars_list    
    class(modelvarmanager), intent(inout) :: auxvars_list
    class(modelvarmanager), intent(inout) :: forcing_list
    logical, intent(in) :: is_update
 
    class(meshbase), pointer :: mesh
    class(meshbase3d), pointer :: mesh3d
    class(localmesh3d), pointer :: lcmesh
 
    integer :: n
    integer :: ke
    integer :: iq
 
    class(localmeshfieldbase), pointer :: ddens, momx, momy, momz, drhot
    class(localmeshfieldbase), pointer :: dens_hyd, pres_hyd, rtot, cvtot, cptot
    class(localmeshfieldbase), pointer :: pres, pt
    type(localmeshfieldbaselist) :: qtrc_list(qa)
 
    class(localmeshfieldbase), pointer :: dens_tp, momx_tp, momy_tp, momz_tp, rhot_tp, rhoh_p
    type(localmeshfieldbaselist) :: rhoq_tp(qa)
    class(localmeshfieldbase), pointer :: bl_rhou_t, bl_rhov_t, bl_rhot_t
    class(localmeshfieldbase), pointer :: bl_rhoq_t
    type(localmeshfieldbaselist) :: bl_rhoq_t_list(qa)
 
    type dyn_bndinfo
      logical, allocatable :: is_bound(:,:)
    end type
    type(dyn_bndinfo), allocatable :: bnd_info(:)
    !------------------------------------------------------------------------
 
    if (.not. this%IsActivated()) return
 
    log_progress(*) 'atmosphere / physics / planetary boundary layer' 
 
    call model_mesh%GetModelMesh( mesh )
    select type(mesh)
    class is (meshbase3d)
      mesh3d => mesh
    end select
 
    !-
    if ( is_update ) then
      call prof_rapstart( 'ATM_BL_tendency', 2)
 
      allocate( bnd_info(mesh3d%LOCAL_MESH_NUM) )
 
      do n=1, mesh3d%LOCAL_MESH_NUM
        call atmosvars_getlocalmeshprgvars( n,    &
          mesh, prgvars_list, auxvars_list,       &
          ddens, momx, momy, momz, drhot,         &
          dens_hyd, pres_hyd, rtot, cvtot, cptot, &
          lcmesh                                  )
        
        call atmosvars_getlocalmeshphyauxvars( n,  &
          mesh, auxvars_list,                      &
          pres, pt )
 
        call atmosvars_getlocalmeshqtrcvarlist( n,    &
          mesh, trcvars_list,                         &
          1, qtrc_list )
 
        call atmosphyblvars_getlocalmeshfields_tend( n,   &
          mesh, this%vars%tends_manager,                  &
          bl_rhou_t, bl_rhov_t, bl_rhot_t, bl_rhoq_t_list )          
     
        !-
        allocate( bnd_info(n)%is_bound(lcmesh%refElem3D%NfpTot,lcmesh%Ne) )
        call this%dyn_bnd%Inquire_bound_flag(  bnd_info(n)%is_bound, & ! (out)
          n, lcmesh%VMapM, lcmesh%VMapP, lcmesh%VMapB,               & ! (in)
          lcmesh, lcmesh%refElem3D                                   ) ! (in)
 
        select case( this%BL_TYPEID )
        case( bl_typeid_mynn_level2 )
          call atm_phy_bl_dgm_mynn_lv2_cal_vviscdiffcoef( &
            this%vars%diagvars(nu_id)%local(n)%val,                 & ! (out)
            this%vars%diagvars(kh_id)%local(n)%val,                 & ! (out)
            this%vars%diagvars(tke_id)%local(n)%val,                & ! (out)
            ddens%val, momx%val, momy%val, momz%val, drhot%val,     & ! (in)
            dens_hyd%val, pres_hyd%val, rtot%val, pres%val, pt%val, & ! (in)
            model_mesh%DOptrMat(3), model_mesh%LiftOptrMat,         & ! (in)
            lcmesh, lcmesh%refElem3D, bnd_info(n)%is_bound          ) ! (in)
        end select
 
        call atm_phy_bl_dgm_common_calc_tendency( &
          bl_rhou_t%val, bl_rhov_t%val, bl_rhot_t%val,    & ! (out)
          bl_rhoq_t_list,                                 & ! (out)
          ddens%val, momx%val, momy%val, drhot%val,       & ! (in)
          qtrc_list,                                      & ! (in)
          pt%val, dens_hyd%val, pres_hyd%val,             & ! (in)
          this%vars%diagvars(nu_id)%local(n)%val,         & ! (in)
          this%vars%diagvars(kh_id)%local(n)%val,         & ! (in)
          model_mesh%element3D_operation,                 & ! (in)
          this%C_IP, this%dtsec,                          & ! (in)
          lcmesh, lcmesh%refElem3D, this%v_elem1D,        & ! (in)
          bnd_info(n)%is_bound, this%use_delta_form       ) ! (in)
      
      end do
 
      do n=1, mesh3d%LOCAL_MESH_NUM
        deallocate( bnd_info(n)%is_bound )
      end do
      call prof_rapend( 'ATM_BL_tendency', 2)
    end if
 
    call prof_rapstart('ATM_PHY_BL_add_tend', 2)
    do n=1, mesh%LOCAL_MESH_NUM
      call atmosvars_getlocalmeshphytends( n,        &
        mesh, forcing_list,                          &
        dens_tp, momx_tp, momy_tp, momz_tp, rhot_tp, &
        rhoh_p, rhoq_tp  )
 
      call atmosphyblvars_getlocalmeshfields_tend( n,  &
        mesh, this%vars%tends_manager,                   &
        bl_rhou_t, bl_rhov_t, bl_rhot_t, bl_rhoq_t_list, &
        lcmesh                                           )
 
      !$omp parallel private(ke, iq)
      !$omp do
      do ke=lcmesh%NeS, lcmesh%NeE
        momx_tp%val(:,ke) = momx_tp%val(:,ke) + bl_rhou_t%val(:,ke)
        momy_tp%val(:,ke) = momy_tp%val(:,ke) + bl_rhov_t%val(:,ke)
        rhot_tp%val(:,ke) = rhot_tp%val(:,ke) + bl_rhot_t%val(:,ke)
      end do
      !$omp end do    
      do iq=1, qa
        if ( .not. tracer_advc(iq) ) cycle
        !$omp do
        do ke=lcmesh%NeS, lcmesh%NeE
          rhoq_tp(iq)%ptr%val(:,ke) = rhoq_tp(iq)%ptr%val(:,ke)        &
                                    + bl_rhoq_t_list(iq)%ptr%val(:,ke)
        end do
        !$omp end do
      end do
      !$omp end parallel
    end do
    call prof_rapend('ATM_PHY_BL_add_tend', 2)
 
    return
  end subroutine atmosphybl_calc_tendency
 
!> Update variables in a component of PBL turbulence parameterization in atmospheric model
!!
!! @param model_mesh Object to manage computational mesh of atmospheric model 
!! @param prgvars_list Object to manage prognostic variables with atmospheric dynamical core
!! @param trcvars_list Object to manage auxiliary variables 
!! @param forcing_list Object to manage forcing terms
!! @param is_update Flag to speicfy whether the tendencies are updated in this call
!!
!OCL SERIAL  
  subroutine atmosphybl_update( this, model_mesh, &
    prgvars_list, trcvars_list,                   &
    auxvars_list, forcing_list, is_update         )  
    
    implicit none
    class(atmosphybl), intent(inout) :: this
    class(modelmeshbase), intent(in) :: model_mesh
    class(modelvarmanager), intent(inout) :: prgvars_list
    class(modelvarmanager), intent(inout) :: trcvars_list    
    class(modelvarmanager), intent(inout) :: auxvars_list
    class(modelvarmanager), intent(inout) :: forcing_list
    logical, intent(in) :: is_update
    !--------------------------------------------------
    return
  end subroutine atmosphybl_update
 
!> Finalize a component of PBL turbulence parameterization in atmospheric model
!!
!OCL SERIAL  
  subroutine atmosphybl_finalize( this )
    use scale_atm_phy_bl_dgm_mynn_lv2, only: &
      atm_phy_bl_dgm_mynn_lv2_final
    implicit none
    class(atmosphybl), intent(inout) :: this
 
    !--------------------------------------------------
    if (.not. this%IsActivated()) return
 
    select case ( this%BL_TYPEID )
    case( bl_typeid_mynn_level2 )
      call atm_phy_bl_dgm_mynn_lv2_final()
    end select
 
    call this%vars%Final()
    call this%v_elem1D%Final()
    return
  end subroutine atmosphybl_finalize
 
!> Set boundary conditions to PBL component in atmospheric model
!!
!! @param dyn_bnd Object to manage boundary conditions of dynamical core
!!
!OCL SERIAL
  subroutine atmosphybl_setdynbc( this, dyn_bnd )
    implicit none
    class(atmosphybl), intent(inout) :: this
    type(atmdynbnd), intent(in), target :: dyn_bnd
    !--------------------------------------------------
 
    this%dyn_bnd => dyn_bnd
 
    return
  end subroutine atmosphybl_setdynbc
!- private ------------------------------------------------
 
end module mod_atmos_phy_bl