mod_atmos_phy_cp_vars.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!> module Atmosphere / Physics / Cumulus Parameterization
!!
!! @par Description
!!          Container for variables with cumulus parameterization component in atmospheric model
!!
!! @author Yuta Kawai, Team SCALE
!!
!<
!-------------------------------------------------------------------------------
#include "scaleFElib.h"
module mod_atmos_phy_cp_vars
  !-----------------------------------------------------------------------------
  !
  !++ Used modules
  !
  use scale_precision
  use scale_io
  use scale_prc
 
  use scale_element_base, only: elementbase3d
  use scale_mesh_base, only: meshbase
  use scale_mesh_base2d, only: meshbase2d
  use scale_mesh_base3d, only: &
    meshbase3d,                              &
    dimtype_xyz  => meshbase3d_dimtypeid_xyz
  use scale_localmesh_base, only: localmeshbase
  use scale_localmesh_3d, only: localmesh3d
  use scale_localmeshfield_base, only: &
    localmeshfieldbase, localmeshfieldbaselist
  use scale_meshfield_base, only: &
    meshfieldbase, meshfield2d, meshfield3d
 
  use scale_file_restart_meshfield, only: &
    file_restart_meshfield_component
  
  use scale_meshfieldcomm_base, only: meshfieldcontainer
  
  use scale_model_var_manager, only: &
    modelvarmanager, variableinfo
  use scale_model_mesh_manager, only: modelmeshbase
    
  use mod_atmos_mesh, only: atmosmesh
 
  !-----------------------------------------------------------------------------
  implicit none
  private
 
  !-----------------------------------------------------------------------------
  !
  !++ Public type & procedures
  !
 
  !> Derived type to manage variables with cumulus parameterization component in atmospheric model
  type, public :: atmosphycpvars
    type(meshfield3d), allocatable :: tends(:)     !< Array of tendency variables
    type(modelvarmanager) :: tends_manager         !< Object to manage tendencies
 
    type(meshfield2d), allocatable :: auxvars2d(:) !< Array of 2D auxiliary variables
    type(modelvarmanager) :: auxvars2d_manager     !< Object to manage 2D auxiliary variables
 
    integer :: tends_num_tot                        !< Number of tendency variables with cumulus parameterization
  contains
    procedure :: init => atmosphycpvars_init
    procedure :: final => atmosphycpvars_final
    procedure :: setup => atmosphycpvars_setup
    procedure :: history => atmosphycpvars_history
  end type atmosphycpvars
 
  public :: atmosphycpvars_getlocalmeshfields_tend
  public :: atmosphycpvars_getlocalmeshfields_sfcflx
 
  !-----------------------------------------------------------------------------
  !
  !++ Public variables
  !
  integer, public, parameter :: atmos_phy_cp_dens_t_id    = 1
  integer, public, parameter :: atmos_phy_cp_rhow_t_id    = 2
  integer, public, parameter :: atmos_phy_cp_rhot_t_id    = 3
  integer, public, parameter :: atmos_phy_cp_rhoqv_t_id   = 4
  integer, public, parameter :: atmos_phy_cp_tends_num1   = 4 
 
  type(variableinfo), public :: atmos_phy_cp_tend_vinfo(atmos_phy_cp_tends_num1)
  DATA atmos_phy_cp_tend_vinfo / &
    variableinfo( atmos_phy_cp_dens_t_id, 'CP_DENS_t', 'tendency of density in CP process',          &
                  'kg/m3/s',  3, 'XYZ',  ''                                                       ), &
    variableinfo( atmos_phy_cp_rhow_t_id, 'CP_RHOW_t', 'tendency of water vapor in CP process',      &
                  'kg/m3/s',  3, 'XYZ',  ''                                                       ), &
    variableinfo( atmos_phy_cp_rhot_t_id, 'CP_RHOT_t', 'tendency of rho*PT in CP process',           &
                  'kg/m3.K/s', 3, 'XYZ',  ''                                                      ), &
    variableinfo( atmos_phy_cp_rhoqv_t_id, 'CP_RHOQV_t', 'tendency of rho*QV in CP process',         &
                  'kg/m3/s', 3, 'XYZ',  ''                                                        )  /
 
  integer, public, parameter :: atmos_phy_cp_aux2d_sflx_rain_id   = 1
  integer, public, parameter :: atmos_phy_cp_aux2d_sflx_snow_id   = 2
  integer, public, parameter :: atmos_phy_cp_aux2d_sflx_engi_id   = 3
  integer, public, parameter :: atmos_phy_cp_aux2d_num            = 3
 
  type(variableinfo), public :: atmos_phy_cp_aux2d_vinfo(atmos_phy_cp_aux2d_num)
  DATA atmos_phy_cp_aux2d_vinfo / &
    variableinfo( atmos_phy_cp_aux2d_sflx_rain_id, 'CP_SFLX_RAIN', 'precipitation flux (liquid) in CP process',    &
                  'kg/m2/s',  2, 'XY',  ''                                                                      ), &
    variableinfo( atmos_phy_cp_aux2d_sflx_snow_id, 'CP_SFLX_SNOW', 'precipitation flux (solid) in CP process',     &
                  'kg/m2/s',  2, 'XY',  ''                                                                      ), &
    variableinfo( atmos_phy_cp_aux2d_sflx_engi_id, 'CP_SFLX_ENGI', 'internal energy flux flux in CP process',      &
                  'J/m2/s',   2, 'XY',  ''                                                                      )  /
 
  !-----------------------------------------------------------------------------
  !
  !++ Private procedures
  !
