scale_meshfieldcomm_1d.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!> module FElib / Data / Communication 1D
!!
!! @par Description
!!      A module to manage 1D data communication for element-based methods
!!
!! @author Yuta Kawai, Team SCALE
!<
#include "scaleFElib.h"
module scale_meshfieldcomm_1d
 
  !-----------------------------------------------------------------------------
  !
  !++ used modules
  !
  use scale_precision
  use scale_io
 
  use scale_element_base, only: elementbase, elementbase1d
  use scale_mesh_base1d, only: meshbase1d
  use scale_meshfield_base, only: meshfield1d
  use scale_meshfieldcomm_base, only: &
    meshfieldcommbase,                               &
    meshfieldcommbase_init, meshfieldcommbase_final, &
    meshfieldcommbase_extract_bounddata,             &
    meshfieldcommbase_extract_bounddata_2,           &
    meshfieldcommbase_extract_bounddata_3,           &
    meshfieldcommbase_set_bounddata,                 &
    meshfieldcommbase_set_bounddata_3,               &
    meshfieldcontainer
  use scale_localmesh_1d, only: localmesh1d
   
  !-----------------------------------------------------------------------------
  implicit none
  private
 
  !-----------------------------------------------------------------------------
  !
  !++ Public type & procedure
  ! 
 
  !> Base derived type to manage data communication with 1D domain
  type, public, extends(meshfieldcommbase) :: meshfieldcomm1d
    class(meshbase1d), pointer :: mesh1d  !< Pointer to an object representing 1D computational mesh
 
    integer :: halosize_1d  !< Halo size in 1D direction
  contains
    procedure, public :: init => meshfieldcomm1d_init
    procedure, public :: put => meshfieldcomm1d_put
    procedure, public :: get => meshfieldcomm1d_get
    procedure, public :: exchange => meshfieldcomm1d_exchange  
    procedure, public :: final => meshfieldcomm1d_final
  end type meshfieldcomm1d
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  
  !-----------------------------------------------------------------------------
  !
  !++ Private procedure
  !
  private :: push_localsendbuf
 
  !-----------------------------------------------------------------------------
  !
  !++ Private parameters & variables
  !
  integer, parameter :: comm_face_num = 2  !< Number of faces with data communication
 
contains
!> Initialize an object to manage data communication with 1D domain
  subroutine meshfieldcomm1d_init( this, &
    sfield_num, hvfield_num, mesh1d,     &
    haloSize_1D )
 
    use scale_meshutil_1d, only: meshutil1d_genpatchboundarymap_wide
    implicit none
    
    class(meshfieldcomm1d), intent(inout) :: this
    integer, intent(in) :: sfield_num                    !< Number of scalar fields
    integer, intent(in) :: hvfield_num                   !< Number of vector fields
    class(meshbase1d), intent(in), target :: mesh1d      !< Object to manage a 1D computational mesh
    integer, intent(in), optional :: halosize_1d         !< Halo size in 1D direction (default: 1)
 
    type(localmesh1d), pointer :: lcmesh
    type(elementbase1d), pointer :: elem
    integer :: n
    integer :: nnode_lcmeshface(comm_face_num,mesh1d%local_mesh_num)
    !-----------------------------------------------------------------------------
    
    this%mesh1d => mesh1d 
    lcmesh => mesh1d%lcmesh_list(1)
    elem => lcmesh%refElem1D
 
    !-
    if ( present(halosize_1d) ) then
      this%haloSize_1D = halosize_1d
    else
      this%haloSize_1D = 1
    end if
    
    !-
    allocate( this%VMapB_size(this%mesh1d%LOCAL_MESH_NUM) )
 
    this%bufsize_per_field =  mesh1d%refElem1D%Nfp * 2 * this%haloSize_1D
 
    do n=1, this%mesh1d%LOCAL_MESH_NUM
      nnode_lcmeshface(:,n) = (/ 1, 1 /) * this%haloSize_1D
    end do
    
    call meshfieldcommbase_init( this, sfield_num, hvfield_num, 0, this%bufsize_per_field, 2, nnode_lcmeshface, mesh1d)  
  
    if ( this%haloSize_1D > 1 ) then
      this%use_vmap_wide_flag = .true.
      allocate( this%VMapB2(this%bufsize_per_field) )
 
      lcmesh => this%mesh1d%lcmesh_list(1)      
      call meshutil1d_genpatchboundarymap_wide( this%VMapB2, &
        lcmesh%VMapB, this%haloSize_1D,                      &
        lcmesh%Ne,                                           &
        elem%Np )
    else
      this%use_vmap_wide_flag = .false.
    end if
 
    do n=1, this%mesh1d%LOCAL_MESH_NUM
      lcmesh => this%mesh1d%lcmesh_list(n)
      if ( this%use_vmap_wide_flag ) then
        this%VMapB_size(n) = size(this%VMapB2)        
      else
        this%VMapB_size(n) = size(lcmesh%VMapB)
      end if
    end do
    return
  end subroutine meshfieldcomm1d_init
 
!> Finalize an object to manage data communication with 1D domain  
  subroutine meshfieldcomm1d_final( this )
    implicit none
    class(meshfieldcomm1d), intent(inout) :: this
    !-----------------------------------------------------------------------------
 
    call meshfieldcommbase_final( this )
    return
  end subroutine meshfieldcomm1d_final
 
