mod_ocean_dyn_vars.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!> module Ocean / Dynamics
!!
!! @par Description
!!          Container for variables with dynamics component
!!
!! @author Yuta Kawai, Team SCALE
!!
!<
!-------------------------------------------------------------------------------
#include "scaleFElib.h"
module mod_ocean_dyn_vars
  !-----------------------------------------------------------------------------
  !
  !++ Used modules
  !
  use scale_precision
  use scale_io
  use scale_prc
 
  use scale_element_base, only: elementbase3d
  use scale_localmesh_base, only: localmeshbase
  use scale_localmesh_2d, only: localmesh2d
  use scale_localmesh_3d, only: localmesh3d
  use scale_mesh_base, only: meshbase
  use scale_mesh_base2d, only: meshbase2d  
  use scale_mesh_base3d, only: meshbase3d
 
  use scale_meshfield_base, only: meshfield3d, meshfield2d
  use scale_localmeshfield_base, only: localmeshfieldbase
 
  use scale_meshfieldcomm_base, only: meshfieldcontainer
  
  use scale_model_var_manager, only: &
    modelvarmanager, variableinfo
  use scale_model_meshbase_manager, only: modelmeshbase
 
  use mod_ocean_mesh, only: oceanmesh
    
  !-----------------------------------------------------------------------------
  implicit none
  private
 
  !-----------------------------------------------------------------------------
  !
  !++ Public type & procedures
  !
 
  !> Derived type to manage variables with oceanic dynamics component
  type, public :: oceandynvars
    type(meshfield2d), allocatable :: aux_vars2d(:) !< Array of 2D auxiliary variables
    type(modelvarmanager) :: auxvars2d_manager      !< Object to manage 2D auxiliary variables
  contains
    procedure :: init => oceandynvars_init
    procedure :: final => oceandynvars_final
    procedure :: history => oceandynvars_history
  end type oceandynvars
 
  public :: oceandynauxvars_getlocalmeshfields
  !public :: OceanDynVars_GetLocalMeshFields_analysis
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
 
  !-
  integer, public, parameter :: ocean_dyn_auxvars2d_num          = 1
  integer, public, parameter :: ocean_dyn_auxvars2d_coriolis_id  = 1
 
  type(variableinfo), public :: ocean_dyn_auxvars2d_vinfo(ocean_dyn_auxvars2d_num)
  DATA ocean_dyn_auxvars2d_vinfo / &
    variableinfo( ocean_dyn_auxvars2d_coriolis_id, 'CORIOLIS', 'coriolis parameter',  &
                  's-1',  2, 'XY',  ''                                             )  /   
  !-----------------------------------------------------------------------------
  !
  !++ Private procedures
  !
  !-------------------
 
contains
 
!> Setup an object to manage variables with oceanic dynamics component
!!
!! @param model_mesh Object to manage computational mesh of oceanic model 
!!
!OCL SERIAL
  subroutine oceandynvars_init( this, model_mesh )
    use scale_localmeshfield_base, only: local_meshfield_type_nodes_faceval
    implicit none
    class(oceandynvars), target, intent(inout) :: this
    class(modelmeshbase), target, intent(in) :: model_mesh
 
    integer :: v
    integer :: n
    logical :: reg_file_hist
 
    class(oceanmesh), pointer :: ocean_mesh
    class(meshbase2d), pointer :: mesh2d
    class(meshbase3d), pointer :: mesh3d
 
    !--------------------------------------------------
 
    log_info('OceanDynVars_Init',*)
    
    nullify( ocean_mesh )
    select type(model_mesh)
    class is (oceanmesh)
      ocean_mesh => model_mesh
    end select
    mesh3d => ocean_mesh%ptr_mesh
    
    call mesh3d%GetMesh2D( mesh2d )
 
    !- Initialize 2D auxiliary variables
 
    call this%AUXVARS2D_manager%Init()
    allocate( this%AUX_VARS2D(ocean_dyn_auxvars2d_num) )
 
    reg_file_hist = .false.    
    do v = 1, ocean_dyn_auxvars2d_num
      call this%AUXVARS2D_manager%Regist(                   &
        ocean_dyn_auxvars2d_vinfo(v), mesh2d,               & ! (in) 
        this%AUX_VARS2D(v), reg_file_hist                   ) ! (out)
      
      do n = 1, mesh3d%LOCAL_MESH_NUM
        this%AUX_VARS2D(v)%local(n)%val(:,:) = 0.0_rp
      end do         
    end do
 
    return
  end subroutine oceandynvars_init
 
!> Finalize an object to manage variables with oceanic dynamics component
  subroutine oceandynvars_final( this )
    implicit none
    class(oceandynvars), intent(inout) :: this
 
    !--------------------------------------------------
 
    log_info('OceanDynVars_Final',*)
 
    call this%AUXVARS2D_manager%Final()
    deallocate( this%AUX_VARS2D )
    
    !call this%ANALYSISVARS_manager%Final()
 
    return
  end subroutine oceandynvars_final
 
  !> Output history files for variables with oceanic dynamics component
  subroutine oceandynvars_history( this )
    use scale_file_history_meshfield, only: file_history_meshfield_put
    implicit none
    class(oceandynvars), intent(in) :: this
    !-------------------------------------------------------------------------
    return
  end subroutine oceandynvars_history
 
  subroutine oceandynauxvars_getlocalmeshfields( domID, mesh, auxvars_list, &
    Coriolis,                                                               &
    lcmesh3D                                                                &
    )
 
    use scale_mesh_base, only: meshbase
    use scale_meshfield_base, only: meshfieldbase
    implicit none
 
    integer, intent(in) :: domid
    class(meshbase), intent(in) :: mesh
    class(modelvarmanager), intent(inout) :: auxvars_list
    class(localmeshfieldbase), pointer, intent(out) :: coriolis
    class(localmesh3d), pointer, intent(out), optional :: lcmesh3d
 
    class(meshfieldbase), pointer :: field   
    class(localmeshbase), pointer :: lcmesh
    !-------------------------------------------------------
 
    !--
    call auxvars_list%Get(ocean_dyn_auxvars2d_coriolis_id, field)
    call field%GetLocalMeshField(domid, coriolis)
    !---
    
    if (present(lcmesh3d)) then
      call mesh%GetLocalMesh( domid, lcmesh )
      nullify( lcmesh3d )
 
      select type(lcmesh)
      type is (localmesh3d)
        if (present(lcmesh3d)) lcmesh3d => lcmesh
      end select
    end if
 
    return
  end subroutine oceandynauxvars_getlocalmeshfields
end module mod_ocean_dyn_vars