mod_cpl_vars.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!> module Coupler / Variables
!!
!! @par Description
!!          Module to manage variables with coupler component
!!
!! @author Yuta Kawai, Team SCALE
!!
!<
!-------------------------------------------------------------------------------
#include "scaleFElib.h"
module mod_cpl_vars
  !-----------------------------------------------------------------------------
  !
  !++ Used modules
  !
  use scale_precision
  use scale_io
  use scale_prc
  use scale_debug
 
  use scale_element_base, only: &
    elementbase, elementbase2d, elementbase3d
  use scale_mesh_base, only: meshbase
  use scale_mesh_base2d, only: &
    meshbase2d
  use scale_mesh_base3d, only: &
    meshbase3d,                              &
    dimtype_xy  => meshbase3d_dimtypeid_xy,  &
    dimtype_xyz  => meshbase3d_dimtypeid_xyz
 
  use scale_localmesh_base, only: localmeshbase
  use scale_localmesh_2d, only: localmesh2d
  use scale_localmesh_3d, only: localmesh3d
  use scale_localmeshfield_base, only: &
    localmeshfieldbase, localmeshfieldbaselist
  use scale_meshfield_base, only: &
    meshfieldbase, meshfield2d, meshfield3d, meshfield3dlist
  !-----------------------------------------------------------------------------
  implicit none
  private
 
  !-----------------------------------------------------------------------------
  !
  !++ Public type & procedures
  !
  !> Derived type to manage variables with coupler component
  type, public :: couplervars
    type(meshfield2d), allocatable :: ocn_vars(:)
 
    type(meshfield2d), allocatable :: ocn_atm_vars(:)
 
    real(rp) :: cnt_putatm_ocn  !< Counter for putting ATM variables to OCN component
    real(rp) :: cnt_putocn_atm  !< Counter for putting OCN variables to ATM component
 
    class(meshbase3d), pointer :: mesh3d_atm => null()
    class(meshbase2d), pointer :: mesh2d_atm => null()
    class(meshbase2d), pointer :: mesh2d_ocn => null()
  contains
    procedure :: init => couplervars_init
    procedure :: final => couplervars_final
    procedure :: putatm => couplervars_putatm
    procedure :: putocn => couplervars_putocn
    procedure :: get_sfc_atm => couplervars_get_sfc_atm
    procedure :: get_atm_ocn => couplervars_get_atm_ocn
    !-
    procedure, private :: putatm_lc => putatm_local
    procedure, private :: putocn_lc => putocn_local
    procedure, private :: get_sfc_atm_lc => get_sfc_atm_local
    procedure, private :: get_atm_ocn_lc => get_atm_ocn_local
  end type couplervars
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
 
  ! Input from ocean component
  integer, parameter, public :: ocn_sfc_temp_id   = 1
  integer, parameter, public :: ocn_sflx_mw_id    = 2
  integer, parameter, public :: ocn_sflx_mu_id    = 3
  integer, parameter, public :: ocn_sflx_mv_id    = 4
  integer, parameter, public :: ocn_sflx_sh_id    = 5
  integer, parameter, public :: ocn_sflx_lh_id    = 6
  integer, parameter, public :: ocn_sflx_qv_id    = 7
  integer, parameter, public :: ocn_sfc_albedo_id = 8
  integer, parameter, public :: ocn_var_num       = 8
 
  ! Output to ocean component
  integer, parameter, public :: ocn_atm_sfc_dens_id    = 1
  integer, parameter, public :: ocn_atm_sfc_pres_id    = 2
  integer, parameter, public :: ocn_atm_temp_id        = 3
  integer, parameter, public :: ocn_atm_pres_id        = 4
  integer, parameter, public :: ocn_atm_w_id           = 5
  integer, parameter, public :: ocn_atm_u_id           = 6
  integer, parameter, public :: ocn_atm_v_id           = 7
  integer, parameter, public :: ocn_atm_qv_id          = 8
  integer, parameter, public :: ocn_atm_sflx_rd_sw_dir = 9
  integer, parameter, public :: ocn_atm_sflx_rd_lw_dif = 10
  integer, parameter, public :: ocn_atm_sflx_engi      = 11
  integer, parameter, public :: ocn_atm_var_num        = 11
 
  !-----------------------------------------------------------------------------
  !
  !++ Private procedures & variables
  !
 
contains
 