!> Put field data into temporary buffers
  subroutine meshfieldcomm1d_put(this, field_list, varid_s)
    implicit none
    class(meshfieldcomm1d), intent(inout) :: this
    type(meshfieldcontainer), intent(in) :: field_list(:)
    integer, intent(in) :: varid_s
  
    integer :: i
    integer :: n
    type(localmesh1d), pointer :: lcmesh
    !-----------------------------------------------------------------------------
    
    if ( this%use_vmap_wide_flag ) then
       call meshfieldcommbase_extract_bounddata_3( field_list, 1, varid_s, this%mesh1d%lcmesh_list, this%VMapB2, this%VMapB_size(1), this%send_buf )
    else
      call meshfieldcommbase_extract_bounddata_2( &
        field_list, 1, varid_s, this%mesh1d%lcmesh_list, size(this%mesh1d%lcmesh_list(1)%VMapB), & !(in)
        this%send_buf ) ! (out)
    end if
 
    return
  end subroutine meshfieldcomm1d_put
 
!> Extract field data from temporary buffers
  subroutine meshfieldcomm1d_get(this, field_list, varid_s)
    use scale_meshfieldcomm_base, only: &
      meshfieldcommbase_wait_core
    implicit none
    
    class(meshfieldcomm1d), intent(inout) :: this
    type(meshfieldcontainer), intent(inout) :: field_list(:)
    integer, intent(in) :: varid_s
 
    integer :: i
    integer :: n
    type(localmesh1d), pointer :: lcmesh
    !-----------------------------------------------------------------------------
    
    if ( this%call_wait_flag_sub_get ) then
      call meshfieldcommbase_wait_core( this, this%commdata_list )
    else
      do i=1, size(field_list) 
      do n=1, this%mesh1D%LOCAL_MESH_NUM
        lcmesh => this%mesh1D%lcmesh_list(n)
        if ( this%use_vmap_wide_flag ) then
          call meshfieldcommbase_set_bounddata_3( this%recv_buf(:,varid_s+i-1,n), lcmesh%refElem, lcmesh, & ! (in)
            this%VMapB2, this%VMapB_size(1),                                                              & ! (in)
            field_list(i)%field1d%local(n)%val )                                                            ! (inout)
        else        
          call meshfieldcommbase_set_bounddata( this%recv_buf(:,varid_s+i-1,n), lcmesh%refElem, lcmesh, & !(in)
            field_list(i)%field1d%local(n)%val )                                                         !(out)
        end if
      end do
      end do
      !$acc wait(1)
    end if
 
    return
  end subroutine meshfieldcomm1d_get
 
!> Exchange field data between neighboring MPI processes
!!
!! @param do_wait Flag whether MPI_waitall is called and move tmp data of LocalMeshCommData object to a recv buffer
!OCL SERIAL
  subroutine meshfieldcomm1d_exchange( this, do_wait )
    use scale_meshfieldcomm_base, only: &
      meshfieldcommbase_exchange_core,  &
      meshfieldcommbase_wait_core,      &
      localmeshcommdata
 
    implicit none
  
    class(meshfieldcomm1d), intent(inout), target :: this
    logical, intent(in), optional :: do_wait
  
    integer :: n, f
    type(localmesh1d), pointer :: mesh
    type(localmeshcommdata), pointer :: commdata
    !-----------------------------------------------------------------------------
 
    do n=1, this%mesh%LOCAL_MESH_NUM
    do f=1, this%nfaces_comm      
      commdata => this%commdata_list(f,n)
      call push_localsendbuf( commdata%send_buf,                       & ! (inout)
        this%send_buf(:,:,n), commdata%s_faceID, f,                    & ! (in)
        commdata%Nnode_LCMeshFace, this%bufsize_per_field,             & ! (in)
        this%field_num_tot, this%mesh1D%lcmesh_list(n), this%haloSize_1D ) ! (in)
    end do
    end do
    !$acc wait(1)
    !-----------------------
    call meshfieldcommbase_exchange_core( this, this%commdata_list, do_wait )
 
    return
  end subroutine meshfieldcomm1d_exchange
 
!----------------------------
 
  subroutine push_localsendbuf( lc_send_buf, &
    send_buf, s_faceID, is, Nnode_LCMeshFace, bufsize_per_field, var_num, &
    lcmesh, haloSize_1D )
    use scale_prc, only: prc_abort
    implicit none
 
    integer, intent(in) :: var_num
    integer, intent(in) :: nnode_lcmeshface
    integer, intent(in) :: bufsize_per_field
    real(rp), intent(inout) :: lc_send_buf(nnode_lcmeshface,var_num)
    real(rp), intent(in) :: send_buf(bufsize_per_field,var_num)
    integer, intent(in) :: s_faceid, is
    type(localmesh1d), intent(in) :: lcmesh
    integer, intent(in) :: halosize_1d
 
    integer :: i, v
    integer :: ne_h1d
    integer :: nfp
    !-----------------------------------------------------------------------------
 
    if ( s_faceid > 0 ) then
      !$omp parallel do
      !$acc parallel loop collapse(2) present(lc_send_buf, send_buf) async(1)
      do v=1, var_num
      do i=1, nnode_lcmeshface
        lc_send_buf(i,v) = send_buf((is-1)*halosize_1d+i,v)
      end do
      end do
    else if ( s_faceid < 0 ) then
      log_info("MeshFieldComm1D",'(a,i0)') "Encountered s_faceID <= 0 in push_localsendbuf. Check! s_faceID=", s_faceid
      call prc_abort
    end if
    return
  end subroutine push_localsendbuf
 
end module scale_meshfieldcomm_1d