mod_ocean_mesh.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!> module Ocean / Mesh
!!
!! @par Description
!!          Base module for mesh with ocean model
!!
!! @author Yuta kawai, Team SCALE
!!
!<
!-------------------------------------------------------------------------------
#include "scaleFElib.h"
module mod_ocean_mesh
  !-----------------------------------------------------------------------------
  !
  !++ Used modules
  !
  use scale_precision
  use scale_io
  use scale_prc
 
  use scale_meshfield_base, only: meshfield3d
  use scale_mesh_base2d, only: meshbase2d
  use scale_mesh_base3d, only: meshbase3d
  use scale_element_base, only: elementbase3d
  use scale_element_line, only: lineelement
  use scale_element_hexahedral, only: hexahedralelement
  use scale_localmesh_2d, only: localmesh2d
  use scale_localmesh_3d, only: localmesh3d
  use scale_sparsemat, only: sparsemat
  use scale_meshfield_base, only: meshfield2d
  use scale_mesh_topography, only: meshtopography
 
  use scale_file_restart_meshfield, only: file_restart_meshfield_component
  use scale_model_var_manager, only: modelvarmanager
  use scale_model_mesh_manager, only: modelmesh3d
  
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public type & procedures
  !
 
  !> Derived type to manage a computational mesh (base class)
  !!
  type, abstract, extends(modelmesh3d), public :: oceanmesh
    type(hexahedralelement) :: element !< Object to manage 3D reference element
    type(lineelement) :: element_v1d   !< Object to manage 1D reference element for the vertical direction
 
    type(meshtopography) :: topography  !< Object to manage topography
    integer :: vcoord_type_id           !< ID of vertical coordinate type
 
    logical :: comm_use_mpi_pc              !< Flag whether persistent communication in MPI is used
    logical :: comm_use_mpi_pc_fujitsu_ext  !< Flag whether Fujitsu extension in MPI persistent communication is used
  contains
    procedure :: oceanmesh_init
    procedure :: oceanmesh_final
    procedure(oceanmesh_setup_restartfile1), public, deferred :: setup_restartfile1
    procedure(oceanmesh_setup_restartfile2), public, deferred :: setup_restartfile2
    procedure(oceanmesh_calc_uvmet), public, deferred :: calc_uvmet
    generic :: setup_restartfile => setup_restartfile1, setup_restartfile2
    procedure(oceanmesh_setup_vcoord), public, deferred :: setup_vcoordinate
    procedure :: read_topography_file => oceanmesh_read_topography_file
  end type oceanmesh
 
  interface
    subroutine oceanmesh_setup_restartfile1( this, restart_file, var_num, dim_name_postfix )
      import oceanmesh
      import file_restart_meshfield_component
      class(oceanmesh), target, intent(inout) :: this
      class(file_restart_meshfield_component), intent(inout) :: restart_file
      integer, intent(in) :: var_num
      character(*), intent(in) :: dim_name_postfix
    end subroutine oceanmesh_setup_restartfile1
  end interface
  interface
    subroutine oceanmesh_setup_restartfile2( this, restart_file, &
      in_basename, in_postfix_timelabel,                         &
      out_basename, out_postfix_timelabel,                       &
      out_dtype, out_title, var_num, dim_name_postfix            )
      import oceanmesh
      import file_restart_meshfield_component
      class(oceanmesh), target, intent(inout) :: this
      class(file_restart_meshfield_component), intent(inout) :: restart_file
      character(*), intent(in) :: in_basename
      logical, intent(in) :: in_postfix_timelabel
      character(*), intent(in) :: out_basename
      logical, intent(in) :: out_postfix_timelabel
      character(*), intent(in) :: out_title
      character(*), intent(in) :: out_dtype  
      integer, intent(in) :: var_num  
      character(*), intent(in) :: dim_name_postfix
    end subroutine oceanmesh_setup_restartfile2
  end interface
  interface
    subroutine oceanmesh_calc_uvmet( this, U, V, &
        Umet, Vmet )
        import oceanmesh
        import meshfield3d
        class(oceanmesh), target, intent(in) :: this
        type(meshfield3d), intent(in) :: U
        type(meshfield3d), intent(in) :: V
        type(meshfield3d), intent(inout) :: Umet
        type(meshfield3d), intent(inout) :: Vmet
    end subroutine oceanmesh_calc_uvmet
  end interface
  interface 
    subroutine oceanmesh_setup_vcoord( this )
      import oceanmesh
      class(oceanmesh), target, intent(inout) :: this
    end subroutine oceanmesh_setup_vcoord
  end interface
  integer, parameter, public :: ocn_mesh_max_commnuicator_num = 16
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  
  !-----------------------------------------------------------------------------
  !
  !++ Private procedures
  !
  !-------------------
 
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
 
