mod_atmos_phy_rd_vars.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!> module Atmosphere / Physics / Radiation
!!
!! @par Description
!!          Container for variables with radiation component in atmospheric model
!!
!! @author Yuta Kawai, Team SCALE
!!
!<
!-------------------------------------------------------------------------------
#include "scaleFElib.h"
module mod_atmos_phy_rd_vars
  !-----------------------------------------------------------------------------
  !
  !++ Used modules
  !
  use scale_precision
  use scale_io
  use scale_prc
 
  use scale_element_base, only: elementbase3d
  use scale_mesh_base, only: meshbase
  use scale_mesh_base2d, only: meshbase2d
  use scale_mesh_base3d, only: &
    meshbase3d,                               &
    dimtype_xyz  => meshbase3d_dimtypeid_xyz, &
    dimtype_xy   => meshbase3d_dimtypeid_xy
  use scale_localmesh_base, only: localmeshbase
  use scale_localmesh_3d, only: localmesh3d
  use scale_localmeshfield_base, only: &
    localmeshfieldbase, localmeshfieldbaselist
  use scale_meshfield_base, only: &
    meshfieldbase, meshfield2d, meshfield3d
  use scale_meshfieldcomm_base, only: meshfieldcontainer
 
  use scale_file_restart_meshfield, only: &
    file_restart_meshfield_component
  
  use scale_model_var_manager, only: &
    modelvarmanager, variableinfo
  use scale_model_mesh_manager, only: modelmeshbase
    
  use mod_atmos_mesh, only: atmosmesh
 
  !-----------------------------------------------------------------------------
  implicit none
  private
 
  !-----------------------------------------------------------------------------
  !
  !++ Public type & procedures
  !
 
  !> Derived type to manage variables with radiation component in atmospheric model
  type, public :: atmosphyrdvars
    type(meshfield3d), allocatable :: tends(:)     !< Array of tendency variables
    type(modelvarmanager) :: tends_manager         !< Object to manage tendencies
 
    type(meshfield2d), allocatable :: auxvars2d(:) !< Array of 2D auxiliary variables
    type(modelvarmanager) :: auxvars2d_manager     !< Object to manage 2D auxiliary variables
 
    type(meshfield2d), allocatable :: sflx_rad_dn(:) !< Array of downward radiative fluxes at the surface
 
    integer :: tends_num_tot                       !< Number of tendency variables with cloud microphysics
 
    type(file_restart_meshfield_component) restart_file !< Restart file for variables with radiation component
  contains
    procedure :: init => atmosphyrdvars_init
    procedure :: final => atmosphyrdvars_final
    procedure :: setup => atmosphyrdvars_setup
    procedure :: history => atmosphyrdvars_history
    procedure :: read_restart_file => atmosphyrdvars_read_restart_file
    procedure :: write_restart_file_prep => atmosphyrdvars_write_restart_file_prep
    procedure :: write_restart_file => atmosphyrdvars_write_restart_file
    procedure :: write_restart_file_post => atmosphyrdvars_write_restart_file_post
  end type atmosphyrdvars
  
  !-----------------------------------------------------------------------------
  !
  !++ Public variables
  !
  integer, public, parameter :: atmos_phy_rd_rhoh_id      = 1 !< ID of diabatic heating rate in RD process
  integer, public, parameter :: atmos_phy_rd_tends_num1   = 1
 
  type(variableinfo), public :: atmos_phy_rd_tend_vinfo(atmos_phy_rd_tends_num1)
  DATA atmos_phy_rd_tend_vinfo / &
    variableinfo( atmos_phy_rd_rhoh_id, 'RD_RHOH', 'diabatic heating rate in RD process',              &
                  'J/kg/s',   3, 'XYZ',  ''                                                         )  /
 
  !-- 2D Auxiliary variables for radiation
 
  ! Radiative fluxes at the surface
  integer, public, parameter :: atmos_phy_rd_aux2d_sflx_lw_up_id   = 1  !< ID of upward longwave surface flux
  integer, public, parameter :: atmos_phy_rd_aux2d_sflx_lw_dn_id   = 2  !< ID of downward longwave surface flux
  integer, public, parameter :: atmos_phy_rd_aux2d_sflx_sw_up_id   = 3  !< ID of upward shortwave surface flux
  integer, public, parameter :: atmos_phy_rd_aux2d_sflx_sw_dn_id   = 4  !< ID of downward shortwave surface flux
  integer, public, parameter :: atmos_phy_rd_restart_var_num       = 4  !< Number of restart variables for radiation component
  ! Radiative fluxes at the top of the model
  integer, public, parameter :: atmos_phy_rd_aux2d_tomflx_lw_up_id = 5  !< ID of upward longwave flux at the top of the model
  integer, public, parameter :: atmos_phy_rd_aux2d_tomflx_lw_dn_id = 6  !< ID of downward longwave flux at the top of the model
  integer, public, parameter :: atmos_phy_rd_aux2d_tomflx_sw_up_id = 7  !< ID of upward shortwave flux at the top of the model
  integer, public, parameter :: atmos_phy_rd_aux2d_tomflx_sw_dn_id = 8  !< ID of downward shortwave flux at the top of the model
  !
  integer, public, parameter :: atmos_phy_rd_aux2d_solins_id       = 9  !< ID of solar insolation flux at the top of the model
  integer, public, parameter :: atmos_phy_rd_aux2d_cossza_id       = 10 !< ID of cosine of solar zenith angle
  integer, public, parameter :: atmos_phy_rd_aux2d_num             = 10
 
  type(variableinfo), public :: atmos_phy_rd_aux2d_vinfo(atmos_phy_rd_aux2d_num)
  DATA atmos_phy_rd_aux2d_vinfo / &
    variableinfo( atmos_phy_rd_aux2d_sflx_lw_up_id  , 'RD_SFLX_LW_up'  , 'upward longwave surface flux'                   , 'W/m2', 2, 'XY', '' ), &
    variableinfo( atmos_phy_rd_aux2d_sflx_lw_dn_id  , 'RD_SFLX_LW_dn'  , 'downward longwave surface flux'                 , 'W/m2', 2, 'XY', '' ), &
    variableinfo( atmos_phy_rd_aux2d_sflx_sw_up_id  , 'RD_SFLX_SW_up'  , 'upward shortwave surface flux'                  , 'W/m2', 2, 'XY', '' ), &
    variableinfo( atmos_phy_rd_aux2d_sflx_sw_dn_id  , 'RD_SFLX_SW_dn'  , 'downward shortwave surface flux'                , 'W/m2', 2, 'XY', '' ), &
    variableinfo( atmos_phy_rd_aux2d_tomflx_lw_up_id, 'RD_TOMFLX_LW_up', 'upward longwave flux at the top of the model'   , 'W/m2', 2, 'XY', '' ), &
    variableinfo( atmos_phy_rd_aux2d_tomflx_lw_dn_id, 'RD_TOMFLX_LW_dn', 'downward longwave flux at the top of the model' , 'W/m2', 2, 'XY', '' ), &
    variableinfo( atmos_phy_rd_aux2d_tomflx_sw_up_id, 'RD_TOMFLX_SW_up', 'upward shortwave flux at the top of the model'  , 'W/m2', 2, 'XY', '' ), &
    variableinfo( atmos_phy_rd_aux2d_tomflx_sw_dn_id, 'RD_TOMFLX_SW_dn', 'downward shortwave flux at the top of the model', 'W/m2', 2, 'XY', '' ), &
    variableinfo( atmos_phy_rd_aux2d_solins_id      , 'RD_SolINS'      , 'solar insolation flux at the top of the model'  , 'W/m2', 2, 'XY', '' ), &
    variableinfo( atmos_phy_rd_aux2d_cossza_id      , 'RD_cosSZA'      , 'cosine of solar zenith angle'                   ,    '1', 2, 'XY', '' )  /
  
  !-
  integer, public, parameter :: atmos_phy_rd_sflx_dn_sw_dir = 1  !< ID of downward direct shortwave flux at the surface
  integer, public, parameter :: atmos_phy_rd_sflx_dn_sw_dif = 2  !< ID of downward diffuse shortwave flux at the surface
  integer, public, parameter :: atmos_phy_rd_sflx_dn_lw     = 3  !< ID of downward longwave flux at the surface
  integer, public, parameter :: atmos_phy_rd_sflx_dn_num    = 3  !< Number of downward radiative fluxes
  !-----------------------------------------------------------------------------
  !
  !++ Private procedures
  !
