mod_atmos_phy_bl_vars.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!> module Atmosphere / Physics / Planetary Boundary Layer Turbulence
!!
!! @par Description
!!          Container for variables with planetary boundary layer (PBL) turbulence parameterization in atmospheric model
!!
!! @author Yuta Kawai, Team SCALE
!!
!<
!-------------------------------------------------------------------------------
#include "scaleFElib.h"
module mod_atmos_phy_bl_vars
  !-----------------------------------------------------------------------------
  !
  !++ Used modules
  !
  use scale_precision
  use scale_io
  use scale_prc
  use scale_tracer, only: qa
 
  use scale_element_base, only: elementbase3d
  use scale_mesh_base, only: meshbase
  use scale_mesh_base2d, only: meshbase2d
  use scale_mesh_base3d, only: &
    meshbase3d,                              &
    dimtype_xyz  => meshbase3d_dimtypeid_xyz
  use scale_localmesh_base, only: localmeshbase
  use scale_localmesh_3d, only: localmesh3d
  use scale_localmeshfield_base, only: &
    localmeshfieldbase, localmeshfieldbaselist
  use scale_meshfield_base, only: &
    meshfieldbase, meshfield2d, meshfield3d
 
  use scale_file_restart_meshfield, only: &
    file_restart_meshfield_component
  
  use scale_meshfieldcomm_base, only: meshfieldcontainer
  
  use scale_model_var_manager, only: &
    modelvarmanager, variableinfo
  use scale_model_mesh_manager, only: modelmeshbase
    
  use mod_atmos_mesh, only: atmosmesh
 
  !-----------------------------------------------------------------------------
  implicit none
  private
 
  !-----------------------------------------------------------------------------
  !
  !++ Public type & procedures
  !
 
  !> Derived type to manage variables with planetary boundary layer (PBL) turbulence parameterization component in atmospheric model
  type, public :: atmosphyblvars
    type(meshfield3d), allocatable :: tends(:)     !< Array of tendency variables
    type(modelvarmanager) :: tends_manager         !< Object to manage tendencies
 
    type(meshfield3d), allocatable :: diagvars(:)
    type(modelvarmanager) :: diagvars_manager
 
    integer :: qs      !< Start index of tracer variables with PBL turbulence parameterization
    integer :: qe      !< End index of tracer variables with PBL turbulence parameterization
    integer :: qa      !< Number of tracer variables with PBL turbulence parameterization
 
    integer :: tends_num_tot                        !< Number of tendency variables with PBL turbulence parameterization
  contains
    procedure :: init => atmosphyblvars_init
    procedure :: final => atmosphyblvars_final
    procedure :: setup => atmosphyblvars_setup
    procedure :: history => atmosphyblvars_history
  end type atmosphyblvars
 
  public :: atmosphyblvars_getlocalmeshfields_tend
 
  !-----------------------------------------------------------------------------
  !
  !++ Public variables
  !
  integer, public, parameter :: atmos_phy_bl_rhou_t_id    = 1
  integer, public, parameter :: atmos_phy_bl_rhov_t_id    = 2
  integer, public, parameter :: atmos_phy_bl_rhot_t_id    = 3
  integer, public, parameter :: atmos_phy_bl_tends_num1   = 3 
 
  type(variableinfo), public :: atmos_phy_bl_tend_vinfo(atmos_phy_bl_tends_num1)
  DATA atmos_phy_bl_tend_vinfo / &
    variableinfo( atmos_phy_bl_rhou_t_id, 'BL_RHOU_t', 'tendency of x-momentum in BL process',           &
                  'kg/m2/s2',  3, 'XYZ',  ''                                                          ), &
    variableinfo( atmos_phy_bl_rhov_t_id, 'BL_RHOV_t', 'tendency of y-momentum in BL process',           &
                  'kg/m2/s2',  3, 'XYZ',  ''                                                          ), &
    variableinfo( atmos_phy_bl_rhot_t_id, 'BL_RHOT_t', 'tendency of rho*PT in BL process',               &
                  'kg/m3.K/s', 3, 'XYZ',  ''                                                          )  /
 
  integer, public, parameter :: atmos_phy_bl_diag_tke_id     = 1
  integer, public, parameter :: atmos_phy_bl_diag_nu_id      = 2
  integer, public, parameter :: atmos_phy_bl_diag_kh_id      = 3
  integer, public, parameter :: atmos_phy_bl_diag_num        = 3
 
  type(variableinfo) :: atmos_phy_bl_diag_vinfo(atmos_phy_bl_diag_num)
  DATA atmos_phy_bl_diag_vinfo / &
    variableinfo( atmos_phy_bl_diag_tke_id, 'TKE', 'SGS turbulence kinetic energy',   &
                  'm2/s2',  3, 'XYZ',  ''                                          ), &
    variableinfo( atmos_phy_bl_diag_nu_id, 'NU', 'eddy viscosity',                    &
                  'm2/s',  3, 'XYZ',  ''                                           ), &
    variableinfo( atmos_phy_bl_diag_kh_id, 'KH', 'eddy diffusion',                    &
                  'm2/s',  3, 'XYZ',  ''                                           )  /
 
  !-----------------------------------------------------------------------------
  !
  !++ Private procedures
  !
