scale_meshfieldcomm_rectdom2d.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!> module FElib / Data / Communication 2D rectangle domain
!!
!! @par Description
!!      A module to manage data communication with 2D rectangle domain for element-based methods
!!
!! @author Yuta Kawai, Team SCALE
!<
#include "scaleFElib.h"
module scale_meshfieldcomm_rectdom2d
 
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
  use scale_prof
 
  use scale_element_base, only: &
    elementbase, elementbase2d
  use scale_mesh_rectdom2d, only: meshrectdom2d
  use scale_meshfield_base, only: meshfield2d
  use scale_meshfieldcomm_base, only: &
    meshfieldcommbase,                               &
    meshfieldcommbase_init, meshfieldcommbase_final, &
    meshfieldcommbase_extract_bounddata,             &
    meshfieldcommbase_extract_bounddata_2,           &
    meshfieldcommbase_extract_bounddata_3,           &
    meshfieldcommbase_set_bounddata,                 &
    meshfieldcommbase_set_bounddata_3,               &
    meshfieldcontainer
  use scale_localmesh_2d, only: localmesh2d
   
  !-----------------------------------------------------------------------------
  implicit none
  private
 
  !-----------------------------------------------------------------------------
  !
  !++ Public type & procedure
  ! 
 
  !> Base derived type to manage data communication with 2D rectangle domain
  type, public, extends(meshfieldcommbase) :: meshfieldcommrectdom2d
    class(meshrectdom2d), pointer :: mesh2d  !< Pointer to an object representing 2D rectangular computational mesh
 
    integer :: halosize_1d  !< Halo size in 1D direction
  contains
    procedure, public :: init => meshfieldcommrectdom2d_init
    procedure, public :: put => meshfieldcommrectdom2d_put
    procedure, public :: get => meshfieldcommrectdom2d_get
    procedure, public :: exchange => meshfieldcommrectdom2d_exchange  
    procedure, public :: final => meshfieldcommrectdom2d_final
  end type meshfieldcommrectdom2d
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  private :: push_localsendbuf
  
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  integer, parameter :: comm_face_num = 4  !< Number of faces with data communication
 
 
contains
!> Initialize an object to manage data communication with 2D rectangle domain
  subroutine meshfieldcommrectdom2d_init( this,        &
    sfield_num, hvfield_num, htensorfield_num, mesh2d, &
    haloSize_1D )
 
    use scale_meshutil_2d, only: meshutil2d_genpatchboundarymap_wide
    implicit none
    
    class(meshfieldcommrectdom2d), intent(inout) :: this
    integer, intent(in) :: sfield_num                    !< Number of scalar fields
    integer, intent(in) :: hvfield_num                   !< Number of horizontal vector fields
    integer, intent(in) :: htensorfield_num              !< Number of horizontal vector fields
    class(meshrectdom2d), intent(in), target :: mesh2d   !< Object to manage a 2D rectangular computational mesh
    integer, intent(in), optional :: halosize_1d         !< Halo size in 1D direction (default: 1)
    
    type(localmesh2d), pointer :: lcmesh
    type(elementbase2d), pointer :: elem
    integer :: n
    integer :: nnode_lcmeshface(comm_face_num,mesh2d%local_mesh_num)
    !-----------------------------------------------------------------------------
    
    this%mesh2d => mesh2d
    lcmesh => mesh2d%lcmesh_list(1)
    elem => lcmesh%refElem2D
 
    !-
    if ( present(halosize_1d) ) then
      this%haloSize_1D = halosize_1d
    else
      this%haloSize_1D = 1
    end if
 
    !-
    allocate( this%VMapB_size(this%mesh2d%LOCAL_MESH_NUM) )
 
    this%bufsize_per_field = 2 * (lcmesh%NeX + lcmesh%NeY) * elem%Nfp*this%haloSize_1D
 
    do n=1, this%mesh2d%LOCAL_MESH_NUM
      lcmesh => this%mesh2d%lcmesh_list(n)
      nnode_lcmeshface(:,n) = (/ lcmesh%NeX, lcmesh%NeY, lcmesh%NeX, lcmesh%NeY /) * lcmesh%refElem2D%Nfp*this%haloSize_1D
    end do
 
    call meshfieldcommbase_init( this, sfield_num, hvfield_num, htensorfield_num, this%bufsize_per_field, comm_face_num, nnode_lcmeshface, mesh2d)  
  
    !-
    if ( this%haloSize_1D > 1 ) then
      this%use_vmap_wide_flag = .true.
      allocate( this%VMapB2(this%bufsize_per_field) )
 
      lcmesh => this%mesh2d%lcmesh_list(1)      
      call meshutil2d_genpatchboundarymap_wide( this%VMapB2, &
        lcmesh%VMapB, this%haloSize_1D,                      &
        lcmesh%NeX, lcmesh%NeY,                              &
        elem%Nfp )
    else
      this%use_vmap_wide_flag = .false.
    end if
 
    do n=1, this%mesh2d%LOCAL_MESH_NUM
      lcmesh => this%mesh2d%lcmesh_list(n)
      if ( this%use_vmap_wide_flag ) then
        this%VMapB_size(n) = size(this%VMapB2)        
      else
        this%VMapB_size(n) = size(lcmesh%VMapB)
      end if
    end do
 
    return
  end subroutine meshfieldcommrectdom2d_init
 
