scale_atm_dyn_dgm_globalnonhydro3d_etot_hevi.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!> module FElib / Fluid dyn solver / Atmosphere / Global nonhydrostatic model / HEVI
!!
!! @par Description
!!      HEVI DGM scheme for Global Atmospheric Dynamical process. 
!!      The governing equations is a fully compressible nonhydrostatic equations, 
!!      which consist of mass, momentum, and thermodynamics (total energy conservation) equations. 
!!
!! @author Yuta Kawai, Team SCALE
!<
!-------------------------------------------------------------------------------
#include "scaleFElib.h"
module scale_atm_dyn_dgm_globalnonhydro3d_etot_hevi
  !-----------------------------------------------------------------------------
  !
  !++ Used modules
  !
  use scale_precision
  use scale_io
  use scale_prc
  use scale_prof
  use scale_const, only: &
    grav => const_grav,  &
    rdry => const_rdry,  &
    cpdry => const_cpdry, &
    cvdry => const_cvdry, &
    pres00 => const_pre00
 
  use scale_sparsemat  
  use scale_element_base, only: &
    elementbase2d, elementbase3d
  use scale_element_modalfilter, only: modalfilter
  use scale_element_hexahedral, only: hexahedralelement
  use scale_element_operation_base, only: elementoperationbase3d
  use scale_localmesh_2d, only: localmesh2d  
  use scale_localmesh_3d, only: localmesh3d
  use scale_mesh_base2d, only: meshbase2d
  use scale_mesh_base3d, only: meshbase3d
  use scale_localmeshfield_base, only: localmeshfield3d
  use scale_meshfield_base, only: meshfield3d
 
  use scale_atm_dyn_dgm_nonhydro3d_common, only: &
    atm_dyn_dgm_nonhydro3d_common_init,                       &
    atm_dyn_dgm_nonhydro3d_common_final,                      &
    dens_vid => prgvar_ddens_id, etot_vid => prgvar_etot_id,  &
    momx_vid => prgvar_momx_id, momy_vid => prgvar_momy_id,   &
    momz_vid => prgvar_momz_id,                               &
    prgvar_num, intrpmat_vpordm1
 
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedures
  !
  public :: atm_dyn_dgm_globalnonhydro3d_etot_hevi_init
  public :: atm_dyn_dgm_globalnonhydro3d_etot_hevi_final
  public :: atm_dyn_dgm_globalnonhydro3d_etot_hevi_cal_tend
  public :: atm_dyn_dgm_globalnonhydro3d_etot_hevi_cal_vi
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  
  !-----------------------------------------------------------------------------
  !
  !++ Private procedures & variables
  !
  !-------------------
 
contains
!OCL SERIAL
  subroutine atm_dyn_dgm_globalnonhydro3d_etot_hevi_init( mesh )
    implicit none
    class(meshbase3d), intent(in) :: mesh
    !--------------------------------------------
 
    call atm_dyn_dgm_nonhydro3d_common_init( mesh )
    return
  end subroutine atm_dyn_dgm_globalnonhydro3d_etot_hevi_init
 
!OCL SERIAL
  subroutine atm_dyn_dgm_globalnonhydro3d_etot_hevi_final()
    implicit none
    !--------------------------------------------
    
    call atm_dyn_dgm_nonhydro3d_common_final()    
    return
  end subroutine atm_dyn_dgm_globalnonhydro3d_etot_hevi_final  
 
  !-------------------------------
 