!OCL SERIAL
  subroutine couplervars_init(this, &
    mesh3D_atm, mesh2D_atm, mesh2D_ocn)
    implicit none
    class(couplervars), intent(inout) :: this
    class(meshbase3d), intent(in), target :: mesh3d_atm
    class(meshbase2d), intent(in), target :: mesh2d_atm
    class(meshbase2d), intent(in), target :: mesh2d_ocn
 
    integer :: iv
    !--------------------------------------------------------------------------------
 
    allocate( this%OCN_vars(ocn_var_num) )
    do iv=1, ocn_var_num
      call this%OCN_vars(iv)%Init( "", "", mesh2d_ocn )
    end do
 
    allocate( this%OCN_atm_vars(ocn_atm_var_num) )
    do iv=1, ocn_atm_var_num
      call this%OCN_atm_vars(iv)%Init( "", "", mesh2d_atm )
    end do
 
    !-
    this%mesh3D_atm => mesh3d_atm
    this%mesh2D_atm => mesh2d_atm
    this%mesh2D_ocn => mesh2d_ocn
    
    !-
    this%CNT_putATM_OCN = 0.0_rp
    this%CNT_putOCN_ATM = 0.0_rp
 
    return
  end subroutine couplervars_init
 
!OCL SERIAL
  subroutine couplervars_final(this)
    implicit none
    class(couplervars), intent(inout) :: this
 
    integer :: iv
    !--------------------------------------------------------------------------------
    do iv=1, ocn_var_num
      call this%OCN_vars(iv)%Final()
    end do
    deallocate( this%OCN_vars )
 
    do iv=1, ocn_atm_var_num
      call this%OCN_atm_vars(iv)%Final()
    end do
    deallocate( this%OCN_atm_vars )
    return
  end subroutine couplervars_final
 
  !> Put ATM variables to CPL buffer for OCN component
  subroutine couplervars_putatm( this, &
    ATM_DDENS, ATM_MOMZ, ATM_MOMX, ATM_MOMY, ATM_QV, &
    ATM_PRES, ATM_Rtot, ATM_DENS_hyd, &
    SFLX_RAD_SW_dir_dn, SFLX_RAD_LW_dif_dn, SFLX_ENGI, &
    countup )
    use mod_atmos_vars_container, only: atmosvarscontainer
    implicit none
    class(couplervars), intent(inout) :: this
    type(meshfield3d), intent(in), target :: atm_ddens
    type(meshfield3d), intent(in), target :: atm_momz
    type(meshfield3d), intent(in), target :: atm_momx
    type(meshfield3d), intent(in), target :: atm_momy
    type(meshfield3d), intent(in), target :: atm_qv
    type(meshfield3d), intent(in), target :: atm_pres
    type(meshfield3d), intent(in), target :: atm_rtot
    type(meshfield3d), intent(in), target :: atm_dens_hyd
    type(meshfield2d), intent(in), target :: sflx_rad_sw_dir_dn
    type(meshfield2d), intent(in), target :: sflx_rad_lw_dif_dn
    type(meshfield2d), intent(in), target :: sflx_engi
    logical, intent(in) :: countup
 
    class(localmesh3d), pointer :: lmesh
    class(localmesh2d), pointer :: lmesh2d
    integer :: ldomid
    real(rp), allocatable :: atm_temp_lc(:,:)
 
    !----------------------------------------------------------------
 
    do ldomid=1, this%mesh2D_atm%LOCAL_MESH_NUM
      lmesh => atm_ddens%mesh%lcmesh_list(ldomid)
      lmesh2d => lmesh%lcmesh2D
      call this%putATM_lc( lmesh, lmesh%refElem3D, lmesh2d, lmesh2d%refElem2D, &
        atm_ddens%local(ldomid)%val, atm_momz%local(ldomid)%val,  atm_momx%local(ldomid)%val, atm_momy%local(ldomid)%val, &
        atm_qv%local(ldomid)%val, atm_pres%local(ldomid)%val, atm_rtot%local(ldomid)%val, atm_dens_hyd%local(ldomid)%val, &
        sflx_rad_sw_dir_dn%local(ldomid)%val, sflx_rad_lw_dif_dn%local(ldomid)%val,                                       &
        sflx_engi         %local(ldomid)%val,  &
        !-
        this%OCN_atm_vars(ocn_atm_sfc_dens_id)%local(ldomid)%val,  &
        this%OCN_atm_vars(ocn_atm_sfc_pres_id)%local(ldomid)%val,  &
        this%OCN_atm_vars(ocn_atm_temp_id)%local(ldomid)%val,      &
        this%OCN_atm_vars(ocn_atm_pres_id)%local(ldomid)%val,      &
        this%OCN_atm_vars(ocn_atm_w_id)%local(ldomid)%val,         &
        this%OCN_atm_vars(ocn_atm_u_id)%local(ldomid)%val,         &
        this%OCN_atm_vars(ocn_atm_v_id)%local(ldomid)%val,         &
        this%OCN_atm_vars(ocn_atm_qv_id)%local(ldomid)%val,           &
        this%OCN_atm_vars(ocn_atm_sflx_rd_sw_dir)%local(ldomid)%val,  &
        this%OCN_atm_vars(ocn_atm_sflx_rd_lw_dif)%local(ldomid)%val,  &
        this%OCN_atm_vars(ocn_atm_sflx_engi)%local(ldomid)%val )
    end do
    
    ! Update counter
    if (countup) then
      this%CNT_putATM_OCN = this%CNT_putATM_OCN + 1.0_rp
    end if
    return
  end subroutine couplervars_putatm
 
  !> Put OCN variables to CPL buffer for ATM component