!> Finalize an object to manage data communication with 2D rectangle domain
  subroutine meshfieldcommrectdom2d_final( this )
    implicit none
    class(meshfieldcommrectdom2d), intent(inout) :: this
    !-----------------------------------------------------------------------------
 
    call meshfieldcommbase_final( this )
    return
  end subroutine meshfieldcommrectdom2d_final
 
!> Put field data into temporary buffers  
  subroutine meshfieldcommrectdom2d_put(this, field_list, varid_s)
    implicit none
    class(meshfieldcommrectdom2d), intent(inout) :: this
    type(meshfieldcontainer), intent(in) :: field_list(:)
    integer, intent(in) :: varid_s  
    !-----------------------------------------------------------------------------
 
    call prof_rapstart( 'comm_put', 1)
    if ( this%use_vmap_wide_flag ) then
       call meshfieldcommbase_extract_bounddata_3( field_list, 2, varid_s, this%mesh2d%lcmesh_list, this%VMapB2, this%VMapB_size(1), this%send_buf )
    else
      call meshfieldcommbase_extract_bounddata_2( &
        field_list, 2, varid_s, this%mesh2d%lcmesh_list, size(this%mesh2d%lcmesh_list(1)%VMapB), & !(in)
        this%send_buf ) ! (out)
    end if
    call prof_rapend( 'comm_put', 1)
    return
  end subroutine meshfieldcommrectdom2d_put
 
 !> Extract field data from temporary buffers 
  subroutine meshfieldcommrectdom2d_get(this, field_list, varid_s)
    use scale_meshfieldcomm_base, only: &
      meshfieldcommbase_wait_core
    implicit none
    
    class(meshfieldcommrectdom2d), intent(inout) :: this
    type(meshfieldcontainer), intent(inout) :: field_list(:)
    integer, intent(in) :: varid_s
 
    integer :: i
    integer :: n
    type(localmesh2d), pointer :: lcmesh
    !-----------------------------------------------------------------------------
    call prof_rapstart( 'comm_get', 1)
 
    !--
    if ( this%call_wait_flag_sub_get ) then
      call meshfieldcommbase_wait_core( this, this%commdata_list, &
        field_list, 2, varid_s, this%mesh2d%lcmesh_list )
    else
      do i=1, size(field_list) 
      do n=1, this%mesh2d%LOCAL_MESH_NUM
        lcmesh => this%mesh2d%lcmesh_list(n)
        if ( this%use_vmap_wide_flag ) then
          call meshfieldcommbase_set_bounddata_3( this%recv_buf(:,varid_s+i-1,n), lcmesh%refElem, lcmesh, & ! (in)
            this%VMapB2, this%VMapB_size(1),                                                              & ! (in)
            field_list(i)%field2d%local(n)%val )                                                            ! (inout)
        else        
          call meshfieldcommbase_set_bounddata( this%recv_buf(:,varid_s+i-1,n), lcmesh%refElem, lcmesh, & !(in)
            field_list(i)%field2d%local(n)%val )                                                         !(out)
        end if
      end do
      end do
      !$acc wait(1)
    end if
    call prof_rapend( 'comm_get', 1)
 
    return
  end subroutine meshfieldcommrectdom2d_get
 
