scale_localmeshfield_base.F90

Go to the documentation of this file.

!> module FElib / Data / base
!!
!! @par Description
!!           A module for managing field data with subdomains included in each MPI process 
!!
!! @author Yuta Kawai, Team SCALE
!!
!<
#include "scaleFElib.h"
module scale_localmeshfield_base
 
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
 
  use scale_localmesh_base, only: &
    localmeshbase
  
  use scale_localmesh_1d, only: &
    localmesh1d, localmesh1d_init, localmesh1d_final
 
  use scale_localmesh_2d, only: &
    localmesh2d, localmesh2d_init, localmesh2d_final
 
  use scale_localmesh_3d, only: &
    localmesh3d, localmesh3d_init, localmesh3d_final
 
  use scale_element_base, only: elementbase2d
 
  !-----------------------------------------------------------------------------
  implicit none
  private
 
  !-----------------------------------------------------------------------------
  !
  !++ Public type & procedure
  ! 
 
  !> Derived type representing a field with local mesh (base type)
  type, public :: localmeshfieldbase
    real(rp), allocatable :: val(:,:)       !< Buffer to save field data at all nodes
    real(rp), allocatable :: face_val(:,:)  !< Buffer to save field data at face nodes
  end type localmeshfieldbase
 
  type, public :: localmeshfieldbaselist
    class(localmeshfieldbase), pointer :: ptr
  end type localmeshfieldbaselist
 
  !> Derived type representing a field with 1D local mesh
  type, extends(localmeshfieldbase), public :: localmeshfield1d
    type(localmesh1d), pointer :: mesh => null()
  contains
    procedure :: init => localmeshfield1d_init
    procedure :: final => localmeshfield1d_final
  end type localmeshfield1d
 
  !> Derived type representing a field with 2D local mesh
  type, extends(localmeshfieldbase), public :: localmeshfield2d
    type(localmesh2d), pointer :: mesh => null()
  contains
    procedure :: init => localmeshfield2d_init
    procedure :: final => localmeshfield2d_final
  end type localmeshfield2d
 
  !> Derived type representing a field with 3D local mesh
  type, extends(localmeshfieldbase), public :: localmeshfield3d
    type(localmesh3d), pointer :: mesh => null()
  contains
    procedure :: init => localmeshfield3d_init
    procedure :: final => localmeshfield3d_final
  end type localmeshfield3d
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  integer, public, parameter :: local_meshfield_type_nodes_val     = 1  !< ID of data type with a field on all nodes in local mesh 
  integer, public, parameter :: local_meshfield_type_nodes_faceval = 2  !< ID of data type with a field on face nodes in local mesh 
 
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
 
  private :: localmeshfieldbase_init
  private :: localmeshfieldbase_final
 
contains
 
!> Initialize an object to manage a field data (base type)
!OCL SERIAL
  subroutine localmeshfieldbase_init( this, lcmesh, data_type )
    use scale_prc, only: prc_abort
    implicit none
    class(localmeshfieldbase), intent(inout) :: this
    class(localmeshbase), intent(in) :: lcmesh   !< Object to manage a field data on a local mesh
    integer, intent(in), optional :: data_type   !< ID of data type (all nodes or face nodes)
 
    integer :: data_type_
    !-----------------------------------------------------------------------------
 
    if ( present(data_type) ) then
      data_type_ = data_type
    else
      data_type_ = local_meshfield_type_nodes_val
    end if
 
    select case( data_type_ )
    case (local_meshfield_type_nodes_val)
      allocate( this%val(lcmesh%refElem%Np,lcmesh%NeA) )
      !$acc enter data create(this%val)
    case (local_meshfield_type_nodes_faceval)
      allocate( this%face_val(lcmesh%refElem%NfpTot,lcmesh%Ne) )
      !$acc enter data create(this%face_val)
    case default
      log_error("LocalMeshFieldBase_Init",*) "Unexcepted data_type", data_type_
      call prc_abort        
    end select
 
    !$acc enter data copyin(this)
    return
  end subroutine localmeshfieldbase_init
 
!> Finalize an object to manage a field data (base type)
!OCL SERIAL
  subroutine localmeshfieldbase_final( this )
    implicit none
    class(localmeshfieldbase), intent(inout) :: this
    !-----------------------------------------------------------------------------
 
    if ( allocated(this%val) ) then
      !$acc exit data delete(this%val)
      deallocate( this%val )
    end if
    if ( allocated(this%face_val) ) then
      !$acc exit data delete(this%face_val)
      deallocate( this%face_val )
    end if
    !$acc exit data delete(this)
    return
  end subroutine localmeshfieldbase_final
 
  !* 1D *********
 
!> Setup an object to manage a field data on 1D local computational mesh
!OCL SERIAL
  subroutine localmeshfield1d_init( this, mesh, data_type )
    implicit none
    class(localmeshfield1d), intent(inout) :: this
    class(localmesh1d), target, intent(in) :: mesh   !< Object to manage a field data on a 1D local mesh
    integer, intent(in), optional :: data_type       !< ID of data type (all nodes or face nodes)
    !-----------------------------------------------------------------------------
 
    this%mesh => mesh
    call localmeshfieldbase_init( this, mesh, data_type )
 
    return
  end subroutine localmeshfield1d_init
 
!> Finalize an object to manage a field data on 1D local computational mesh
!OCL SERIAL
  subroutine localmeshfield1d_final( this )
    implicit none
    class(localmeshfield1d), intent(inout) :: this
    !-----------------------------------------------------------------------------
 
    call localmeshfieldbase_final( this )
 
    return
  end subroutine localmeshfield1d_final
 
  !* 2D *********
  
!> Setup an object to manage a field data on 2D local computational mesh
!OCL SERIAL
  subroutine localmeshfield2d_init( this, mesh, data_type )
    implicit none
    class(localmeshfield2d), intent(inout) :: this
    class(localmesh2d), target, intent(in) :: mesh   !< Object to manage a field data on a 2D local mesh
    integer, intent(in), optional :: data_type       !< ID of data type (all nodes or face nodes)
    !-----------------------------------------------------------------------------
 
    this%mesh => mesh
    call localmeshfieldbase_init( this, mesh, data_type )
 
    return
  end subroutine localmeshfield2d_init
 
!> Finalize an object to manage a field data on 2D local computational mesh
!OCL SERIAL
  subroutine localmeshfield2d_final( this )
    implicit none
    class(localmeshfield2d), intent(inout) :: this
    !-----------------------------------------------------------------------------
 
    call localmeshfieldbase_final( this )
    return
  end subroutine localmeshfield2d_final
 
  !* 3D *********
  
!> Setup an object to manage a field data on 3D local computational mesh
!OCL SERIAL
  subroutine localmeshfield3d_init( this, mesh, data_type )
    implicit none
    class(localmeshfield3d), intent(inout) :: this
    class(localmesh3d), target, intent(in) :: mesh   !< Object to manage a field data on a 3D local mesh
    integer, optional, intent(in) :: data_type
    !-----------------------------------------------------------------------------
 
    this%mesh => mesh
    call localmeshfieldbase_init( this, mesh, data_type )
 
    return
  end subroutine localmeshfield3d_init
 
!> Finalize an object to manage a field data on 3D local computational mesh
!OCL SERIAL
  subroutine localmeshfield3d_final( this )
    implicit none
    class(localmeshfield3d), intent(inout) :: this
    !-----------------------------------------------------------------------------
 
    call localmeshfieldbase_final( this )
    return
  end subroutine localmeshfield3d_final
 
end module scale_localmeshfield_base