mod_atmos_phy_cp.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!> module Atmosphere / Physics / Cumulus Parameterization
!!
!! @par Description
!!          Module for cumulus parameterization
!!
!! @author Yuta Kawai, Team SCALE
!!
!<
!-------------------------------------------------------------------------------
#include "scaleFElib.h"
module mod_atmos_phy_cp
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !  
  use scale_precision
  use scale_prc
  use scale_io
  use scale_prof
  use scale_const, only: &
    undef8 => const_undef8
 
  use scale_element_line, only: lineelement
 
  use scale_mesh_base, only: meshbase
  use scale_mesh_base2d, only: meshbase2d
  use scale_mesh_base3d, only: meshbase3d
 
  use scale_localmesh_base, only: localmeshbase
  use scale_localmesh_2d, only: localmesh2d
  use scale_localmesh_3d, only: localmesh3d
  use scale_element_base, only: elementbase, &
    elementbase1d, elementbase2d, elementbase3d
 
  use scale_meshfield_base, only: &
    meshfieldbase, meshfield3d
  use scale_localmeshfield_base, only: &
    localmeshfieldbase, localmeshfieldbaselist
 
  use scale_model_mesh_manager, only: modelmeshbase
  use scale_model_var_manager, only: modelvarmanager
  use scale_model_component_proc, only:  modelcomponentproc
 
  use mod_atmos_phy_cp_vars, only: atmosphycpvars
 
  use mod_atmos_vars_container, only: &
    atmosvarscontainer
 
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public type & procedure
  !
 
  !> Derived type to manage a component of cumulus parameterization in atmospheric model
  !!
  type, extends(modelcomponentproc), public :: atmosphycp
    integer :: cp_typeid         !< Type id of cumulus parameterization scheme
    type(atmosphycpvars) :: vars !< Object to manage variables with cumulus parameterization
 
    integer :: atm_var_container_typeid     !< Type ID of variable container for cumulus parameterization
 
    real(rp) :: dtsec !< Timestep for cumulus parameterization
 
    type(lineelement) :: v_elem1d
  contains
    procedure :: setup => atmosphycp_setup
    procedure :: calc_tendency => atmosphycp_calc_tendency
    procedure :: update => atmosphycp_update
    procedure :: finalize => atmosphycp_finalize
  end type atmosphycp
 
  !-----------------------------------------------------------------------------
  !++ Public parameters & variables
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  integer, parameter :: cp_typeid_mconv_adjustment = 1 !< Type ID of a moist convective adjustment scheme
  
contains
 
  !> Setup a component of cumulus parameterization in atmospheric model
  !!
  !! @param model_mesh Object to manage computational mesh of atmospheric model 
  !! @param tm_parent_comp Object to mange a temporal scheme in a parent component
  !!
  subroutine atmosphycp_setup( this, model_mesh, tm_parent_comp )
    use scale_atmos_hydrometeor, only: &
       n_hyd    
    use mod_atmos_mesh, only: atmosmesh
    use scale_time_manager, only: time_manager_component
    use mod_atmos_vars, only: atm_vars_container_primary_id
 
    use scale_atm_phy_cp_dgm_mconv_adjustment, only: &
      atm_phy_cp_dgm_mconv_adjustment_setup
    implicit none
    class(atmosphycp), intent(inout) :: this
    class(modelmeshbase), target, intent(in) :: model_mesh
    class(time_manager_component), intent(inout) :: tm_parent_comp
 
    real(dp) :: time_dt                             = undef8 !< Timestep for cumulus parameterization
    character(len=H_SHORT) :: time_dt_unit          = 'SEC'  !< Unit of timestep
 
    character(len=H_MID) :: cp_type = 'NONE'                 !< Type of a cumulus parameterization scheme
    integer :: atm_var_container_typeid                      !< Type ID of variable container for cumulus parameterization
 
    namelist /param_atmos_phy_cp/ &
      time_dt,             &
      time_dt_unit,        &
      cp_type,             &
      atm_var_container_typeid
 
    class(atmosmesh), pointer     :: atm_mesh
    class(meshbase), pointer      :: ptr_mesh
    class(localmesh3d), pointer :: lcmesh3d
    class(elementbase3d), pointer :: elem3d
 
    integer :: ierr
    !-----------------------------------------------------
 
    if (.not. this%IsActivated()) return
 
    log_newline
    log_info("ATMOS_PHY_CP_setup",*) 'Setup'
 
    atm_var_container_typeid = atm_vars_container_primary_id
 
    !--- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_atmos_phy_cp,iostat=ierr)
    if( ierr < 0 ) then !--- missing
      log_info("ATMOS_PHY_CP_setup",*) 'Not found namelist. Default used.'
    elseif( ierr > 0 ) then !--- fatal error
      log_error("ATMOS_PHY_CP_setup",*) 'Not appropriate names in namelist PARAM_ATMOS_PHY_CP. Check!'
      call prc_abort
    endif
    log_nml(param_atmos_phy_cp)
 
    this%atm_var_container_typeid = atm_var_container_typeid
    
    !- Get atmospheric mesh --------------------------------------------------
 
    call model_mesh%GetModelMesh( ptr_mesh )
    select type(model_mesh)
    class is (atmosmesh)
      atm_mesh => model_mesh
    end select
 
    !--- Register this component in the time manager
    
    call tm_parent_comp%Regist_process( 'ATMOS_PHY_CP', time_dt, time_dt_unit, & ! (in)
      this%tm_process_id )                                                       ! (out) 
 
    this%dtsec = tm_parent_comp%process_list(this%tm_process_id)%dtsec
 
    !--- Set the type of cumulus parameterization
 
    select case( cp_type )
    case( 'MOIST_CONV_ADJUSTMENT' )
      this%CP_TYPEID = cp_typeid_mconv_adjustment
      call atm_phy_cp_dgm_mconv_adjustment_setup()
    case default
      log_error("ATMOS_PHY_CP_setup",*) 'Not appropriate cumulus parameterization type. Check!'
      call prc_abort
    end select
 
    !- Initialize the variables 
    call this%vars%Init( model_mesh )
 
    !-
    call this%v_elem1D%Init( atm_mesh%ptr_mesh%refElem3D%PolyOrder_v, .false. ) 
 
    return
  end subroutine atmosphycp_setup
 
  !> Calculate tendencies associated with cumulus parameterization in atmospheric model
  !!
  !!
  !! @param model_mesh Object to manage computational mesh of atmospheric model 
  !! @param prgvars_list Object to manage prognostic variables with atmospheric dynamical core
  !! @param trcvars_list Object to manage auxiliary variables 
  !! @param forcing_list Object to manage forcing terms
  !! @param is_update Flag to speicfy whether the tendencies are updated in this call
  !!