!OCL SERIAL
  subroutine atm_dyn_dgm_globalnonhydro3d_etot_hevi_cal_tend( &
    DENS_dt, MOMX_dt, MOMY_dt, MOMZ_dt, EnTot_dt,             & ! (out)
    ddens_, momx_, momy_, momz_, etot_, dpres_,               & ! (in)
    dens_hyd, pres_hyd, pres_hyd_ref, therm_hyd,              & ! (in)
    coriolis, rtot, cvtot, cptot, dphyddx, dphyddy,           & ! (in)
    element3d_operation, dx, dy, dz, sx, sy, sz, lift,        & ! (in)
    lmesh, elem, lmesh2d, elem2d )                              ! (in)
 
    use scale_atm_dyn_dgm_nonhydro3d_etot_hevi_numflux, only: &
      get_ebnd_flux => atm_dyn_dgm_nonhydro3d_etot_hevi_numflux_get_generalhvc
    use scale_const, only: &
      ohm => const_ohm
    implicit none
 
    class(localmesh3d), intent(in) :: lmesh
    class(elementbase3d), intent(in) :: elem
    class(localmesh2d), intent(in) :: lmesh2d
    class(elementbase2d), intent(in) :: elem2d
    class(elementoperationbase3d), intent(in) :: element3d_operation
    type(sparsemat), intent(in) :: dx, dy, dz, sx, sy, sz, lift
    real(rp), intent(out) :: dens_dt(elem%np,lmesh%nea)
    real(rp), intent(out) :: momx_dt(elem%np,lmesh%nea)
    real(rp), intent(out) :: momy_dt(elem%np,lmesh%nea)
    real(rp), intent(out) :: momz_dt(elem%np,lmesh%nea)
    real(rp), intent(out) :: entot_dt(elem%np,lmesh%nea)
    real(rp), intent(in)  :: ddens_(elem%np,lmesh%nea)
    real(rp), intent(in)  :: momx_(elem%np,lmesh%nea)
    real(rp), intent(in)  :: momy_(elem%np,lmesh%nea)
    real(rp), intent(in)  :: momz_(elem%np,lmesh%nea)
    real(rp), intent(in)  :: etot_(elem%np,lmesh%nea)
    real(rp), intent(in)  :: dpres_(elem%np,lmesh%nea)    
    real(rp), intent(in)  :: dens_hyd(elem%np,lmesh%nea)
    real(rp), intent(in)  :: pres_hyd(elem%np,lmesh%nea)
    real(rp), intent(in)  :: pres_hyd_ref(elem%np,lmesh%nea)
    real(rp), intent(in)  :: therm_hyd(elem%np,lmesh%nea)
    real(rp), intent(in)  :: coriolis(elem2d%np,lmesh2d%nea)
    real(rp), intent(in)  :: rtot (elem%np,lmesh%nea)    
    real(rp), intent(in)  :: cvtot(elem%np,lmesh%nea)
    real(rp), intent(in)  :: cptot(elem%np,lmesh%nea)
    real(rp), intent(in) :: dphyddx(elem%np,lmesh%nea)
    real(rp), intent(in) :: dphyddy(elem%np,lmesh%nea)
 
    real(rp) :: fx(elem%np), fy(elem%np), fz(elem%np), liftdelflx(elem%np)
    real(rp) :: dpres_hyd(elem%np), gradphyd_x(elem%np), gradphyd_y(elem%np)
    real(rp) :: del_flux(elem%nfptot,lmesh%ne,prgvar_num)
    real(rp) :: del_flux_hyd(elem%nfptot,lmesh%ne,2)
    real(rp) :: rdens_(elem%np), u_(elem%np), v_(elem%np), w_(elem%np), wt_(elem%np)
 
    real(rp) :: g11(elem%np), g12(elem%np), g22(elem%np)
    real(rp) :: gsqrtv(elem%np), rgsqrtv(elem%np)
    real(rp) :: x2d(elem2d%np,lmesh2d%ne), y2d(elem2d%np,lmesh2d%ne)
    real(rp) :: x(elem%np), y(elem%np), twoovdel2(elem%np)
    real(rp) :: cori(elem%np,2)
    logical :: is_panel1to4
    real(rp) :: s
 
    integer :: ke, ke2d
    integer :: p, p12, p3
 
    real(rp) :: gamm, rgamm    
    real(rp) :: rp0
    real(rp) :: rovp0, p0ovr
 
    real(rp) :: entot_(elem%np), enthalpy_(elem%np)
    real(rp) :: u1_(elem%np), u2_(elem%np)
    !------------------------------------------------------------------------
 
    call prof_rapstart('cal_dyn_tend_bndflux', 3)
    call get_ebnd_flux( &
      del_flux, del_flux_hyd,                                                  & ! (out)
      ddens_, momx_, momy_, momz_, etot_, dpres_, dens_hyd, pres_hyd,          & ! (in)
      rtot, cvtot, cptot,                                                      & ! (in)
      lmesh%Gsqrt, lmesh%GIJ(:,:,1,1), lmesh%GIJ(:,:,1,2), lmesh%GIJ(:,:,2,2), & ! (in)
      lmesh%G_ij(:,:,1,1), lmesh%G_ij(:,:,1,2), lmesh%G_ij(:,:,2,2),           & ! (in)
      lmesh%GsqrtH, lmesh%GI3(:,:,1), lmesh%GI3(:,:,2), lmesh%zlev(:,:),       & ! (in)
      lmesh%normal_fn(:,:,1), lmesh%normal_fn(:,:,2), lmesh%normal_fn(:,:,3),  & ! (in)
      lmesh%vmapM, lmesh%vmapP, elem%IndexH2Dto3D_bnd,                         & ! (in)
      lmesh, elem, lmesh2d, elem2d                                             ) ! (in)
    call prof_rapend('cal_dyn_tend_bndflux', 3)
 
    !-----
    call prof_rapstart('cal_dyn_tend_interior', 3)
    gamm  = cpdry / cvdry
    rgamm = cvdry / cpdry
    rp0   = 1.0_rp / pres00
    rovp0 = rdry * rp0
    p0ovr = pres00 / rdry
 
    s = 1.0_rp 
    is_panel1to4 = .true.
    if ( lmesh%panelID == 5 ) then
      is_panel1to4 = .false.
    else if ( lmesh%panelID == 6 ) then
      is_panel1to4 = .false.
      s = - 1.0_rp
    end if
 
    !$omp parallel private(                        &
    !$omp rdens_, u_, v_, w_, wt_,                 &
    !$omp entot_, enthalpy_, u1_, u2_,             &
    !$omp Fx, Fy, Fz, LiftDelFlx,                  &
    !$omp DPRES_hyd, GradPhyd_x, GradPhyd_y,       &
    !$omp G11, G12, G22, GsqrtV, RGsqrtV,          &
    !$omp X, Y, twoOVdel2,                         &
    !$omp CORI, ke, ke2D                           )
 
    !$omp do
    do ke2d = lmesh2d%NeS, lmesh2d%NeE
      x2d(:,ke2d) = tan(lmesh2d%pos_en(:,ke2d,1))
      y2d(:,ke2d) = tan(lmesh2d%pos_en(:,ke2d,2))
    end do
 
    !$omp do
    do ke = lmesh%NeS, lmesh%NeE
      !--
      ke2d = lmesh%EMap3Dto2D(ke)
      g11(:) = lmesh%GIJ(elem%IndexH2Dto3D,ke2d,1,1)
      g12(:) = lmesh%GIJ(elem%IndexH2Dto3D,ke2d,1,2)
      g22(:) = lmesh%GIJ(elem%IndexH2Dto3D,ke2d,2,2)
      gsqrtv(:)  = lmesh%Gsqrt(:,ke) / lmesh%GsqrtH(elem%IndexH2Dto3D,ke2d)
      rgsqrtv(:) = 1.0_rp / gsqrtv(:)
 
      !--
      rdens_(:) = 1.0_rp / ( ddens_(:,ke) + dens_hyd(:,ke) )
      u_(:) = momx_(:,ke) * rdens_(:)
      v_(:) = momy_(:,ke) * rdens_(:)
      w_(:) = momz_(:,ke) * rdens_(:)
      wt_(:) = w_(:) * rgsqrtv(:) + lmesh%GI3(:,ke,1) * u_(:) + lmesh%GI3(:,ke,2) * v_(:) 
      u1_(:) = lmesh%G_ij(elem%IndexH2Dto3D(:),ke2d,1,1) * u_(:) + lmesh%G_ij(elem%IndexH2Dto3D(:),ke2d,2,1) * v_(:)
      u2_(:) = lmesh%G_ij(elem%IndexH2Dto3D(:),ke2d,2,1) * u_(:) + lmesh%G_ij(elem%IndexH2Dto3D(:),ke2d,2,2) * v_(:)
 
      ! DPRES_(:) = ( CPtot(:,ke) / CVtot(:,ke) - 1.0_RP ) &
      !           * (   ETOT_(:,ke) - Grav * ( DDENS_(:,ke) + DENS_hyd(:,ke) ) * lmesh%zlev(:,ke)        &
      !               - 0.5_RP * ( MOMX_(:,ke) * u1_(:) + MOMY_(:,ke) * u2_(:) + MOMZ_(:,ke) * w_(:) ) ) &
      !           - PRES_hyd(:,ke)
      
      enthalpy_(:) = etot_(:,ke) + pres_hyd(:,ke) + dpres_(:,ke)
 
      x(:) = x2d(elem%IndexH2Dto3D,ke2d)
      y(:) = y2d(elem%IndexH2Dto3D,ke2d)
      twoovdel2(:) = 2.0_rp / ( 1.0_rp + x(:)**2 + y(:)**2 )
 
      cori(:,1) = s * ohm * twoovdel2(:) * ( - x(:) * y(:)        * momx_(:,ke) + (1.0_rp + y(:)**2) * momy_(:,ke) )
      cori(:,2) = s * ohm * twoovdel2(:) * ( - (1.0_rp + x(:)**2) * momx_(:,ke) +  x(:) * y(:)       * momy_(:,ke) )
      
      if ( is_panel1to4 ) then
        cori(:,1) = s * y(:) * cori(:,1)
        cori(:,2) = s * y(:) * cori(:,2)
      end if
 
      !-- Gradient hydrostatic pressure
      
      dpres_hyd(:) = pres_hyd(:,ke) - pres_hyd_ref(:,ke)
 
      call sparsemat_matmul(dx, gsqrtv(:) * dpres_hyd(:), fx)
      call sparsemat_matmul(dz, gsqrtv(:) * lmesh%GI3(:,ke,1) * dpres_hyd(:), fz)
      call sparsemat_matmul(lift, lmesh%Fscale(:,ke) * del_flux_hyd(:,ke,1), liftdelflx)
      gradphyd_x(:) = lmesh%Escale(:,ke,1,1) * fx(:) &
                    + lmesh%Escale(:,ke,3,3) * fz(:) &
                    + liftdelflx(:)
 
      call sparsemat_matmul(dy, gsqrtv(:) * dpres_hyd(:), fy)
      call sparsemat_matmul(dz, gsqrtv(:) * lmesh%GI3(:,ke,2) * dpres_hyd(:), fz)
      call sparsemat_matmul(lift, lmesh%Fscale(:,ke) * del_flux_hyd(:,ke,2), liftdelflx)
      gradphyd_y(:) = lmesh%Escale(:,ke,2,2) * fy(:) &
                    + lmesh%Escale(:,ke,3,3) * fz(:) &
                    + liftdelflx(:)
      
      !-- DENS
      call sparsemat_matmul(dx, lmesh%Gsqrt(:,ke) * momx_(:,ke), fx)
      call sparsemat_matmul(dy, lmesh%Gsqrt(:,ke) * momy_(:,ke), fy)
      call sparsemat_matmul(lift, lmesh%Fscale(:,ke) * del_flux(:,ke,dens_vid), liftdelflx)
 
      dens_dt(:,ke) = - ( &
            lmesh%Escale(:,ke,1,1) * fx(:)     &
          + lmesh%Escale(:,ke,2,2) * fy(:)     &
          + liftdelflx(:) ) / lmesh%Gsqrt(:,ke)
      
      !-- MOMX
      call sparsemat_matmul(dx, lmesh%Gsqrt(:,ke) * ( u_(:) * momx_(:,ke) + g11(:) * dpres_(:,ke) ), fx)
      call sparsemat_matmul(dy, lmesh%Gsqrt(:,ke) * ( v_(:) * momx_(:,ke) + g12(:) * dpres_(:,ke) ), fy)
      call sparsemat_matmul(dz, lmesh%Gsqrt(:,ke) * ( wt_(:) * momx_(:,ke)                              &
                                                    + ( lmesh%GI3(:,ke,1) * g11(:) + lmesh%GI3(:,ke,2) * g12(:) ) * dpres_(:,ke) ), fz)
      call sparsemat_matmul(lift, lmesh%Fscale(:,ke) * del_flux(:,ke,momx_vid), liftdelflx)
 
      momx_dt(:,ke) = &
          - ( lmesh%Escale(:,ke,1,1) * fx(:)                                         &
            + lmesh%Escale(:,ke,2,2) * fy(:)                                         &
            + lmesh%Escale(:,ke,3,3) * fz(:)                                         &
            + liftdelflx(:)                   ) / lmesh%Gsqrt(:,ke)                  &
          + twoovdel2(:) * y(:) *                                                    &
            ( - x(:) * y(:) * u_(:) + (1.0_rp + y(:)**2) * v_(:) ) * momx_(:,ke)     &
          - ( g11(:) * gradphyd_x(:) + g12(:) * gradphyd_y(:) ) * rgsqrtv(:)         &
          + cori(:,1)              
 
      !-- MOMY
      call sparsemat_matmul(dx, lmesh%Gsqrt(:,ke) * ( u_(:) * momy_(:,ke) + g12(:) * dpres_(:,ke) ), fx)
      call sparsemat_matmul(dy, lmesh%Gsqrt(:,ke) * ( v_(:) * momy_(:,ke) + g22(:) * dpres_(:,ke) ), fy)
      call sparsemat_matmul(dz, lmesh%Gsqrt(:,ke) * ( wt_(:) * momy_(:,ke)                              &
                                                    + ( lmesh%GI3(:,ke,1) * g12(:) + lmesh%GI3(:,ke,2) * g22(:) ) * dpres_(:,ke) ), fz)
      call sparsemat_matmul(lift, lmesh%Fscale(:,ke) * del_flux(:,ke,momy_vid), liftdelflx)
 
      momy_dt(:,ke) = &
            - ( lmesh%Escale(:,ke,1,1) * fx(:)                                         &
              + lmesh%Escale(:,ke,2,2) * fy(:)                                         &
              + lmesh%Escale(:,ke,3,3) * fz(:)                                         &
              + liftdelflx(:)                  ) / lmesh%Gsqrt(:,ke)                   &
            + twoovdel2(:) * x(:) *                                                    &
              ( (1.0_rp + x(:)**2) * u_(:) - x(:) * y(:) * v_(:) ) * momy_(:,ke)       &
            - ( g12(:) * gradphyd_x(:) + g22(:) * gradphyd_y(:) ) * rgsqrtv(:)         &
            + cori(:,2) 
 
      !-- MOMZ
      call sparsemat_matmul(dx, lmesh%Gsqrt(:,ke) *   u_(:) * momz_(:,ke), fx)
      call sparsemat_matmul(dy, lmesh%Gsqrt(:,ke) *   v_(:) * momz_(:,ke), fy)
      call sparsemat_matmul(dz, lmesh%Gsqrt(:,ke) *   wt_(:) * momz_(:,ke), fz)
      call sparsemat_matmul(lift, lmesh%Fscale(:,ke) * del_flux(:,ke,momz_vid), liftdelflx)
      
      momz_dt(:,ke) = &
          - ( lmesh%Escale(:,ke,1,1) * fx(:)       &
            + lmesh%Escale(:,ke,2,2) * fy(:)       &
            + lmesh%Escale(:,ke,3,3) * fz(:)       &
            + liftdelflx(:) ) / lmesh%Gsqrt(:,ke)
 
      !-- EnTot
      call sparsemat_matmul(dx, lmesh%Gsqrt(:,ke) * u_(:) * enthalpy_(:), fx)
      call sparsemat_matmul(dy, lmesh%Gsqrt(:,ke) * v_(:) * enthalpy_(:), fy)
      call sparsemat_matmul(lift, lmesh%Fscale(:,ke) * del_flux(:,ke,etot_vid), liftdelflx)
      
      entot_dt(:,ke) = &
          - ( lmesh%Escale(:,ke,1,1) * fx(:)      &
            + lmesh%Escale(:,ke,2,2) * fy(:)      &
            + liftdelflx(:) ) / lmesh%Gsqrt(:,ke) 
 
    end do
    !$omp end do
    !$omp end parallel
    call prof_rapend('cal_dyn_tend_interior', 3)
 
    return
  end subroutine atm_dyn_dgm_globalnonhydro3d_etot_hevi_cal_tend
 