!OCL SERIAL
  subroutine couplervars_putocn( this, ocn_vars, countup )
    use mod_ocean_vars, only: oceanvars, &
      sflx_mw_id => ocn_sflx_mw_id,        &
      sflx_mu_id => ocn_sflx_mu_id,        &
      sflx_mv_id => ocn_sflx_mv_id,        &
      sflx_sh_id => ocn_sflx_sh_id,        &
      sflx_lh_id => ocn_sflx_lh_id,        &
      sflx_qv_id => ocn_sflx_qv_id,        &
      sfc_temp_id => auxvar2d_sfc_temp_id, &
      salb_vis_dir_id => auxvar2d_sfc_alb_vis_dir_id
    implicit none
    class(couplervars), intent(inout) :: this
    type(oceanvars), intent(in) :: ocn_vars
    logical, intent(in) :: countup
 
    class(localmesh2d), pointer :: lmesh
    integer :: ldomid    
    !----------------------------------------------------------------
 
    do ldomid=1, this%mesh2D_ocn%LOCAL_MESH_NUM
      lmesh => this%mesh2D_ocn%lcmesh_list(ldomid)
 
      call this%putOCN_lc( lmesh, lmesh%refElem2D, &
        ocn_vars%AUX_VARS2D(sfc_temp_id)%local(ldomid)%val,     &
        ocn_vars%AUX_VARS2D(salb_vis_dir_id)%local(ldomid)%val, &
        ocn_vars%OCN_SFLX(sflx_mw_id)%local(ldomid)%val,        &
        ocn_vars%OCN_SFLX(sflx_mu_id)%local(ldomid)%val,        &
        ocn_vars%OCN_SFLX(sflx_mv_id)%local(ldomid)%val,        &
        ocn_vars%OCN_SFLX(sflx_sh_id)%local(ldomid)%val,        &
        ocn_vars%OCN_SFLX(sflx_lh_id)%local(ldomid)%val,        &
        ocn_vars%OCN_SFLX(sflx_qv_id)%local(ldomid)%val,        &
        !-
        this%OCN_vars(ocn_sfc_temp_id)%local(ldomid)%val,       &
        this%OCN_vars(ocn_sfc_albedo_id)%local(ldomid)%val,     &
        this%OCN_vars(ocn_sflx_mw_id)%local(ldomid)%val,        &
        this%OCN_vars(ocn_sflx_mu_id)%local(ldomid)%val,        &
        this%OCN_vars(ocn_sflx_mv_id)%local(ldomid)%val,        &
        this%OCN_vars(ocn_sflx_sh_id)%local(ldomid)%val,        &
        this%OCN_vars(ocn_sflx_lh_id)%local(ldomid)%val,        &
        this%OCN_vars(ocn_sflx_qv_id)%local(ldomid)%val         )
    end do
 
    ! Update counter
    if ( countup ) then
      this%CNT_putOCN_ATM = this%CNT_putOCN_ATM + 1.0_rp
    end if
 
    return
  end subroutine couplervars_putocn
 
  !> Get SFC variables from CPL buffer for ATM component
!OCL SERIAL
  subroutine couplervars_get_sfc_atm( this,      &
    SFC_TEMP, SFC_ALBEDO,                        &
    SFLX_MW, SFLX_MU, SFLX_MV, SFLX_SH, SFLX_LH, &
    SFLX_QV )
    implicit none
    class(couplervars), intent(inout) :: this
    type(meshfield2d), intent(inout) :: sfc_temp
    type(meshfield2d), intent(inout) :: sfc_albedo
    type(meshfield2d), intent(inout) :: sflx_mw
    type(meshfield2d), intent(inout) :: sflx_mu
    type(meshfield2d), intent(inout) :: sflx_mv
    type(meshfield2d), intent(inout) :: sflx_sh
    type(meshfield2d), intent(inout) :: sflx_lh
    type(meshfield2d), intent(inout) :: sflx_qv
 
    integer :: ldomid
    class(localmesh2d), pointer :: lmesh, lmesh_o
    !----------------------------------------------------------------
 
    do ldomid=1, this%mesh2D_atm%LOCAL_MESH_NUM
      lmesh => this%mesh2D_atm%lcmesh_list(ldomid)
      lmesh_o => this%mesh2D_ocn%lcmesh_list(ldomid)
 
      call this%get_SFC_ATM_lc( &
        lmesh, lmesh%refElem2D, lmesh_o, lmesh_o%refElem2D,       &
        this%OCN_vars(ocn_sfc_temp_id)%local(ldomid)%val,         &
        this%OCN_vars(ocn_sfc_albedo_id)%local(ldomid)%val,       &
        this%OCN_vars(ocn_sflx_mw_id)%local(ldomid)%val,          &
        this%OCN_vars(ocn_sflx_mu_id)%local(ldomid)%val,          &
        this%OCN_vars(ocn_sflx_mv_id)%local(ldomid)%val,          &
        this%OCN_vars(ocn_sflx_sh_id)%local(ldomid)%val,          &
        this%OCN_vars(ocn_sflx_lh_id)%local(ldomid)%val,          &
        this%OCN_vars(ocn_sflx_qv_id)%local(ldomid)%val,          &
        !-
        sfc_temp%local(ldomid)%val, sfc_albedo%local(ldomid)%val, &
        sflx_mw%local(ldomid)%val, sflx_mu%local(ldomid)%val,     &
        sflx_mv%local(ldomid)%val, sflx_sh%local(ldomid)%val,     &
        sflx_lh%local(ldomid)%val, sflx_qv%local(ldomid)%val      )
    end do
 
    this%CNT_putOCN_ATM = 0.0_rp
    return
  end subroutine couplervars_get_sfc_atm
 
  !> Get ATM variables from CPL buffer for OCN component