contains
  !> Setup an object to manage variables with a radiation component  
!OCL SERIAL
  subroutine atmosphyrdvars_init( this, model_mesh )
 
    use scale_tracer, only: &
      tracer_name, tracer_desc, tracer_unit
    use scale_file_history, only: &
      file_history_reg
 
    implicit none
    class(atmosphyrdvars), target, intent(inout) :: this
    class(modelmeshbase), target, intent(in) :: model_mesh
 
    class(atmosmesh), pointer :: atm_mesh
    class(meshbase2d), pointer :: mesh2d
    class(meshbase3d), pointer :: mesh3d
 
    integer :: iv
    integer :: iq
    integer :: n
    logical :: reg_file_hist
    !----------------------------------------------------
 
    log_info('AtmosPhyRdVars_Init',*)
    return
  end subroutine atmosphyrdvars_init
 
  !> Setup variables objects with radiation component
  subroutine atmosphyrdvars_setup( this, model_mesh )
    use scale_tracer, only: &
      tracer_name, tracer_desc, tracer_unit
    use scale_file_history, only: &
      file_history_reg
 
    implicit none
    class(atmosphyrdvars), target, intent(inout) :: this
    class(modelmeshbase), target, intent(in) :: model_mesh
 
    class(atmosmesh), pointer :: atm_mesh
    class(meshbase2d), pointer :: mesh2d
    class(meshbase3d), pointer :: mesh3d
 
    integer :: iv
    integer :: iq
    integer :: n
    logical :: reg_file_hist
    !----------------------------------------------------
 
    log_info('AtmosPhyRdVars_Init',*)
 
    this%TENDS_NUM_TOT = atmos_phy_rd_tends_num1
 
    !- Initialize auxiliary and diagnostic variables
 
    nullify( atm_mesh )
    select type(model_mesh)
    class is (atmosmesh)
      atm_mesh => model_mesh
    end select
    mesh3d => atm_mesh%ptr_mesh
 
    call mesh3d%GetMesh2D( mesh2d )
 
    !----
 
    !-
    call this%tends_manager%Init()
    allocate( this%tends(this%TENDS_NUM_TOT) )
 
    reg_file_hist = .true.
    do iv=1, atmos_phy_rd_tends_num1
      call this%tends_manager%Regist( &
        atmos_phy_rd_tend_vinfo(iv), mesh3d, & ! (in) 
        this%tends(iv), reg_file_hist        ) ! (out)
      
      do n = 1, mesh3d%LOCAL_MESH_NUM
        this%tends(iv)%local(n)%val(:,:) = 0.0_rp
      end do         
    end do
 
    !- 
    call this%auxvars2D_manager%Init()
    allocate( this%auxvars2D(atmos_phy_rd_aux2d_num) )
 
    reg_file_hist = .true.
    do iv=1, atmos_phy_rd_aux2d_num
      call this%auxvars2D_manager%Regist( &
        atmos_phy_rd_aux2d_vinfo(iv), mesh2d, & ! (in) 
        this%auxvars2D(iv), reg_file_hist     ) ! (out)
      
      do n = 1, mesh2d%LOCAL_MESH_NUM
        this%auxvars2D(iv)%local(n)%val(:,:) = 0.0_rp
      end do         
    end do
 
    !- Setup restart file for variables with radiation component
    call atm_mesh%Setup_restartfile( this%restart_file, &
      atmos_phy_rd_restart_var_num                      )
 
    return
  end subroutine atmosphyrdvars_setup
 
  !> Finalize an object to manage variables with radiation component  
