scale_coriolis_param.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!> Module common / Coriolis parameter 
!!
!! @par Description
!!      Setup coriolis parameter (for regional model)
!!
!!
!! @par Reference
!!
!! @author Yuta Kawai, Team SCALE
!!
#include "scaleFElib.h"
module scale_coriolis_param
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_const, only: &
    pi => const_pi,      &
    ohm => const_ohm
  
  use scale_io
  use scale_prc
 
  !-----------------------------------------------------------------------------
  implicit none
  private
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !  
  public :: get_coriolis_parameter
 
contains
 
!> Get Coriolis parameter
!OCL SERIAL
  subroutine get_coriolis_parameter( &
    coriolis,                        &
    COLIORIS_type, Np,               &
    y, f0, beta, y0,                 &
    lat                              )
 
    implicit none
 
    integer, intent(in) :: np                 !< Array size
    real(rp), intent(out) :: coriolis(np)     !< Array storing Coriolis parameter
    character(*), intent(in) :: colioris_type !< Type of Coriolis parameter [PLANE / SPHERE / NONE]
    real(rp), intent(in), optional :: y(np)   !< y-coordinate which is used when COLIORIS_type=PLANE
    real(rp), intent(in), optional :: f0      !< Value of Coriolis parameter at reference latitude which is used when COLIORIS_type=PLANE
    real(rp), intent(in), optional :: beta    !< Rossby parameter at reference latitude which is used when COLIORIS_type=PLANE
    real(rp), intent(in), optional :: y0      !< Distance from reference latitude
    real(rp), intent(in), optional :: lat(np) !< Latitude
 
    integer :: i
    !------------------------------------------
 
    if ( trim(colioris_type) == 'PLANE' ) then
      if ( ( .not. present(f0) ) .or. ( .not. present(beta) )    &
            .or. ( .not. present(y) ) .or. ( .not. present(y0) ) ) then
        log_error('get_coriolis_parameter',*) 'If COLIORIS_type is set to PLANE, f0 and beta must be passed. Check!'
        call prc_abort
      end if
      !$omp parallel do
      do i=1, np
        coriolis(i) = f0 + beta * ( y(i) - y0 )
      end do
    else if ( trim(colioris_type) == 'SPHERE' ) then
      if ( .not. present(lat) ) then
        log_error('get_coriolis_parameter',*) 'If COLIORIS_type is set to SPHERE, lat must be passed. Check!'
        call prc_abort
      end if
      !$omp parallel do
      do i=1, np
        coriolis(i) =  2.0_rp * ohm * sin( lat(i) )
      end do
    else if ( trim(colioris_type) == 'NONE' ) then
      !$omp parallel do
      do i=1, np
        coriolis(i) =  0.0_rp
      end do      
    else
      log_error('get_coriolis_parameter',*) 'Unexpected COLIORIS_type is specified. Check! COLIORIS_type=', colioris_type
      call prc_abort
    end if  
 
    return
  end subroutine get_coriolis_parameter
 
end module scale_coriolis_param