!OCL SERIAL
  subroutine couplervars_get_atm_ocn( this,          &
    ATM_SFC_DENS, ATM_SFC_PRES, ATM_TEMP, ATM_PRES, ATM_W, ATM_U, ATM_V, ATM_QV, &
    RD_SFLX_SW_DIR, RD_SFLX_LW_DIF, DZ_A )
    implicit none
    class(couplervars), intent(inout) :: this
    type(meshfield2d), intent(inout) :: atm_sfc_dens
    type(meshfield2d), intent(inout) :: atm_sfc_pres
    type(meshfield2d), intent(inout) :: atm_temp
    type(meshfield2d), intent(inout) :: atm_pres
    type(meshfield2d), intent(inout) :: atm_w
    type(meshfield2d), intent(inout) :: atm_u
    type(meshfield2d), intent(inout) :: atm_v
    type(meshfield2d), intent(inout) :: atm_qv
    type(meshfield2d), intent(inout) :: rd_sflx_sw_dir
    type(meshfield2d), intent(inout) :: rd_sflx_lw_dif
    type(meshfield2d), intent(inout) :: dz_a
 
    integer :: ldomid
    !----------------------------------------------------------------
 
    do ldomid=1, this%mesh2D_atm%LOCAL_MESH_NUM
      call this%get_ATM_OCN_lc( &
        this%mesh3D_atm%lcmesh_list(ldomid), this%mesh3D_atm%refElem3D, &
        this%mesh2D_atm%lcmesh_list(ldomid), this%mesh2D_atm%refElem2D, &
        this%mesh2D_ocn%lcmesh_list(ldomid), this%mesh2D_ocn%refElem2D, &
        !-
        this%OCN_atm_vars(ocn_atm_sfc_dens_id)%local(ldomid)%val,     &
        this%OCN_atm_vars(ocn_atm_sfc_pres_id)%local(ldomid)%val,     &
        this%OCN_atm_vars(ocn_atm_temp_id)%local(ldomid)%val,         &
        this%OCN_atm_vars(ocn_atm_pres_id)%local(ldomid)%val,         &
        this%OCN_atm_vars(ocn_atm_w_id)%local(ldomid)%val,            &
        this%OCN_atm_vars(ocn_atm_u_id)%local(ldomid)%val,            &
        this%OCN_atm_vars(ocn_atm_v_id)%local(ldomid)%val,            &
        this%OCN_atm_vars(ocn_atm_qv_id)%local(ldomid)%val,           &
        this%OCN_atm_vars(ocn_atm_sflx_rd_sw_dir)%local(ldomid)%val,  &
        this%OCN_atm_vars(ocn_atm_sflx_rd_lw_dif)%local(ldomid)%val,  &
        !-
        atm_sfc_dens%local(ldomid)%val, atm_sfc_pres%local(ldomid)%val, &
        atm_temp%local(ldomid)%val, atm_pres%local(ldomid)%val,                                              &
        atm_w%local(ldomid)%val, atm_u%local(ldomid)%val, atm_v%local(ldomid)%val, atm_qv%local(ldomid)%val, &
        rd_sflx_sw_dir%local(ldomid)%val,  &
        rd_sflx_lw_dif%local(ldomid)%val, &
        dz_a%local(ldomid)%val )
    end do
 
    this%CNT_putATM_OCN = 0.0_rp
    return
  end subroutine couplervars_get_atm_ocn
 