!OCL SERIAL  
  subroutine atm_dyn_dgm_globalnonhydro3d_etot_hevi_cal_vi( &
    DENS_dt, MOMX_dt, MOMY_dt, MOMZ_dt, ETOT_dt,             & ! (out)
    ddens_, momx_, momy_, momz_, etot_, dens_hyd, pres_hyd,  & ! (in)
    ddens0_, momx0_, momy0_, momz0_, etot0_,                 & ! (in)
    rtot, cvtot, cptot,                                      & ! (in)
    element3d_operation, dz, lift,                           & ! (in)
    impl_fac, dt,                                            & ! (in)
    lmesh, elem, lmesh2d, elem2d                             ) ! (in)
 
    use scale_atm_dyn_dgm_nonhydro3d_etot_hevi_common, only: &
      vi_eval_ax => atm_dyn_dgm_nonhydro3d_etot_hevi_common_eval_ax,                    &
      vi_eval_ax_uv => atm_dyn_dgm_nonhydro3d_etot_hevi_common_eval_ax_uv,              &
      vi_construct_matbnd => atm_dyn_dgm_nonhydro3d_etot_hevi_common_construct_matbnd,  &
      vi_construct_matbnd_uv => atm_dyn_dgm_nonhydro3d_etot_hevi_common_construct_matbnd_uv
      
    implicit none
 
    class(localmesh3d), intent(in) :: lmesh
    class(elementbase3d), intent(in) :: elem
    class(localmesh2d), intent(in) :: lmesh2d
    class(elementbase2d), intent(in) :: elem2d
    real(rp), intent(out) :: dens_dt(elem%np,lmesh%nea)
    real(rp), intent(out) :: momx_dt(elem%np,lmesh%nea)
    real(rp), intent(out) :: momy_dt(elem%np,lmesh%nea)
    real(rp), intent(out) :: momz_dt(elem%np,lmesh%nea)
    real(rp), intent(out) :: etot_dt(elem%np,lmesh%nea)
    real(rp), intent(in)  :: ddens_(elem%np,lmesh%nea)
    real(rp), intent(in)  :: momx_(elem%np,lmesh%nea)
    real(rp), intent(in)  :: momy_(elem%np,lmesh%nea)
    real(rp), intent(in)  :: momz_(elem%np,lmesh%nea)
    real(rp), intent(in)  :: etot_(elem%np,lmesh%nea)
    real(rp), intent(in)  :: dens_hyd(elem%np,lmesh%nea)
    real(rp), intent(in)  :: pres_hyd(elem%np,lmesh%nea)
    real(rp), intent(in)  :: ddens0_(elem%np,lmesh%nea)
    real(rp), intent(in)  :: momx0_(elem%np,lmesh%nea)
    real(rp), intent(in)  :: momy0_(elem%np,lmesh%nea)
    real(rp), intent(in)  :: momz0_(elem%np,lmesh%nea)
    real(rp), intent(in)  :: etot0_(elem%np,lmesh%nea)
    real(rp), intent(in)  :: rtot(elem%np,lmesh%nea)
    real(rp), intent(in)  :: cvtot(elem%np,lmesh%nea)
    real(rp), intent(in)  :: cptot(elem%np,lmesh%nea)
    class(elementoperationbase3d), intent(in) :: element3d_operation
    class(sparsemat), intent(in) :: dz, lift
    real(rp), intent(in) :: impl_fac
    real(rp), intent(in) :: dt
 
    real(rp) :: prog_vars (elem%np,lmesh%nez,prgvar_num,lmesh%nex*lmesh%ney)
    real(rp) :: dpres     (elem%np,lmesh%nez,lmesh%nex*lmesh%ney)
    real(rp) :: prog_vars0(elem%np,lmesh%nez,prgvar_num,lmesh%nex*lmesh%ney)
    real(rp) :: dpres0    (elem%np,lmesh%nez,lmesh%nex*lmesh%ney)
    real(rp) :: b1d(3,elem%nnode_v,lmesh%nez,elem%nnode_h1d**2,lmesh%nex*lmesh%ney)
    real(rp) :: geopot    (elem%np,lmesh%nez,lmesh%nex*lmesh%ney)
    real(rp) :: kinhovdens(elem%np,lmesh%nez,lmesh%nex*lmesh%ney)
    integer :: ipiv(elem%nnode_v*3*lmesh%nez,elem%nnode_h1d**2)
    real(rp) :: b1d_uv(elem%nnode_v,lmesh%nez,2,elem%nnode_h1d**2,lmesh%nex*lmesh%ney)
    integer :: ipiv_uv(elem%nnode_v*1*lmesh%nez,elem%nnode_h1d**2)
    real(rp) :: alph(elem%nfptot,lmesh%nez,lmesh%nex*lmesh%ney)
    real(rp) :: rtot_z(elem%np,lmesh%nez,lmesh%nex*lmesh%ney)
    real(rp) :: cptot_ov_cvtot(elem%np,lmesh%nez,lmesh%nex*lmesh%ney)
    real(rp) :: dens_hyd_z(elem%np,lmesh%nez,lmesh%nex*lmesh%ney)
    real(rp) :: pres_hyd_z(elem%np,lmesh%nez,lmesh%nex*lmesh%ney)
    real(rp) :: gnnm_z(elem%np,lmesh%nez,lmesh%nex*lmesh%ney)
    real(rp) :: g13_z(elem%np,lmesh%nez,lmesh%nex*lmesh%ney)
    real(rp) :: g23_z(elem%np,lmesh%nez,lmesh%nex*lmesh%ney)
    real(rp) :: gsqrtv_z(elem%np,lmesh%nez,lmesh%nex*lmesh%ney)
    real(rp) :: nz(elem%nfptot,lmesh%nez,lmesh%nex*lmesh%ney)
    integer :: vmapm(elem%nfptot,lmesh%nez)
    integer :: vmapp(elem%nfptot,lmesh%nez)
    integer :: colmask(elem%nnode_v)
    integer :: ke_xy, ke_z, ke, ke2d, v
    integer :: itr_nlin
    integer :: kl, ku, nz_1d
    integer :: kl_uv, ku_uv, nz_1d_uv
    integer :: ij
    logical :: is_converged
 
    real(rp), allocatable :: pmatbnd(:,:,:)
    real(rp), allocatable :: pmatbnd_uv(:,:,:)
    integer :: info, info_uv
 
    real(rp) :: dens_(elem%np)
    !------------------------------------------------------------------------
 
    call prof_rapstart( 'hevi_cal_vi_prep', 3)
 
    nz_1d = elem%Nnode_v * 3 * lmesh%NeZ
    kl = ( elem%Nnode_v + 1 ) * 3 - 1
    ku = kl
    nz_1d_uv = elem%Nnode_v * 1 * lmesh%NeZ
    kl_uv = elem%Nnode_v
    ku_uv = kl_uv
    allocate( pmatbnd(2*kl+ku+1,nz_1d,elem%Nnode_h1D**2) )
    allocate( pmatbnd_uv(2*kl_uv+ku_uv+1,nz_1d_uv,elem%Nnode_h1D**2) )
 
    call lmesh%GetVmapZ1D( vmapm, vmapp ) ! (out)
 
    !-
    
    !$omp parallel private( ke_xy, ke_z, ke, ke2D, DENS_ )
    !$omp do collapse(2)
    do ke_xy=1, lmesh%NeX*lmesh%NeY
    do ke_z=1, lmesh%NeZ
      ke = ke_xy + (ke_z-1)*lmesh%NeX*lmesh%NeY
      ke2d = lmesh%EMap3Dto2D(ke)
 
      prog_vars(:,ke_z,dens_vid,ke_xy) = ddens0_(:,ke)
      prog_vars(:,ke_z,momx_vid,ke_xy) = momx0_(:,ke)
      prog_vars(:,ke_z,momy_vid,ke_xy) = momy0_(:,ke)
      prog_vars(:,ke_z,momz_vid,ke_xy) = momz0_(:,ke)
      prog_vars(:,ke_z,etot_vid,ke_xy) = etot0_(:,ke)
 
      dens_hyd_z(:,ke_z,ke_xy) = dens_hyd(:,ke)
      pres_hyd_z(:,ke_z,ke_xy) = pres_hyd(:,ke)
      geopot(:,ke_z,ke_xy) = grav * lmesh%zlev(:,ke)
 
      dens_(:) = dens_hyd(:,ke) + ddens0_(:,ke)
      kinhovdens(:,ke_z,ke_xy) = 0.5_rp * ( &
          momx0_(:,ke) * ( lmesh%G_ij(elem%IndexH2Dto3D,ke2d,1,1) * momx0_(:,ke) + lmesh%G_ij(elem%IndexH2Dto3D,ke2d,2,1) * momy0_(:,ke) ) &
        + momy0_(:,ke) * ( lmesh%G_ij(elem%IndexH2Dto3D,ke2d,2,1) * momx0_(:,ke) + lmesh%G_ij(elem%IndexH2Dto3D,ke2d,2,2) * momy0_(:,ke) ) &
        ) / dens_(:)**2
        
      rtot_z(:,ke_z,ke_xy) = rtot(:,ke)
      cptot_ov_cvtot(:,ke_z,ke_xy) = cptot(:,ke) / cvtot(:,ke)
      
      dpres(:,ke_z,ke_xy) = &
        ( cptot_ov_cvtot(:,ke_z,ke_xy) - 1.0_rp ) &
         * ( etot0_(:,ke) - ( dens_(:) * ( kinhovdens(:,ke_z,ke_xy) + geopot(:,ke_z,ke_xy) ) + 0.5_rp * momz0_(:,ke)**2 / dens_(:) ) ) &
        - pres_hyd(:,ke)
 
      nz(:,ke_z,ke_xy) = lmesh%normal_fn(:,ke,3)
      g13_z(:,ke_z,ke_xy) = lmesh%GI3(:,ke,1)
      g23_z(:,ke_z,ke_xy) = lmesh%GI3(:,ke,2)
      gsqrtv_z(:,ke_z,ke_xy) = lmesh%Gsqrt(:,ke) / lmesh%GsqrtH(elem%IndexH2Dto3D,ke2d)
 
      gnnm_z(:,ke_z,ke_xy) = ( &
          1.0_rp / gsqrtv_z(:,ke_z,ke_xy)**2                                                    &
        + g13_z(:,ke_z,ke_xy) * ( lmesh%GIJ(elem%IndexH2Dto3D,ke2d,1,1) * g13_z(:,ke_z,ke_xy)   &
                                + lmesh%GIJ(elem%IndexH2Dto3D,ke2d,1,2) * g23_z(:,ke_z,ke_xy) ) &
        + g23_z(:,ke_z,ke_xy) * ( lmesh%GIJ(elem%IndexH2Dto3D,ke2d,1,2) * g13_z(:,ke_z,ke_xy)   &
                                + lmesh%GIJ(elem%IndexH2Dto3D,ke2d,2,2) * g23_z(:,ke_z,ke_xy) ) )
    end do
    end do
    !$omp end do
    !$omp workshare
    prog_vars0(:,:,:,:) = prog_vars(:,:,:,:)
    dpres0(:,:,:) = dpres(:,:,:)
    !$omp end workshare
    !$omp end parallel
      
    call prof_rapend( 'hevi_cal_vi_prep', 3)
 
    !--
 
    if ( abs(impl_fac) > 0.0_rp ) then
      call prof_rapstart( 'hevi_cal_vi_itr', 3)
 
      ! G = (q^n+1 - q^n*) + impl_fac * A(q^n+1) = 0
      ! dG/dq^n+1 del[q] = - G(q^n*)
      do itr_nlin = 1, 1
        call prof_rapstart( 'hevi_cal_vi_ax', 3)
 
        call vi_eval_ax_uv( &
          momx_dt(:,:), momy_dt(:,:), alph(:,:,:),                              & ! (out, dummy)
          prog_vars, dpres, prog_vars0, dpres0,                                 & ! (in)
          ddens_, momx_, momy_, momz_, etot_,                                   & ! (in)
          dens_hyd_z, pres_hyd_z,                                               & ! (in)
          rtot_z, cptot_ov_cvtot,                                               & ! (in)
          dz, lift, intrpmat_vpordm1,                                           & ! (in)
          gnnm_z, g13_z, g23_z, gsqrtv_z,                                       & ! (in)
          impl_fac, dt,                                                         & ! (in) 
          lmesh, elem, nz, vmapm, vmapp,                                        & ! (in)
          b1d_uv(:,:,:,:,:)                                                     ) ! (out)
 
        call prof_rapend( 'hevi_cal_vi_ax', 3)
 
        do ke_xy=1, lmesh%NeX * lmesh%NeY
          call prof_rapstart( 'hevi_cal_vi_matbnd', 3)
          call vi_construct_matbnd_uv( pmatbnd_uv(:,:,:),              & ! (out)
            kl_uv, ku_uv, nz_1d_uv,                                    & ! (in)
            prog_vars(:,:,:,ke_xy), kinhovdens(:,:,ke_xy),             & ! (in)
            dens_hyd_z(:,:,ke_xy), pres_hyd_z(:,:,ke_xy),              & ! (in)
            g13_z(:,:,ke_xy), g23_z(:,:,ke_xy), gsqrtv_z(:,:,ke_xy),   & ! (in)
            alph(:,:,ke_xy),                                           & ! (in)
            rtot_z(:,:,ke_xy), cptot_ov_cvtot(:,:,ke_xy),              & ! (in)
            geopot(:,:,ke_xy),                                         & ! (in)
            dz, lift, intrpmat_vpordm1,                                & ! (in)
            impl_fac, dt,                                              & ! (in)
            lmesh, elem, nz(:,:,ke_xy), vmapm, vmapp, ke_xy, 1         ) ! (in)
          call prof_rapend( 'hevi_cal_vi_matbnd', 3)
 
          call prof_rapstart( 'hevi_cal_vi_lin', 3)
          !$omp parallel private(ij, v, ke_z, info, ColMask)
          !$omp do
          do ij=1, elem%Nnode_h1D**2
            call dgbsv( nz_1d_uv, kl_uv, ku_uv, 2, pmatbnd_uv(:,:,ij), 2*kl_uv+ku_uv+1, ipiv_uv(:,ij), b1d_uv(:,:,:,ij,ke_xy), nz_1d_uv, info)
 
            colmask(:) = elem%Colmask(:,ij)
            do ke_z=1, lmesh%NeZ
              prog_vars(colmask(:),ke_z,momx_vid,ke_xy) = prog_vars(colmask(:),ke_z,momx_vid,ke_xy) + b1d_uv(:,ke_z,1,ij,ke_xy)
              prog_vars(colmask(:),ke_z,momy_vid,ke_xy) = prog_vars(colmask(:),ke_z,momy_vid,ke_xy) + b1d_uv(:,ke_z,2,ij,ke_xy)
            end do
          end do ! for ij
          !$omp end do
          !$omp end parallel
          call prof_rapend( 'hevi_cal_vi_lin', 3)
 
        end do ! for ke_xy
          
        call prof_rapstart( 'hevi_cal_vi_ax', 3)
        call vi_eval_ax( &
          dens_dt(:,:), momz_dt(:,:), etot_dt(:,:),                             & ! (out, dummy) 
          alph(:,:,:),                                                          & ! (in)
          prog_vars, dpres, prog_vars0, dpres0,                                 & ! (in)
          ddens_, momx_, momy_, momz_, etot_,                                   & ! (in)
          dens_hyd_z, pres_hyd_z,                                               & ! (in)
          rtot_z, cptot_ov_cvtot,                                               & ! (in)
          dz, lift, intrpmat_vpordm1,                                           & ! (in)
          gnnm_z, g13_z, g23_z, gsqrtv_z,                                       & ! (in)
          impl_fac, dt,                                                         & ! (in) 
          lmesh, elem, nz, vmapm, vmapp,                                        & ! (in)
          b1d(:,:,:,:,:)                                                        ) ! (out)
        call prof_rapend( 'hevi_cal_vi_ax', 3)
 
        do ke_xy=1, lmesh%NeX * lmesh%NeY
          call prof_rapstart( 'hevi_cal_vi_matbnd', 3)
          call vi_construct_matbnd( pmatbnd(:,:,:),                    & ! (out)
            kl, ku, nz_1d,                                             & ! (in)
            prog_vars(:,:,:,ke_xy), kinhovdens(:,:,ke_xy),             & ! (in)
            dens_hyd_z(:,:,ke_xy), pres_hyd_z(:,:,ke_xy),              & ! (in)
            g13_z(:,:,ke_xy), g23_z(:,:,ke_xy), gsqrtv_z(:,:,ke_xy),   & ! (in)
            alph(:,:,ke_xy),                                           & ! (in)
            rtot_z(:,:,ke_xy), cptot_ov_cvtot(:,:,ke_xy),              & ! (in)
            geopot(:,:,ke_xy),                                         & ! (in)
            dz, lift, intrpmat_vpordm1,                                & ! (in)
            impl_fac, dt,                                              & ! (in)
            lmesh, elem, nz(:,:,ke_xy), vmapm, vmapp, ke_xy, 1         ) ! (in)
          call prof_rapend( 'hevi_cal_vi_matbnd', 3)
 
          call prof_rapstart( 'hevi_cal_vi_lin', 3)
          !$omp parallel private(ij, v, ke_z, info, ColMask)
          !$omp do
          do ij=1, elem%Nnode_h1D**2
            call dgbsv( nz_1d, kl, ku, 1, pmatbnd(:,:,ij), 2*kl+ku+1, ipiv(:,ij), b1d(:,:,:,ij,ke_xy), nz_1d, info)
 
            colmask(:) = elem%Colmask(:,ij)
            do ke_z=1, lmesh%NeZ
              prog_vars(colmask(:),ke_z,dens_vid,ke_xy) = prog_vars(colmask(:),ke_z,dens_vid,ke_xy) + b1d(1,:,ke_z,ij,ke_xy)
              prog_vars(colmask(:),ke_z,momz_vid,ke_xy) = prog_vars(colmask(:),ke_z,momz_vid,ke_xy) + b1d(2,:,ke_z,ij,ke_xy)
              prog_vars(colmask(:),ke_z,etot_vid,ke_xy) = prog_vars(colmask(:),ke_z,etot_vid,ke_xy) + b1d(3,:,ke_z,ij,ke_xy)
            end do
          end do ! for ij
          !$omp end do
          !$omp do
          do ke_z=1, lmesh%NeZ
            dens_(:) = dens_hyd_z(:,ke_z,ke_xy) + prog_vars(:,ke_z,dens_vid,ke_xy)
            dpres(:,ke_z,ke_xy) = &
              ( cptot_ov_cvtot(:,ke_z,ke_xy) - 1.0_rp ) &
              * ( prog_vars(:,ke_z,etot_vid,ke_xy)                                                                                               &
                - ( dens_(:) * ( kinhovdens(:,ke_z,ke_xy) + geopot(:,ke_z,ke_xy) ) + 0.5_rp * prog_vars(:,ke_z,momz_vid,ke_xy)**2 / dens_(:) ) ) &
            - pres_hyd_z(:,ke_z,ke_xy)
          end do
          !$omp end parallel
          call prof_rapend( 'hevi_cal_vi_lin', 3)
 
        end do ! for ke_xy
      end do ! itr nlin
 
      call prof_rapend( 'hevi_cal_vi_itr', 3)
    end if
 
    call prof_rapstart( 'hevi_cal_vi_retrun_var', 3)
    if ( abs(impl_fac) > 0.0_rp) then
      !$omp parallel do collapse(2) private(ke_xy, ke_z, ke)
      do ke_xy=1, lmesh%NeX * lmesh%NeY
      do ke_z=1, lmesh%NeZ
        ke = ke_xy + (ke_z-1)*lmesh%NeX*lmesh%NeY
        dens_dt(:,ke) = ( prog_vars(:,ke_z,dens_vid,ke_xy) - ddens_(:,ke) ) / impl_fac
        momx_dt(:,ke) = ( prog_vars(:,ke_z,momx_vid,ke_xy) - momx_(:,ke) ) / impl_fac
        momy_dt(:,ke) = ( prog_vars(:,ke_z,momy_vid,ke_xy) - momy_(:,ke) ) / impl_fac
        momz_dt(:,ke) = ( prog_vars(:,ke_z,momz_vid,ke_xy) - momz_(:,ke) ) / impl_fac
        etot_dt(:,ke) = ( prog_vars(:,ke_z,etot_vid,ke_xy) - etot_(:,ke) ) / impl_fac
      end do
      end do
    else
      call vi_eval_ax_uv( &
        momx_dt(:,:), momy_dt(:,:), alph(:,:,:),                              & ! (out)
        prog_vars, dpres, prog_vars0, dpres0,                                 & ! (in)
        ddens_, momx_, momy_, momz_, etot_,                                   & ! (in)
        dens_hyd_z, pres_hyd_z,                                               & ! (in)
        rtot_z, cptot_ov_cvtot,                                               & ! (in)
        dz, lift, intrpmat_vpordm1,                                           & ! (in)
        gnnm_z, g13_z, g23_z, gsqrtv_z,                                       & ! (in)
        impl_fac, dt,                                                         & ! (in) 
        lmesh, elem, nz, vmapm, vmapp                                         ) ! (in)
          
      call vi_eval_ax( &
        dens_dt(:,:), momz_dt(:,:), etot_dt(:,:),                             & ! (out) 
        alph(:,:,:),                                                          & ! (in)
        prog_vars, dpres, prog_vars0, dpres0,                                 & ! (in)
        ddens_, momx_, momy_, momz_, etot_,                                   & ! (in)
        dens_hyd_z, pres_hyd_z,                                               & ! (in)
        rtot_z, cptot_ov_cvtot,                                               & ! (in)
        dz, lift, intrpmat_vpordm1,                                           & ! (in)
        gnnm_z, g13_z, g23_z, gsqrtv_z,                                       & ! (in)
        impl_fac, dt,                                                         & ! (in) 
        lmesh, elem, nz, vmapm, vmapp                                         ) ! (in)
    end if
    call prof_rapend( 'hevi_cal_vi_retrun_var', 3)
 
 
    return
  end subroutine atm_dyn_dgm_globalnonhydro3d_etot_hevi_cal_vi
 
end module scale_atm_dyn_dgm_globalnonhydro3d_etot_hevi