contains
  !> Setup an object to manage variables with a planetary boundary layer (PBL) turbulence parameterization component  
!OCL SERIAL
  subroutine atmosphyblvars_init( this, model_mesh, &
    QS_BL, QE_BL, QA_BL )
    implicit none
    class(atmosphyblvars), target, intent(inout) :: this
    class(modelmeshbase), target, intent(in) :: model_mesh
    integer, intent(in) :: qs_bl
    integer, intent(in) :: qe_bl
    integer, intent(in) :: qa_bl
    !----------------------------------------------------
 
    log_info('AtmosPhyBlVars_Init',*)
 
    this%QS = qs_bl
    this%QE = qe_bl
    this%QA = qa_bl
    return
  end subroutine atmosphyblvars_init
 
  !> Setup variable objects
!OCL SERIAL
  subroutine atmosphyblvars_setup( this, model_mesh )
    use scale_tracer, only: &
      tracer_name, tracer_desc, tracer_unit, &
      qa
    use scale_file_history, only: &
      file_history_reg
    implicit none
    class(atmosphyblvars), target, intent(inout) :: this
    class(modelmeshbase), target, intent(in) :: model_mesh
 
    integer :: iv
    integer :: iq
    integer :: n
    logical :: reg_file_hist
 
    class(atmosmesh), pointer :: atm_mesh
    class(meshbase2d), pointer :: mesh2d
    class(meshbase3d), pointer :: mesh3d
 
    type(variableinfo) :: qtrc_tp_vinfo_tmp
    type(variableinfo) :: qtrc_vterm_vinfo_tmp
    !----------------------------------------------------
 
    this%TENDS_NUM_TOT = atmos_phy_bl_tends_num1 + qa
 
    !- Initialize auxiliary and diagnostic variables
 
    nullify( atm_mesh )
    select type(model_mesh)
    class is (atmosmesh)
      atm_mesh => model_mesh
    end select
    mesh3d => atm_mesh%ptr_mesh
    
    call mesh3d%GetMesh2D( mesh2d )
 
    !- Initialize tendency variables
 
    call this%tends_manager%Init()
    allocate( this%tends(this%TENDS_NUM_TOT) )
 
    reg_file_hist = .true.    
    do iv=1, atmos_phy_bl_tends_num1
      call this%tends_manager%Regist( &
        atmos_phy_bl_tend_vinfo(iv), mesh3d,            &
        this%tends(iv), reg_file_hist, fill_zero=.true. )         
    end do
 
    qtrc_tp_vinfo_tmp%ndims    = 3
    qtrc_tp_vinfo_tmp%dim_type = 'XYZ'
    qtrc_tp_vinfo_tmp%STDNAME  = ''
    
    do iq = 1, qa
      iv = atmos_phy_bl_tends_num1 + iq 
      qtrc_tp_vinfo_tmp%keyID = iv
      qtrc_tp_vinfo_tmp%NAME  = 'BL_'//trim(tracer_name(iq))//'_t'
      qtrc_tp_vinfo_tmp%DESC  = 'tendency of rho*'//trim(tracer_name(iq))//' in BL process'
      qtrc_tp_vinfo_tmp%UNIT  = 'kg/m3/s'
 
      reg_file_hist = .true.
      call this%tends_manager%Regist( &
        qtrc_tp_vinfo_tmp, mesh3d,                      & 
        this%tends(iv), reg_file_hist, fill_zero=.true. )
    end do
 
    !- Initialize diagnostic variables
    
    call this%diagvars_manager%Init()
    allocate( this%diagvars(atmos_phy_bl_diag_num) )
 
    reg_file_hist = .true.
    do iv=1, atmos_phy_bl_diag_num
      call this%diagvars_manager%Regist( &
        atmos_phy_bl_diag_vinfo(iv), mesh3d,               &
        this%diagvars(iv), reg_file_hist, fill_zero=.true. )
    end do
 
    return
  end subroutine atmosphyblvars_setup
 
  !> Finalize an object to manage variables with planetary boundary layer (PBL) turbulence parameterization component  