!-
!OCL SERIAL
  subroutine putatm_local( this, &
    lmesh_a, elem_a, lmesh2D_a, elem2D_a,&
    ATM_DDENS, ATM_MOMZ, ATM_MOMX, ATM_MOMY, ATM_QV,             &
    ATM_PRES, ATM_Rtot, ATM_DENS_hyd,                            &
    ATM_RD_SFLX_SW_DIR, ATM_RD_SFLX_LW_DIF, ATM_SFLX_ENGI,       &
    O_ATM_SFC_DENS, O_ATM_SFC_PRES,  &
    O_ATM_TEMP, O_ATM_PRES, O_ATM_W, O_ATM_U, O_ATM_V, O_ATM_QV, &
    O_ATM_RD_SFLX_SW_DIR, O_ATM_RD_SFLX_LW_DIF, O_ATM_SFLX_ENGI  )
    implicit none
    class(couplervars), intent(inout) :: this
    class(localmesh3d), intent(in) :: lmesh_a
    class(elementbase3d), intent(in) :: elem_a
    class(localmesh2d), intent(in) :: lmesh2d_a
    class(elementbase2d), intent(in) :: elem2d_a
    real(rp), intent(in) :: atm_ddens(elem_a%np,lmesh_a%nea)
    real(rp), intent(in) :: atm_momz(elem_a%np,lmesh_a%nea)
    real(rp), intent(in) :: atm_momx(elem_a%np,lmesh_a%nea)
    real(rp), intent(in) :: atm_momy(elem_a%np,lmesh_a%nea)
    real(rp), intent(in) :: atm_qv(elem_a%np,lmesh_a%nea)
    real(rp), intent(in) :: atm_pres(elem_a%np,lmesh_a%nea)
    real(rp), intent(in) :: atm_rtot(elem_a%np,lmesh_a%nea)
    real(rp), intent(in) :: atm_dens_hyd(elem_a%np,lmesh_a%nea)
    real(rp), intent(in) :: atm_rd_sflx_sw_dir(elem2d_a%np,lmesh2d_a%nea)
    real(rp), intent(in) :: atm_rd_sflx_lw_dif(elem2d_a%np,lmesh2d_a%nea)
    real(rp), intent(in) :: atm_sflx_engi(elem2d_a%np,lmesh2d_a%nea)
    real(rp), intent(out) :: o_atm_sfc_dens(elem2d_a%np,lmesh2d_a%nea)
    real(rp), intent(out) :: o_atm_sfc_pres(elem2d_a%np,lmesh2d_a%nea)
    real(rp), intent(out) :: o_atm_temp(elem2d_a%np,lmesh2d_a%nea)
    real(rp), intent(out) :: o_atm_pres(elem2d_a%np,lmesh2d_a%nea)
    real(rp), intent(out) :: o_atm_w(elem2d_a%np,lmesh2d_a%nea)
    real(rp), intent(out) :: o_atm_u(elem2d_a%np,lmesh2d_a%nea)
    real(rp), intent(out) :: o_atm_v(elem2d_a%np,lmesh2d_a%nea)
    real(rp), intent(out) :: o_atm_qv(elem2d_a%np,lmesh2d_a%nea)
    real(rp), intent(out) :: o_atm_rd_sflx_sw_dir(elem2d_a%np,lmesh2d_a%nea)
    real(rp), intent(out) :: o_atm_rd_sflx_lw_dif(elem2d_a%np,lmesh2d_a%nea)
    real(rp), intent(out) :: o_atm_sflx_engi(elem2d_a%np,lmesh2d_a%nea)
 
    integer :: ke2d
    real(rp) :: coef1, coef2
 
    integer :: hslice0(elem2d_a%np), hslice1(elem2d_a%np)
    real(rp) :: dens_(elem2d_a%np)
    real(rp) :: temp_(elem2d_a%np)
    !----------------------------------------------------------------
 
    coef1 = this%CNT_putATM_OCN
    coef2 = 1.0_rp / ( 1.0_rp + coef1 )
 
    hslice0(:) = elem_a%Hslice(:,1)
    hslice1(:) = elem_a%Hslice(:,2)
 
    !$omp parallel private(temp_, dens_)
    !$omp do
    do ke2d=lmesh2d_a%NeS, lmesh2d_a%NeE
      dens_(:) = atm_dens_hyd(hslice0(:),ke2d) + atm_ddens(hslice0(:),ke2d)
      temp_(:) = atm_pres(hslice0(:),ke2d) / ( dens_(:) * atm_rtot(hslice0(:),ke2d) )
 
      o_atm_sfc_dens(:,ke2d) = o_atm_sfc_dens(:,ke2d) * coef1 + dens_(:)
      o_atm_sfc_pres(:,ke2d) = o_atm_sfc_pres(:,ke2d) * coef1 + atm_pres(hslice0(:),ke2d)
 
      o_atm_temp(:,ke2d) = o_atm_temp(:,ke2d) * coef1 + temp_(:)
      o_atm_pres(:,ke2d) = o_atm_pres(:,ke2d) * coef1 + atm_pres(hslice0(:),ke2d)
      o_atm_w(:,ke2d)    = o_atm_w(:,ke2d) * coef1 + atm_momz(hslice1(:),ke2d) / dens_(:)
      o_atm_u(:,ke2d)    = o_atm_u(:,ke2d) * coef1 + atm_momx(hslice0(:),ke2d) / dens_(:)
      o_atm_v(:,ke2d)    = o_atm_v(:,ke2d) * coef1 + atm_momy(hslice0(:),ke2d) / dens_(:)
      o_atm_qv(:,ke2d)   = o_atm_qv(:,ke2d) * coef1 + atm_qv(hslice0(:),ke2d)
 
      o_atm_rd_sflx_sw_dir(:,ke2d) = o_atm_rd_sflx_sw_dir(:,ke2d) * coef1 + atm_rd_sflx_sw_dir(:,ke2d)
      o_atm_rd_sflx_lw_dif(:,ke2d) = o_atm_rd_sflx_lw_dif(:,ke2d) * coef1 + atm_rd_sflx_lw_dif(:,ke2d)
      o_atm_sflx_engi(:,ke2d) = o_atm_sflx_engi(:,ke2d) * coef1 + atm_sflx_engi(:,ke2d)
    end do
    !$omp do
    do ke2d=lmesh2d_a%NeS, lmesh2d_a%NeE
      o_atm_sfc_dens(:,ke2d) = o_atm_sfc_dens(:,ke2d) * coef2
      o_atm_sfc_pres(:,ke2d) = o_atm_sfc_pres(:,ke2d) * coef2
 
      o_atm_temp(:,ke2d) = o_atm_temp(:,ke2d) * coef2
      o_atm_pres(:,ke2d) = o_atm_pres(:,ke2d) * coef2
      o_atm_w(:,ke2d)    = o_atm_w(:,ke2d)    * coef2
      o_atm_u(:,ke2d)    = o_atm_u(:,ke2d)    * coef2
      o_atm_v(:,ke2d)    = o_atm_v(:,ke2d)    * coef2
      o_atm_qv(:,ke2d)   = o_atm_qv(:,ke2d)   * coef2
 
      o_atm_rd_sflx_sw_dir(:,ke2d) = o_atm_rd_sflx_sw_dir(:,ke2d) * coef2
      o_atm_rd_sflx_lw_dif(:,ke2d) = o_atm_rd_sflx_lw_dif(:,ke2d) * coef2
      o_atm_sflx_engi(:,ke2d) = o_atm_sflx_engi(:,ke2d) * coef2
    end do
    !$omp end parallel
    return
  end subroutine putatm_local
 