contains
  !> Setup an object to manage variables with a cumulus parameterization component  
!OCL SERIAL
  subroutine atmosphycpvars_init( this, model_mesh )
    implicit none
    class(atmosphycpvars), target, intent(inout) :: this
    class(modelmeshbase), target, intent(in) :: model_mesh
    !----------------------------------------------------
 
    log_info('AtmosPhyCpVars_Init',*)
    return
  end subroutine atmosphycpvars_init
 
  !> Setup variable objects with cumulus parameterization component
  subroutine atmosphycpvars_setup( this, model_mesh )
    use scale_atmos_hydrometeor, only: &
       n_hyd, &
       hyd_name
    use scale_tracer, only: &
      tracer_name, tracer_desc, tracer_unit
    use scale_file_history, only: &
      file_history_reg
    implicit none
    class(atmosphycpvars), target, intent(inout) :: this
    class(modelmeshbase), target, intent(in) :: model_mesh
 
    integer :: iv
    integer :: iq
    integer :: n
    logical :: reg_file_hist
 
    class(atmosmesh), pointer :: atm_mesh
    class(meshbase2d), pointer :: mesh2d
    class(meshbase3d), pointer :: mesh3d
 
    type(variableinfo) :: qtrc_tp_vinfo_tmp
    type(variableinfo) :: qtrc_vterm_vinfo_tmp
    !----------------------------------------------------
 
 
    this%TENDS_NUM_TOT = atmos_phy_cp_tends_num1 + n_hyd
 
    !- Initialize auxiliary and diagnostic variables
 
    nullify( atm_mesh )
    select type(model_mesh)
    class is (atmosmesh)
      atm_mesh => model_mesh
    end select
    mesh3d => atm_mesh%ptr_mesh
    
    call mesh3d%GetMesh2D( mesh2d )
 
    !----
 
    call this%tends_manager%Init()
    allocate( this%tends(this%TENDS_NUM_TOT) )
 
    reg_file_hist = .true.    
    do iv = 1, atmos_phy_cp_tends_num1
      call this%tends_manager%Regist(           &
        atmos_phy_cp_tend_vinfo(iv), mesh3d,    &
        this%tends(iv), reg_file_hist           )
      
      do n = 1, mesh3d%LOCAL_MESH_NUM
        this%tends(iv)%local(n)%val(:,:) = 0.0_rp
      end do         
    end do
 
    qtrc_tp_vinfo_tmp%ndims    = 3
    qtrc_tp_vinfo_tmp%dim_type = 'XYZ'
    qtrc_tp_vinfo_tmp%STDNAME  = ''
    
    do iq = 1, n_hyd
      iv = atmos_phy_cp_tends_num1 + iq 
      qtrc_tp_vinfo_tmp%keyID = iv
      qtrc_tp_vinfo_tmp%NAME  = 'CP_'//trim(hyd_name(iq))//'_t'
      qtrc_tp_vinfo_tmp%DESC  = 'tendency of rho*'//trim(hyd_name(iq))//' in CP process'
      qtrc_tp_vinfo_tmp%UNIT  = 'kg/m3/s'
 
      reg_file_hist = .true.
      call this%tends_manager%Regist( &
        qtrc_tp_vinfo_tmp, mesh3d,              & 
        this%tends(iv), reg_file_hist           ) 
      
      do n = 1, mesh3d%LOCAL_MESH_NUM
        this%tends(iv)%local(n)%val(:,:) = 0.0_rp
      end do         
    end do    
 
    !--
    
    call this%auxvars2D_manager%Init()
    allocate( this%auxvars2D(atmos_phy_cp_aux2d_num) )
 
    reg_file_hist = .true.    
    do iv = 1, atmos_phy_cp_aux2d_num
      call this%auxvars2D_manager%Regist( &
        atmos_phy_cp_aux2d_vinfo(iv), mesh2d,    & ! (in) 
        this%auxvars2D(iv), reg_file_hist        ) ! (out)
      
      do n = 1, mesh3d%LOCAL_MESH_NUM
        this%auxvars2D(iv)%local(n)%val(:,:) = 0.0_rp
      end do         
    end do
 
    return
  end subroutine atmosphycpvars_setup
 
  !> Finalize an object to manage variables with cumulus parameterization component  
