scale_atm_phy_rd_dgm_common.F90

Go to the documentation of this file.

!> module FElib / Atmosphere / Physics radiation
!!
!! @par Description
!!      Common module for radiation process
!!
!! @author Yuta Kawai, Team SCALE
!<
!-------------------------------------------------------------------------------
#include "scaleFElib.h"
module scale_atm_phy_rd_dgm_common
  !-----------------------------------------------------------------------------
  !
  !++ Used modules
  !
  use scale_precision
  use scale_io
  use scale_prc
  use scale_prof
 
  use scale_atmos_phy_rd_common, only: &
    i_up, i_dn, i_lw, i_sw
  
  use scale_element_base, only: &
    elementbase1d, elementbase2d, elementbase3d
  use scale_element_hexahedral, only: hexahedralelement
  use scale_localmesh_2d, only: localmesh2d  
  use scale_localmesh_3d, only: localmesh3d
  use scale_mesh_base3d, only: meshbase3d
  use scale_localmeshfield_base, only: localmeshfield3d
  use scale_meshfield_base, only: meshfield3d
 
  use scale_element_operation_base, only: elementoperationbase3d
 
  !-----------------------------------------------------------------------------
  implicit none
  private  
  !-----------------------------------------------------------------------------
  !
  !++ Public type & procedure
  !
  public :: atm_phy_rd_dgm_calc_heating
  
  !-----------------------------------------------------------------------------
  !++ Public parameters & variables
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !  
contains
!OCL SERIAL
  subroutine atm_phy_rd_dgm_calc_heating( RHOH, &
    flux_rad, DDENS, DENS_hyd, CVtot, &
    lcmesh, elem3D, elem2D, &
    element3D_operation,  &
    TEMP_t )
    implicit none
    class(localmesh3d), intent(in) :: lcmesh
    class(elementbase3d), intent(in) :: elem3d
    class(elementbase2d), intent(in) :: elem2d
    real(rp), intent(out) :: rhoh(elem3d%np,lcmesh%nea)
    real(rp), intent(in) :: flux_rad(elem3d%np,lcmesh%ne,2,2)
    real(rp), intent(in) :: ddens(elem3d%np,lcmesh%nea)
    real(rp), intent(in) :: dens_hyd(elem3d%np,lcmesh%nea)
    real(rp), intent(in) :: cvtot(elem3d%np,lcmesh%nea)   
    class(elementoperationbase3d), intent(in) :: element3d_operation
    real(rp), intent(out), optional :: temp_t(elem3d%np,lcmesh%nea,2)
 
    integer :: ke
    real(rp) :: fz_lw(elem3d%np)
    real(rp) :: fz_sw(elem3d%np)
    real(rp) :: dens(elem3d%np)
 
    logical :: cal_temp_t
    !------------------------------------------------------------------------------
 
    if (present(temp_t)) then
      cal_temp_t = .true.
    else
      cal_temp_t = .false.
    end if
 
    !$omp parallel do private(Fz_LW, Fz_SW, DENS)
    do ke=lcmesh%NeS, lcmesh%NeE
      call element3d_operation%Dz( flux_rad(:,ke,i_lw,i_up) - flux_rad(:,ke,i_lw,i_dn), fz_lw )
      call element3d_operation%Dz( flux_rad(:,ke,i_sw,i_up) - flux_rad(:,ke,i_sw,i_dn), fz_sw )
 
      rhoh(:,ke) = - lcmesh%Escale(:,ke,3,3) * ( fz_lw(:) + fz_sw(:) )
 
      if ( cal_temp_t ) then
        dens(:) = dens_hyd(:,ke) + ddens(:,ke)
        temp_t(:,ke,1) = - lcmesh%Escale(:,ke,3,3) * fz_lw(:)  / ( dens(:) * cvtot(:,ke) )
        temp_t(:,ke,2) = - lcmesh%Escale(:,ke,3,3) * fz_sw(:)  / ( dens(:) * cvtot(:,ke) )
      end if
    end do
 
    return
  end subroutine atm_phy_rd_dgm_calc_heating
end module scale_atm_phy_rd_dgm_common