!OCL SERIAL
  subroutine putocn_local( this, &
    lmesh_o, elem_o, &
    SFC_TEMP, SALB_VIS_DIR, SFLX_MW, SFLX_MU, SFLX_MV, SFLX_SH, SFLX_LH, SFLX_QV, &
    SFC_TEMP_out, SALB_VIS_DIR_out, SFLX_MW_out, SFLX_MU_out, SFLX_MV_out, SFLX_SH_out, SFLX_LH_out, SFLX_QV_out )
    implicit none
    class(couplervars), intent(inout) :: this
    class(localmesh2d), intent(in) :: lmesh_o
    class(elementbase2d), intent(in) :: elem_o
    real(rp), intent(in) :: sfc_temp(elem_o%np,lmesh_o%nea)
    real(rp), intent(in) :: salb_vis_dir(elem_o%np,lmesh_o%nea)
    real(rp), intent(in) :: sflx_mw(elem_o%np,lmesh_o%nea)
    real(rp), intent(in) :: sflx_mu(elem_o%np,lmesh_o%nea)
    real(rp), intent(in) :: sflx_mv(elem_o%np,lmesh_o%nea)
    real(rp), intent(in) :: sflx_sh(elem_o%np,lmesh_o%nea)
    real(rp), intent(in) :: sflx_lh(elem_o%np,lmesh_o%nea)
    real(rp), intent(in) :: sflx_qv(elem_o%np,lmesh_o%nea)
    real(rp), intent(out) :: sfc_temp_out(elem_o%np,lmesh_o%nea)
    real(rp), intent(out) :: salb_vis_dir_out(elem_o%np,lmesh_o%nea)
    real(rp), intent(out) :: sflx_mw_out(elem_o%np,lmesh_o%nea)
    real(rp), intent(out) :: sflx_mu_out(elem_o%np,lmesh_o%nea)
    real(rp), intent(out) :: sflx_mv_out(elem_o%np,lmesh_o%nea)
    real(rp), intent(out) :: sflx_sh_out(elem_o%np,lmesh_o%nea)
    real(rp), intent(out) :: sflx_lh_out(elem_o%np,lmesh_o%nea)
    real(rp), intent(out) :: sflx_qv_out(elem_o%np,lmesh_o%nea)
 
    integer :: ke
    real(rp) :: coef1, coef2
    !----------------------------------------------------------------
 
    coef1 = this%CNT_putOCN_ATM
    coef2 = 1.0_rp / ( 1.0_rp + coef1 )
 
    !$omp parallel
    !$omp do
    do ke=lmesh_o%NeS, lmesh_o%NeE
      sfc_temp_out(:,ke) = sfc_temp_out(:,ke) * coef1 + sfc_temp(:,ke)
      salb_vis_dir_out(:,ke) = salb_vis_dir_out(:,ke) * coef1 + salb_vis_dir(:,ke)
      sflx_mw_out(:,ke) = sflx_mw_out(:,ke) * coef1 + sflx_mw(:,ke)
      sflx_mu_out(:,ke) = sflx_mu_out(:,ke) * coef1 + sflx_mu(:,ke)
      sflx_mv_out(:,ke) = sflx_mv_out(:,ke) * coef1 + sflx_mv(:,ke)
      sflx_sh_out(:,ke) = sflx_sh_out(:,ke) * coef1 + sflx_sh(:,ke)
      sflx_lh_out(:,ke) = sflx_lh_out(:,ke) * coef1 + sflx_lh(:,ke)
      sflx_qv_out(:,ke) = sflx_qv_out(:,ke) * coef1 + sflx_qv(:,ke)
    end do
    !$omp do
    do ke=lmesh_o%NeS, lmesh_o%NeE
      sfc_temp_out(:,ke) = sfc_temp_out(:,ke) * coef2
      salb_vis_dir_out(:,ke) = salb_vis_dir_out(:,ke) * coef2
      sflx_mw_out(:,ke) = sflx_mw_out(:,ke) * coef2
      sflx_mu_out(:,ke) = sflx_mu_out(:,ke) * coef2
      sflx_mv_out(:,ke) = sflx_mv_out(:,ke) * coef2
      sflx_sh_out(:,ke) = sflx_sh_out(:,ke) * coef2
      sflx_lh_out(:,ke) = sflx_lh_out(:,ke) * coef2
      sflx_qv_out(:,ke) = sflx_qv_out(:,ke) * coef2
    end do
    !$omp end parallel
    return
  end subroutine putocn_local
  
