scale_meshutil_cubedsphere3d.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!> module FElib / Mesh / utility for 3D cubed-sphere mesh
!!
!! @par Description
!!          A module useful for generating 3D cubed-sphere mesh
!!
!! @author Yuta Kawai, Team SCALE
!<
!-------------------------------------------------------------------------------
#include "scaleFElib.h"
module scale_meshutil_cubedsphere3d
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_const, only: &
    pi => const_pi,      &
    eps => const_eps
  use scale_precision
  use scale_prc
  use scale_io
  use scale_prc
 
  use scale_meshutil_3d, only: &
    meshutilcubedsphere3d_gencubedomain    => meshutil3d_gencubedomain,                   &
    meshutilcubedsphere3d_genconnectivity  => meshutil3d_genconnectivity,                 &
    meshutilcubedsphere3d_buildinteriormap => meshutil3d_buildinteriormap,                &
    meshutilcubedsphere3d_genpatchboundarymap => meshutil3d_genpatchboundarymap,          &
    meshutilcubedsphere3d_genpatchboundarymap_wide => meshutil3d_genpatchboundarymap_wide
  implicit none
  private
  
  !-----------------------------------------------------------------------------
  !
  !++ Public procedure
  !
  public :: meshutilcubedsphere3d_gencubedomain
  public :: meshutilcubedsphere3d_genconnectivity  
  public :: meshutilcubedsphere3d_buildinteriormap
  public :: meshutilcubedsphere3d_buildglobalmap
  public :: meshutilcubedsphere3d_genpatchboundarymap
  public :: meshutilcubedsphere3d_genpatchboundarymap_wide
  
contains
!OCL SERIAL
  subroutine meshutilcubedsphere3d_buildglobalmap( &
    panelID_table, pi_table, pj_table, pk_table,    &
    tileID_map, tileFaceID_map, tilePanelID_map,    &
    Ntile,                                          &
    NeZ  )
    
    ! use scale_prc, only: PRC_isMaster
    use scale_meshutil_3d, only: &
      meshutil3d_genconnectivity
    use scale_meshutil_cubedsphere2d, only: &
      meshutilcubedsphere2d_modifyconnectivity
    implicit none
 
    integer, intent(in) :: ntile
    integer, intent(out) :: panelid_table(ntile)
    integer, intent(out) :: pi_table(ntile)
    integer, intent(out) :: pj_table(ntile)
    integer, intent(out) :: pk_table(ntile)
    integer, intent(out) :: tileid_map(6,ntile)
    integer, intent(out) :: tilefaceid_map(6,ntile)
    integer, intent(out) :: tilepanelid_map(6,ntile)
    integer, intent(in) :: nez
 
    integer :: ntileperpanel
    integer :: nex, ney, nvx, nvy, nvz
    integer, allocatable :: nodesid_3d(:,:,:,:)
    integer, allocatable :: etov(:,:)
    integer, allocatable :: etoe(:,:)
    integer, allocatable :: etof(:,:)
    integer :: i, j, k, f
    integer :: panelid
    integer :: tileid, tileid_r
    integer :: counter
    
    integer :: pi_, pj_
    !-----------------------------------------------------------------------------
 
    ntileperpanel = ntile / 6
    ney = int( sqrt(dble(ntileperpanel)) )
    nex = ntileperpanel/ney
    nvx = nex + 1
    nvy = ney + 1
    nvz = nez + 1
    allocate( nodesid_3d(nvx,nvy,nvz,6) )
    allocate( etov(ntile,8), etoe(ntile,6), etof(ntile,6) )
 
    counter = 0
    do panelid = 1, 6
    do k = 1, nvz
    do j = 1, nvy
    do i = 1, nvx
      counter = counter + 1
      nodesid_3d(i,j,k,panelid) = counter
    end do
    end do
    end do
    end do
 
    !----
 
    tileid = 0
    do panelid = 1, 6
    do k = 1, nez
    do j = 1, ney
    do i = 1, nex
      tileid = tileid + 1
      panelid_table(tileid) = panelid
      pi_table(tileid) = i; pj_table(tileid) = j; pk_table(tileid) = k
      etov(tileid,:) = (/ nodesid_3d(i,j  ,k  ,panelid), nodesid_3d(i+1,j  ,k  ,panelid), &
                          nodesid_3d(i,j+1,k  ,panelid), nodesid_3d(i+1,j+1,k  ,panelid), &
                          nodesid_3d(i,j  ,k+1,panelid), nodesid_3d(i+1,j  ,k+1,panelid), &
                          nodesid_3d(i,j+1,k+1,panelid), nodesid_3d(i+1,j+1,k+1,panelid)  /)
    end do
    end do
    end do
    end do
 
    call meshutil3d_genconnectivity( etoe, etof, &
      etov, ntile, 6 )
    tileid_map(:,:) = transpose(etoe)
    tilefaceid_map(:,:) = transpose(etof)
    
    do tileid=1, ntile
    do f=1, 6
      tileid_r = tileid_map(f,tileid)
      tilepanelid_map(f,tileid) = panelid_table(tileid_r)
    end do
    end do
 
    call meshutilcubedsphere2d_modifyconnectivity( &
      tilepanelid_map, tileid_map, tilefaceid_map,          & ! (inout)
      panelid_table, pi_table, pj_table, nex, ney, ntile, 6 ) ! (in)
        
    return
  end subroutine meshutilcubedsphere3d_buildglobalmap
 
end module scale_meshutil_cubedsphere3d