!OCL SERIAL
  subroutine atmosphycpvars_final( this )
    implicit none
    class(atmosphycpvars), intent(inout) :: this
    !----------------------------------------------------
 
     log_info('AtmosPhyCpVars_Final',*)
 
     call this%tends_manager%Final()
     deallocate( this%tends )
 
     call this%auxvars2D_manager%Final()
     deallocate( this%auxvars2D )
 
    return
  end subroutine atmosphycpvars_final
 
!OCL SERIAL
  subroutine atmosphycpvars_getlocalmeshfields_tend( domID, mesh, bl_tends_list, &
    cp_DENS_t, cp_RHOT_t, cp_RHOQv_t,                                             &
    lcmesh3D                                                                     &
    )
 
    use scale_mesh_base, only: meshbase
    use scale_meshfield_base, only: meshfieldbase
    implicit none
 
    integer, intent(in) :: domid
    class(meshbase), intent(in) :: mesh
    class(modelvarmanager), intent(inout) :: bl_tends_list
    class(localmeshfieldbase), pointer, intent(out) :: cp_dens_t
    class(localmeshfieldbase), pointer, intent(out) :: cp_rhot_t
    class(localmeshfieldbase), pointer, intent(out) :: cp_rhoqv_t
    class(localmesh3d), pointer, intent(out), optional :: lcmesh3d
 
    class(meshfieldbase), pointer :: field   
    class(localmeshbase), pointer :: lcmesh
 
    integer :: iq
    !-------------------------------------------------------
 
    !--
    call bl_tends_list%Get(atmos_phy_cp_dens_t_id, field)
    call field%GetLocalMeshField(domid, cp_dens_t)
 
    call bl_tends_list%Get(atmos_phy_cp_rhot_t_id, field)
    call field%GetLocalMeshField(domid, cp_rhot_t)
 
    call bl_tends_list%Get(atmos_phy_cp_rhoqv_t_id, field)
    call field%GetLocalMeshField(domid, cp_rhoqv_t)
 
    if (present(lcmesh3d)) then
      call mesh%GetLocalMesh( domid, lcmesh )
      nullify( lcmesh3d )
 
      select type(lcmesh)
      type is (localmesh3d)
        if (present(lcmesh3d)) lcmesh3d => lcmesh
      end select
    end if
 
    return
  end subroutine atmosphycpvars_getlocalmeshfields_tend
 
!OCL SERIAL
  subroutine atmosphycpvars_getlocalmeshfields_sfcflx( domID, mesh, sfcflx_list, &
    SFLX_rain, SFLX_snow, SFLX_engi                                              )
    
    use scale_mesh_base, only: meshbase
    use scale_meshfield_base, only: meshfieldbase
    implicit none
 
    integer, intent(in) :: domid
    class(meshbase), intent(in) :: mesh
    class(modelvarmanager), intent(inout) :: sfcflx_list
    class(localmeshfieldbase), pointer, intent(out) :: sflx_rain
    class(localmeshfieldbase), pointer, intent(out) :: sflx_snow
    class(localmeshfieldbase), pointer, intent(out) :: sflx_engi
 
    class(meshfieldbase), pointer :: field
    !-------------------------------------------------------
 
    call sfcflx_list%Get(atmos_phy_cp_aux2d_sflx_rain_id, field)
    call field%GetLocalMeshField(domid, sflx_rain)
 
    call sfcflx_list%Get(atmos_phy_cp_aux2d_sflx_snow_id, field)
    call field%GetLocalMeshField(domid, sflx_snow)
 
    call sfcflx_list%Get(atmos_phy_cp_aux2d_sflx_engi_id, field)
    call field%GetLocalMeshField(domid, sflx_engi)
    
    return
  end subroutine atmosphycpvars_getlocalmeshfields_sfcflx
 
!OCL SERIAL
  subroutine atmosphycpvars_history( this )
    use scale_file_history_meshfield, only: file_history_meshfield_put
    implicit none
    class(atmosphycpvars), intent(inout) :: this
 
    integer :: v
    integer :: hst_id
    !----------------------------------------------------
 
    do v=1, this%TENDS_NUM_TOT
      hst_id = this%tends(v)%hist_id
      if ( hst_id > 0 ) call file_history_meshfield_put( hst_id, this%tends(v) )
    end do
 
    do v=1, atmos_phy_cp_aux2d_num
      hst_id = this%auxvars2D(v)%hist_id
      if ( hst_id > 0 ) call file_history_meshfield_put( hst_id, this%auxvars2D(v) )
    end do
    return
  end subroutine atmosphycpvars_history
 
end module mod_atmos_phy_cp_vars