!OCL SERIAL
  subroutine get_sfc_atm_local( this, &
    lmesh_a, elem_a, lmesh_o, elem_o, &
    O_SFC_TEMP, O_SFC_ALBEDO, O_SFLX_MW, O_SFLX_MU, O_SFLX_MV, O_SFLX_SH, O_SFLX_LH, O_SFLX_QV, &
    SFC_TEMP, SFC_ALBEDO, SFLX_MW, SFLX_MU, SFLX_MV, SFLX_SH, SFLX_LH, SFLX_QV )
    implicit none
    class(couplervars), intent(inout) :: this
    class(localmesh2d), intent(in) :: lmesh_a
    class(elementbase2d), intent(in) :: elem_a
    class(localmesh2d), intent(in) :: lmesh_o
    class(elementbase2d), intent(in) :: elem_o
    real(rp), intent(in) :: o_sfc_temp(elem_o%np,lmesh_o%nea)
    real(rp), intent(in) :: o_sfc_albedo(elem_o%np,lmesh_o%nea)
    real(rp), intent(in) :: o_sflx_mw(elem_o%np,lmesh_o%nea)
    real(rp), intent(in) :: o_sflx_mu(elem_o%np,lmesh_o%nea)
    real(rp), intent(in) :: o_sflx_mv(elem_o%np,lmesh_o%nea)
    real(rp), intent(in) :: o_sflx_sh(elem_o%np,lmesh_o%nea)
    real(rp), intent(in) :: o_sflx_lh(elem_o%np,lmesh_o%nea)
    real(rp), intent(in) :: o_sflx_qv(elem_o%np,lmesh_o%nea)
    real(rp), intent(out) :: sfc_temp(elem_a%np,lmesh_a%nea)
    real(rp), intent(out) :: sfc_albedo(elem_a%np,lmesh_a%nea)
    real(rp), intent(out) :: sflx_mw(elem_a%np,lmesh_a%nea)
    real(rp), intent(out) :: sflx_mu(elem_a%np,lmesh_a%nea)
    real(rp), intent(out) :: sflx_mv(elem_a%np,lmesh_a%nea)
    real(rp), intent(out) :: sflx_sh(elem_a%np,lmesh_a%nea)
    real(rp), intent(out) :: sflx_lh(elem_a%np,lmesh_a%nea)
    real(rp), intent(out) :: sflx_qv(elem_a%np,lmesh_a%nea)
 
    integer :: ke
    !----------------------------------------------------------------
 
    !$omp parallel do
    do ke=lmesh_a%NeS, lmesh_a%NeE
      sfc_temp(:,ke)  = o_sfc_temp(:,ke)
      sfc_albedo(:,ke) = o_sfc_albedo(:,ke)
      sflx_mw(:,ke) = o_sflx_mw(:,ke)
      sflx_mu(:,ke) = o_sflx_mu(:,ke)
      sflx_mv(:,ke) = o_sflx_mv(:,ke)
      sflx_sh(:,ke) = o_sflx_sh(:,ke)
      sflx_lh(:,ke) = o_sflx_lh(:,ke)
      sflx_qv(:,ke) = o_sflx_qv(:,ke)
    end do
    return
  end subroutine get_sfc_atm_local
 