!OCL SERIAL
  subroutine atmosphycp_calc_tendency( &
    this, model_mesh, prgvars_list, trcvars_list, &
    auxvars_list, forcing_list, is_update         )
    use scale_tracer, only: &
      qa
    use scale_atm_phy_cp_dgm_mconv_adjustment, only: &
      atm_phy_cp_dgm_mconv_adjustment_calc_tendency
    
    use mod_atmos_vars, only: &
      atmosvars_getlocalmeshprgvars,     &
      atmosvars_getlocalmeshphyauxvars,  &
      atmosvars_getlocalmeshqtrcvarlist, & 
      atmosvars_getlocalmeshphytends,    &
      atmosvars_getlocalmeshqtrc_qv
    use mod_atmos_phy_cp_vars, only: &
      atmosphycpvars_getlocalmeshfields_tend, &
      sflx_rain_id => atmos_phy_cp_aux2d_sflx_rain_id, &
      sflx_engi_id => atmos_phy_cp_aux2d_sflx_engi_id
    implicit none
    class(atmosphycp), intent(inout) :: this
    class(modelmeshbase), intent(in) :: model_mesh
    class(modelvarmanager), intent(inout) :: prgvars_list
    class(modelvarmanager), intent(inout) :: trcvars_list    
    class(modelvarmanager), intent(inout) :: auxvars_list
    class(modelvarmanager), intent(inout) :: forcing_list
    logical, intent(in) :: is_update
 
    class(meshbase), pointer :: mesh
    class(meshbase3d), pointer :: mesh3d
    class(localmesh3d), pointer :: lcmesh
 
    integer :: n
    integer :: ke
    integer :: iq
 
    class(localmeshfieldbase), pointer :: ddens, momx, momy, momz, drhot, qv
    class(localmeshfieldbase), pointer :: dens_hyd, pres_hyd, rtot, cvtot, cptot
    class(localmeshfieldbase), pointer :: pres, pt
 
    class(localmeshfieldbase), pointer :: dens_tp, momx_tp, momy_tp, momz_tp, rhot_tp, rhoh_p
    class(localmeshfieldbase), pointer :: rhoq_tp
    class(localmeshfieldbase), pointer :: cp_dens_t, cp_rhot_t, cp_rhoqv_t
    !------------------------------------------------------------------------
 
    if (.not. this%IsActivated()) return
 
    log_progress(*) 'atmosphere / physics / cumulus parameterization' 
 
    call model_mesh%GetModelMesh( mesh )
    select type(mesh)
    class is (meshbase3d)
      mesh3d => mesh
    end select
 
    !-
    if ( is_update ) then
      call prof_rapstart( 'ATM_CP_tendency', 2)
      do n=1, mesh3d%LOCAL_MESH_NUM
        call atmosvars_getlocalmeshprgvars( n,    &
          mesh, prgvars_list, auxvars_list,       &
          ddens, momx, momy, momz, drhot,         &
          dens_hyd, pres_hyd, rtot, cvtot, cptot, &
          lcmesh                                  )
        
        call atmosvars_getlocalmeshphyauxvars( n,  &
          mesh, auxvars_list,                      &
          pres, pt )
 
        call atmosvars_getlocalmeshqtrc_qv( n, &
          mesh, trcvars_list, forcing_list,    &
          qv )
 
        call atmosphycpvars_getlocalmeshfields_tend( n, &
          mesh, this%vars%tends_manager,            &
          cp_dens_t, cp_rhot_t, cp_rhoqv_t          )
 
        select case( this%CP_TYPEID )
        case( cp_typeid_mconv_adjustment )
          call atm_phy_cp_dgm_mconv_adjustment_calc_tendency( &
            cp_dens_t%val, cp_rhot_t%val, cp_rhoqv_t%val,     & ! (out)
            this%vars%auxvars2D(sflx_rain_id)%local(n)%val,   & ! (out)
            this%vars%auxvars2D(sflx_engi_id)%local(n)%val,   & ! (out)
            ddens%val, drhot%val, qv%val, pt%val, pres%val,   & ! (in)
            dens_hyd%val, rtot%val, cptot%val, this%dtsec,    & ! (in)
            lcmesh, lcmesh%refElem3D, this%v_elem1D           ) ! (in)
        end select
      end do
 
      call prof_rapend( 'ATM_CP_tendency', 2)
    end if
 
    call prof_rapstart('ATM_PHY_CP_add_tend', 2)
    do n=1, mesh%LOCAL_MESH_NUM
      call atmosvars_getlocalmeshphytends( n,        &
        mesh, forcing_list,                          &
        dens_tp, momx_tp, momy_tp, momz_tp, rhot_tp, &
        rhoh_p )
 
      call atmosvars_getlocalmeshqtrc_qv( n, &
        mesh, trcvars_list, forcing_list,    &
        qv, rhoq_tp )
      
      call atmosphycpvars_getlocalmeshfields_tend( n,  &
        mesh, this%vars%tends_manager,                 &
        cp_dens_t, cp_rhot_t, cp_rhoqv_t,              &
        lcmesh                                         )
      
      !$omp parallel private(ke)
      !$omp do
      do ke=lcmesh%NeS, lcmesh%NeE
        dens_tp%val(:,ke) = dens_tp%val(:,ke) + cp_dens_t%val(:,ke)
        rhot_tp%val(:,ke) = rhot_tp%val(:,ke) + cp_rhot_t%val(:,ke)
        rhoq_tp%val(:,ke) = rhoq_tp%val(:,ke) + cp_rhoqv_t%val(:,ke)
      end do
      !$omp end parallel
    end do
    call prof_rapend('ATM_PHY_CP_add_tend', 2)
 
    return
  end subroutine atmosphycp_calc_tendency
 