!OCL SERIAL
  subroutine atmosphyblvars_final( this )
    implicit none
    class(atmosphyblvars), intent(inout) :: this
    !----------------------------------------------------
 
    log_info('AtmosPhyBlVars_Final',*)
 
    call this%tends_manager%Final()
    deallocate( this%tends )
 
    call this%diagvars_manager%Final()
    deallocate( this%diagvars )
    return
  end subroutine atmosphyblvars_final
 
!OCL SERIAL
  subroutine atmosphyblvars_getlocalmeshfields_tend( domID, mesh, bl_tends_list, &
    bl_RHOU_t, bl_RHOV_t, bl_RHOT_t, bl_RHOQ_t,                                  &
    lcmesh3D                                                                     &
    )
 
    use scale_mesh_base, only: meshbase
    use scale_meshfield_base, only: meshfieldbase
    implicit none
 
    integer, intent(in) :: domid
    class(meshbase), intent(in) :: mesh
    class(modelvarmanager), intent(inout) :: bl_tends_list
    class(localmeshfieldbase), pointer, intent(out) :: bl_rhou_t
    class(localmeshfieldbase), pointer, intent(out) :: bl_rhov_t
    class(localmeshfieldbase), pointer, intent(out) :: bl_rhot_t
    type(localmeshfieldbaselist), intent(out), optional :: bl_rhoq_t(:)
    class(localmesh3d), pointer, intent(out), optional :: lcmesh3d
 
    class(meshfieldbase), pointer :: field   
    class(localmeshbase), pointer :: lcmesh
 
    integer :: iq
    !-------------------------------------------------------
 
    !--
    call bl_tends_list%Get(atmos_phy_bl_rhou_t_id, field)
    call field%GetLocalMeshField(domid, bl_rhou_t)
 
    call bl_tends_list%Get(atmos_phy_bl_rhov_t_id, field)
    call field%GetLocalMeshField(domid, bl_rhov_t)
 
    call bl_tends_list%Get(atmos_phy_bl_rhot_t_id, field)
    call field%GetLocalMeshField(domid, bl_rhot_t)
 
    !---
    if ( present(bl_rhoq_t) ) then
      do iq = 1, size(bl_rhoq_t)
        call bl_tends_list%Get(atmos_phy_bl_tends_num1 + iq, field)
        call field%GetLocalMeshField(domid, bl_rhoq_t(iq)%ptr)
      end do    
    end if
 
    if (present(lcmesh3d)) then
      call mesh%GetLocalMesh( domid, lcmesh )
      nullify( lcmesh3d )
 
      select type(lcmesh)
      type is (localmesh3d)
        if (present(lcmesh3d)) lcmesh3d => lcmesh
      end select
    end if
 
    return
  end subroutine atmosphyblvars_getlocalmeshfields_tend
 
  !> Put data with BL variables to history file
!OCL SERIAL
  subroutine atmosphyblvars_history( this )
    use scale_file_history_meshfield, only: file_history_meshfield_put
    implicit none
    class(atmosphyblvars), intent(inout) :: this
 
    integer :: v
    integer :: hst_id
    !----------------------------------------------------
 
    do v=1, this%TENDS_NUM_TOT
      hst_id = this%tends(v)%hist_id
      if ( hst_id > 0 ) call file_history_meshfield_put( hst_id, this%tends(v) )
    end do
 
    do v=1, atmos_phy_bl_diag_num
      hst_id = this%diagvars(v)%hist_id
      if ( hst_id > 0 ) call file_history_meshfield_put( hst_id, this%diagvars(v) )
    end do    
 
    return
  end subroutine atmosphyblvars_history
 
end module mod_atmos_phy_bl_vars