!OCL SERIAL
  subroutine atmosphyrdvars_final( this )
    implicit none
    class(atmosphyrdvars), intent(inout) :: this
    !----------------------------------------------------
 
    log_info('AtmosPhyRdVars_Final',*)
 
    call this%tends_manager%Final()
    deallocate( this%tends )
 
    call this%auxvars2D_manager%Final()
    deallocate( this%auxvars2D )
 
    return
  end subroutine atmosphyrdvars_final
 
  !> Write history data of variables with radiation component
!OCL SERIAL
  subroutine atmosphyrdvars_history( this )
    use scale_file_history_meshfield, only: file_history_meshfield_put
    implicit none
    class(atmosphyrdvars), intent(inout) :: this
 
    integer :: v
    integer :: hst_id
    !----------------------------------------------------
 
    do v = 1, this%TENDS_NUM_TOT
      hst_id = this%tends(v)%hist_id
      if ( hst_id > 0 ) call file_history_meshfield_put( hst_id, this%tends(v) )
    end do
 
    do v = 1, atmos_phy_rd_aux2d_num
      hst_id = this%auxvars2D(v)%hist_id
      if ( hst_id > 0 ) call file_history_meshfield_put( hst_id, this%auxvars2D(v) )
    end do
 
    return
  end subroutine atmosphyrdvars_history
 