!> Update variables in a component of cumulus parameterization in atmospheric model
!!
!! @param model_mesh Object to manage computational mesh of atmospheric model 
!! @param prgvars_list Object to manage prognostic variables with atmospheric dynamical core
!! @param trcvars_list Object to manage auxiliary variables 
!! @param forcing_list Object to manage forcing terms
!! @param is_update Flag to speicfy whether the tendencies are updated in this call
!!
!OCL SERIAL  
  subroutine atmosphycp_update( this, model_mesh, &
    prgvars_list, trcvars_list,                   &
    auxvars_list, forcing_list, is_update         )  
    
    implicit none
    class(atmosphycp), intent(inout) :: this
    class(modelmeshbase), intent(in) :: model_mesh
    class(modelvarmanager), intent(inout) :: prgvars_list
    class(modelvarmanager), intent(inout) :: trcvars_list    
    class(modelvarmanager), intent(inout) :: auxvars_list
    class(modelvarmanager), intent(inout) :: forcing_list
    logical, intent(in) :: is_update
    !--------------------------------------------------
    return
  end subroutine atmosphycp_update
 
!> Finalize a component of cumulus parameterization in atmospheric model
!!
!OCL SERIAL  
  subroutine atmosphycp_finalize( this )
    use scale_atm_phy_cp_dgm_mconv_adjustment, only: &
      atm_phy_cp_dgm_mconv_adjustment_finalize
    implicit none
    class(atmosphycp), intent(inout) :: this
 
    !--------------------------------------------------
    if (.not. this%IsActivated()) return
 
    select case ( this%CP_TYPEID )
    case( cp_typeid_mconv_adjustment )
      call atm_phy_cp_dgm_mconv_adjustment_finalize()
    end select
 
    call this%vars%Final()
    call this%v_elem1D%Final()
    return
  end subroutine atmosphycp_finalize
 
!- private ------------------------------------------------
 
end module mod_atmos_phy_cp