!OCL SERIAL
  subroutine get_atm_ocn_local( this, &
    lmesh3D_a, elem3D_a, lmesh_a, elem_a, lmesh_o, elem_o, &
    O_ATM_SFC_DENS, O_ATM_SFC_PRES, O_ATM_TEMP, O_ATM_PRES, O_ATM_W, O_ATM_U, O_ATM_V, O_ATM_QV, &
!    O_ATM_SFLX_ENGI, &
    O_ATM_RD_SFLX_SW_DIR, O_ATM_RD_SFLX_LW_DIF, &
    ATM_SFC_DENS, ATM_SFC_PRES, ATM_TEMP, ATM_PRES, ATM_W, ATM_U, ATM_V, ATM_QV, &
!    ATM_SFLX_ENGI, &
    ATM_RD_SFLX_SW_DIR, ATM_RD_SFLX_LW_DIF, &
    DZ_A )
    implicit none
    class(couplervars), intent(inout) :: this
    class(localmesh3d), intent(in) :: lmesh3d_a
    class(elementbase3d), intent(in) :: elem3d_a
    class(localmesh2d), intent(in) :: lmesh_a
    class(elementbase2d), intent(in) :: elem_a
    class(localmesh2d), intent(in) :: lmesh_o
    class(elementbase2d), intent(in) :: elem_o
    real(rp), intent(in) :: o_atm_sfc_dens(elem_a%np,lmesh_a%nea)
    real(rp), intent(in) :: o_atm_sfc_pres(elem_a%np,lmesh_a%nea)
    real(rp), intent(in) :: o_atm_temp(elem_a%np,lmesh_a%nea)
    real(rp), intent(in) :: o_atm_pres(elem_a%np,lmesh_a%nea)
    real(rp), intent(in) :: o_atm_w(elem_a%np,lmesh_a%nea)
    real(rp), intent(in) :: o_atm_u(elem_a%np,lmesh_a%nea)
    real(rp), intent(in) :: o_atm_v(elem_a%np,lmesh_a%nea)
    real(rp), intent(in) :: o_atm_qv(elem_a%np,lmesh_a%nea)
    ! real(RP), intent(in) :: O_ATM_SFLX_ENGI(elem_a%Np,lmesh_a%NeA)
    real(rp), intent(in) :: o_atm_rd_sflx_sw_dir(elem_a%np,lmesh_a%nea)
    real(rp), intent(in) :: o_atm_rd_sflx_lw_dif(elem_a%np,lmesh_a%nea)
    real(rp), intent(out) :: atm_sfc_dens(elem_o%np,lmesh_o%nea)
    real(rp), intent(out) :: atm_sfc_pres(elem_o%np,lmesh_o%nea)
    real(rp), intent(out) :: atm_temp(elem_o%np,lmesh_o%nea)
    real(rp), intent(out) :: atm_pres(elem_o%np,lmesh_o%nea)
    real(rp), intent(out) :: atm_w(elem_o%np,lmesh_o%nea)
    real(rp), intent(out) :: atm_u(elem_o%np,lmesh_o%nea)
    real(rp), intent(out) :: atm_v(elem_o%np,lmesh_o%nea)
    real(rp), intent(out) :: atm_qv(elem_o%np,lmesh_o%nea)
    ! real(RP), intent(out) :: ATM_SFLX_ENGI(elem_o%Np,lmesh_o%NeA)
    real(rp), intent(out) :: atm_rd_sflx_sw_dir(elem_o%np,lmesh_o%nea)
    real(rp), intent(out) :: atm_rd_sflx_lw_dif(elem_o%np,lmesh_o%nea)
    real(rp), intent(out) :: dz_a(elem_o%np,lmesh_o%nea)
 
    integer :: ke
    !----------------------------------------------------------------
 
    !$omp parallel do
    do ke=lmesh_a%NeS, lmesh_a%NeE
      atm_sfc_dens(:,ke) = o_atm_sfc_dens(:,ke)
      atm_sfc_pres(:,ke) = o_atm_sfc_pres(:,ke)
 
      atm_temp(:,ke)  = o_atm_temp(:,ke)
      atm_pres(:,ke)  = o_atm_pres(:,ke)
      atm_w(:,ke)     = o_atm_w(:,ke)
      atm_u(:,ke)     = o_atm_u(:,ke)
      atm_v(:,ke)     = o_atm_v(:,ke)
      atm_qv(:,ke)    = o_atm_qv(:,ke)
      ! ATM_SFLX_ENGI(:,ke) = O_ATM_SFLX_ENGI(:,ke)
      atm_rd_sflx_sw_dir(:,ke) = o_atm_rd_sflx_sw_dir(:,ke)
      atm_rd_sflx_lw_dif(:,ke) = o_atm_rd_sflx_lw_dif(:,ke)
 
      dz_a(:,ke) = lmesh3d_a%zlev(elem3d_a%Hslice(:,2),ke) - lmesh3d_a%zlev(elem3d_a%Hslice(:,1),ke)
    end do
    return
  end subroutine get_atm_ocn_local
end module mod_cpl_vars