!> Read data with atmospheric variables with radiation component from restart file
!!
!OCL SERIAL
  subroutine atmosphyrdvars_read_restart_file( this )
    use scale_meshfieldcomm_base, only: meshfieldcontainer
    implicit none
    
    class(atmosphyrdvars), intent(inout), target :: this
 
    integer :: iv
    !--------------------------------------------------------------------
 
    log_newline
    log_info("AtmosPhyRdVars_Read_restart_file",*) 'Open restart file (ATMOS/Physics radiation) '
 
    !- Open restart file
    call this%restart_file%Open()
 
    !- Read restart file
 
    do iv=atmos_phy_rd_aux2d_sflx_lw_up_id, atmos_phy_rd_aux2d_sflx_sw_dn_id
      call this%restart_file%Read_var( dimtype_xy, this%auxvars2D(iv)%varname, &
        this%auxvars2D(iv) )
    end do
 
    !- Close restart file
    log_info("AtmosPhyRdVars_Read_restart_file",*) 'Close restart file (ATMOS/Physics radiation) '
    call this%restart_file%Close()
    return
  end subroutine atmosphyrdvars_read_restart_file
 
!> Write data with atmospheric variables with radiation component to restart file
!!
!OCL SERIAL
  subroutine atmosphyrdvars_write_restart_file_prep( this )
    implicit none
    class(atmosphyrdvars), intent(inout) :: this
 
    integer :: iv, rf_vid
    !---------------------------------------
 
    log_newline
    log_info("AtmosPhyRdVars_Write_restart_file_prep",*) 'Define variables with ATMOS/Physics radiation'
 
    !- Create restart file
    call this%restart_file%Create()
    call prc_mpibarrier()
 
    !- Define variables
 
    do iv=atmos_phy_rd_aux2d_sflx_lw_up_id, atmos_phy_rd_aux2d_sflx_sw_dn_id
      rf_vid = iv
      call this%restart_file%Def_var( this%auxvars2D(iv),     &
        atmos_phy_rd_aux2d_vinfo(iv)%DESC, rf_vid, dimtype_xy )
    end do
    return
  end subroutine atmosphyrdvars_write_restart_file_prep
 
!> Write data with atmospheric variables with radiation component to restart file
!!
!OCL SERIAL
  subroutine atmosphyrdvars_write_restart_file( this )
    implicit none
    class(atmosphyrdvars), intent(inout) :: this
 
    integer :: iv, rf_vid 
    !---------------------------------------
    !- Write restart file
    do iv=atmos_phy_rd_aux2d_sflx_lw_up_id, atmos_phy_rd_aux2d_sflx_sw_dn_id
      rf_vid = iv
      call this%restart_file%Write_var(rf_vid, this%auxvars2D(iv) )
    end do
    return
  end subroutine atmosphyrdvars_write_restart_file
 
  !> Close restart file with atmospheric radiation component
  !!
!OCL SERIAL
  subroutine atmosphyrdvars_write_restart_file_post( this )
    implicit none
    class(atmosphyrdvars), intent(inout) :: this
    !---------------------------------------
    log_info("AtmosPhyRdVars_Write_restart_file_post",*) 'Close restart file (ATMOS/Physics radiation) '
 
    call this%restart_file%Close()
    return
  end subroutine atmosphyrdvars_write_restart_file_post
 
end module mod_atmos_phy_rd_vars