contains
 
!> Setup an object to manage a computational mesh
  subroutine oceanmesh_init( this, mesh )
 
    use scale_file_monitor_meshfield, only: &
      file_monitor_meshfield_set_dim
    
    implicit none
    class(oceanmesh), target, intent(inout) :: this
    class(meshbase3d), intent(in) :: mesh            !< Object to manage 3D computational mesh
 
    class(meshbase2d), pointer :: mesh2d
    !-------------------------------------------
 
    call this%ModelMesh3D_Init( mesh )
 
    !-
    call file_monitor_meshfield_set_dim( mesh, 'OCN3D' )
    
    !-
    call mesh%GetMesh2D( mesh2d )
    call this%topography%Init( "topo", mesh2d )
 
    return
  end subroutine oceanmesh_init
 
!> Finalize an object to manage a computational mesh
  subroutine oceanmesh_final(this)
    implicit none
 
    class(oceanmesh), intent(inout) :: this
    !-------------------------------------------
 
    call this%topography%Final()
    call this%ModelMesh3D_Final()
 
    call this%element%Final()
    call this%element_v1D%Final()
 
    return
  end subroutine oceanmesh_final
 
!OCL SERIAL
  subroutine oceanmesh_read_topography_file( this,      &
    TOPO_IN_BASENAME, TOPO_IN_VARNAME, mesh2D, dom_zmin )
    use scale_file_base_meshfield, only: file_base_meshfield
    use scale_mesh_rectdom2d, only: meshrectdom2d
    use scale_mesh_cubedspheredom2d, only: meshcubedspheredom2d
    use scale_mesh_base2d, only: &
      mftype2d_xy => meshbase2d_dimtypeid_xy    
    implicit none
    class(oceanmesh), target, intent(inout) :: this
    character(*), intent(in) :: topo_in_basename
    character(*), intent(in) :: topo_in_varname
    class(meshbase2d), intent(in), target :: mesh2d
    real(rp), intent(in) :: dom_zmin
 
    type(file_base_meshfield) :: file_topo
 
    integer :: idom, ke2d
    class(localmesh2d), pointer :: lcmesh2d
    !-------------------------------------------
 
    if ( trim(topo_in_basename) /= '' ) then
      log_info("OCEAN_MESH_setup",*) 'Read topography data'
 
      select type(mesh2d)
      type is (meshrectdom2d)
        call file_topo%Init(1, mesh2d=mesh2d )
      type is (meshcubedspheredom2d)
        call file_topo%Init(1, meshcubedsphere2d=mesh2d )
      end select
 
      call file_topo%Open( topo_in_basename, myrank=prc_myrank )
      call file_topo%Read_Var( mftype2d_xy, topo_in_varname, this%topography%topo )
      call file_topo%Close()
      call file_topo%Final()
    else
      log_info("OCEAN_MESH_setup",*) 'No topography data is specified. Set the topography to a constant value: ', dom_zmin
 
      do idom=1, mesh2d%LOCAL_MESH_NUM
        lcmesh2d => mesh2d%lcmesh_list(idom)
        !$omp parallel do
        do ke2d=lcmesh2d%NeS, lcmesh2d%NeE
          this%topography%topo%local(idom)%val(:,ke2d) = dom_zmin
        end do
      end do
    end if
    
    return
  end subroutine oceanmesh_read_topography_file
 
end module mod_ocean_mesh