!> Exchange field data between neighboring MPI processes
!!
!OCL SERIAL
  subroutine meshfieldcommrectdom2d_exchange( this, do_wait )
    use scale_meshfieldcomm_base, only: &
      meshfieldcommbase_exchange_core,  &
      localmeshcommdata
 
    implicit none
  
    class(meshfieldcommrectdom2d), intent(inout), target :: this
    logical, intent(in), optional :: do_wait
 
    integer :: n, f
    type(localmesh2d), pointer :: lcmesh
    type(localmeshcommdata), pointer :: commdata
    !-----------------------------------------------------------------------------
 
    call prof_rapstart( 'comm_exchange_1', 1)
 
    do n=1, this%mesh%LOCAL_MESH_NUM
      lcmesh => this%mesh2d%lcmesh_list(n)
      do f=1, this%nfaces_comm
        commdata => this%commdata_list(f,n)
        call push_localsendbuf( commdata%send_buf,                  &  ! (inout)
          this%send_buf(:,:,n), commdata%s_faceID, this%is_f(f,n),  &  ! (in)
          commdata%Nnode_LCMeshFace, this%bufsize_per_field,        &  ! (in)
          this%field_num_tot, lcmesh, this%HaloSize_1D )               ! (in)
      end do
    end do
    !$acc wait(1)
 
    call prof_rapend( 'comm_exchange_1', 1)
    !-----------------------
 
    call prof_rapstart( 'comm_exchange_2', 1)
 
    call meshfieldcommbase_exchange_core( this, this%commdata_list, do_wait )
 
    !---------------------
    call prof_rapend( 'comm_exchange_2', 1)
 
    return
  end subroutine meshfieldcommrectdom2d_exchange
 
!----------------------------
 
  !> Push temporary buffer of the local send data to the communication buffer
!OCL SERIAL
  subroutine push_localsendbuf( lc_send_buf, &
    send_buf, s_faceID, is, Nnode_LCMeshFace, bufsize_per_field, var_num, &
    lcmesh, haloSize_1D )
    use scale_prc, only: prc_abort
    implicit none
 
    integer, intent(in) :: var_num
    integer, intent(in) :: nnode_lcmeshface
    integer, intent(in) :: bufsize_per_field
    real(rp), intent(inout) :: lc_send_buf(nnode_lcmeshface,var_num)
    real(rp), intent(in) :: send_buf(bufsize_per_field,var_num)
    integer, intent(in) :: s_faceid, is
    type(localmesh2d), intent(in) :: lcmesh
    integer, intent(in) :: halosize_1d
 
    integer :: i, v
    integer :: ne_h1d
    integer :: nfp
    !-----------------------------------------------------------------------------
 
    if ( s_faceid > 0 ) then
      !$omp parallel do
      !$acc parallel loop collapse(2) present(lc_send_buf, send_buf) async(1)
      do v=1, var_num
      do i=1, nnode_lcmeshface
        lc_send_buf(i,v) = send_buf((is-1)*halosize_1d+i,v)
      end do
      end do
    else if ( s_faceid < 0 ) then
      log_info("MeshFieldCommRectDom2D",'(a,i0)') "Encountered s_faceID <= 0 in push_localsendbuf. Check! s_faceID=", s_faceid
      call prc_abort
    end if
    return
  end subroutine push_localsendbuf
 
end module scale_meshfieldcomm_rectdom2d