mod_ocean_vars.F90

Go to the documentation of this file.

!-------------------------------------------------------------------------------
!> module Ocean / Variables
!!
!! @par Description
!!          Module to manage variables with ocean component
!!
!! @author Yuta Kawai, Team SCALE
!!
!<
!-------------------------------------------------------------------------------
#include "scaleFElib.h"
module mod_ocean_vars
  !-----------------------------------------------------------------------------
  !
  !++ Used modules
  !
  use scale_precision
  use scale_io
  use scale_prc
  use scale_debug
 
  use scale_element_base, only: &
    elementbase, elementbase2d, elementbase3d
  use scale_mesh_base, only: meshbase
  use scale_mesh_base2d, only: &
    meshbase2d
  use scale_mesh_base3d, only: &
    meshbase3d,                              &
    dimtype_xy  => meshbase3d_dimtypeid_xy,  &
    dimtype_xyz  => meshbase3d_dimtypeid_xyz
 
  use scale_localmesh_base, only: localmeshbase
  use scale_localmesh_2d, only: localmesh2d
  use scale_localmesh_3d, only: localmesh3d
  use scale_localmeshfield_base, only: &
    localmeshfieldbase, localmeshfieldbaselist
  use scale_meshfield_base, only: &
    meshfieldbase, meshfield2d, meshfield3d, meshfield3dlist
  
  use scale_file_restart_meshfield, only: &
    file_restart_meshfield_component
  
  use scale_meshfieldcomm_base, only: meshfieldcontainer
 
  use scale_model_var_manager, only: &
    modelvarmanager, variableinfo
 
  use mod_ocean_mesh, only: oceanmesh
  !-----------------------------------------------------------------------------
  implicit none
  private
 
  !-----------------------------------------------------------------------------
  !
  !++ Public type & procedures
  !
 
  !> Derived type to manage variables with ocean component
  type, public :: oceanvars
    class(oceanmesh), pointer :: mesh                !< Pointer to an object to manage a primary mesh for ocean component
 
    !- prognostic variables
    type(meshfield3d), allocatable :: prog_vars(:) !< Array of 3D prognostic variables
    type(modelvarmanager) :: progvars_manager      !< An object to manage prognostic variables
 
    !- tracer variables (Dummy for future use)
    type(meshfield3d), allocatable :: qtrc_vars(:) !< Array of 3D tracer variables
    type(modelvarmanager) :: qtrcvars_manager      !< An object to manage tracer variables
 
    !- auxiliary variables (3D) (Dummy for future use)
    type(meshfield3d), allocatable :: aux_vars(:)  !< Array of 3D auxiliary variables
    type(modelvarmanager) :: auxvars_manager       !< Object to manage 3D auxiliary variables
 
    !- auxiliary variables (2D)
    type(meshfield2d), allocatable :: aux_vars2d(:) !< Array of 2D auxiliary variables
    type(modelvarmanager) :: auxvars2d_manager      !< An object to manage 2D auxiliary variables
 
    !- atmospheric variables (2D)
    type(meshfield2d), allocatable :: atm_vars2d(:) !< Array of 2D atmospheric variables
 
    !- ocean surface fluxes sent to CPL buffer
    type(meshfield2d), allocatable :: ocn_sflx(:)  !< Array of 2D ocean surface fluxes sent to CPL buffer
 
    !- Tendency with physics
    type(meshfield3d), allocatable :: phy_tend(:)  !< Array of tendency variables with physics
    type(modelvarmanager) :: phytends_manager      !< Object to manage tendency variables with physics
    integer :: phytends_commid
    integer :: phytend_num_tot                     !< Total number of tendency variables with physics
 
    !- history file
    integer :: hist_comp_id = -1 !< Component ID for history file
 
    !- restart file
    type(file_restart_meshfield_component) :: restart_file !< Object to manage restart file for ocean component
  contains
    procedure :: init => oceanvars_init
    procedure :: final => oceanvars_final
    procedure :: history => oceanvars_history
    procedure :: read_restart_file => oceanvars_read_restart_file
    procedure :: write_restart_file_prep => oceanvars_write_restart_file_prep
    procedure :: write_restart_file => oceanvars_write_restart_file
    procedure :: write_restart_file_post => oceanvars_write_restart_file_post
  end type oceanvars
 
  public :: oceanvars_getlocalmeshprgvars
 
  !-----------------------------------------------------------------------------
  !
  !++ Public parameters & variables
  !
  integer, public, parameter :: prgvar_therm_id   = 1 ! Variable associated with energy equation (DRHOT or ETOT)
  integer, public, parameter :: prgvar_drhot_id   = 1
  integer, public, parameter :: prgvar_salt_id    = 2
  integer, public, parameter :: prgvar_w_id       = 3
  integer, public, parameter :: prgvar_u_id       = 4
  integer, public, parameter :: prgvar_v_id       = 5
  integer, public, parameter :: prgvar_scalar_num = 3
  integer, public, parameter :: prgvar_hvec_num   = 1
  integer, public, parameter :: prgvar_num        = 5
 
  integer, public, parameter :: phytend_u_id        = 1
  integer, public, parameter :: phytend_v_id        = 2
  integer, public, parameter :: phytend_w_id        = 3
  integer, public, parameter :: phytend_therm_id    = 4
  integer, public, parameter :: phytend_salt_id     = 5
  integer, public, parameter :: phytend_rhoh_id     = 6
  integer, public, parameter :: phytend_num         = 6
 
  integer, public, parameter :: auxvar2d_sfc_temp_id        = 1
  integer, public, parameter :: auxvar2d_sfc_alb_ir_dir_id  = 2
  integer, public, parameter :: auxvar2d_sfc_alb_ir_dif_id  = 3
  integer, public, parameter :: auxvar2d_sfc_alb_nir_dir_id = 4
  integer, public, parameter :: auxvar2d_sfc_alb_nir_dif_id = 5
  integer, public, parameter :: auxvar2d_sfc_alb_vis_dir_id = 6
  integer, public, parameter :: auxvar2d_sfc_alb_vis_dif_id = 7
  integer, public, parameter :: auxvar2d_num                = 7
 
  ! Lower atmosphere variables received from CPL buffer
  integer, public, parameter :: atmvar2d_sfc_dens_id   = 1
  integer, public, parameter :: atmvar2d_sfc_pres_id   = 2
  integer, public, parameter :: atmvar2d_atm_temp_id       = 3
  integer, public, parameter :: atmvar2d_atm_dens_id       = 4
  integer, public, parameter :: atmvar2d_atm_pres_id       = 5
  integer, public, parameter :: atmvar2d_atm_w_id          = 6
  integer, public, parameter :: atmvar2d_atm_u_id          = 7
  integer, public, parameter :: atmvar2d_atm_v_id          = 8
  integer, public, parameter :: atmvar2d_atm_qv_id         = 9
  integer, public, parameter :: atmvar2d_sflx_rd_sw_dir_id = 10
  integer, public, parameter :: atmvar2d_sflx_rd_lw_dif_id = 11
  integer, public, parameter :: atmvar2d_lowest_layer_dz_id = 12
  integer, public, parameter :: atmvar2d_num               = 12
 
  ! Ocean surface fluxes sent to CPL buffer
  integer, public, parameter :: ocn_sflx_mw_id = 1 !< w-momentum flux at the ocean surface    [kg/m/s2]
  integer, public, parameter :: ocn_sflx_mu_id = 2 !< u-momentum flux at the ocean surface    [kg/m/s2]
  integer, public, parameter :: ocn_sflx_mv_id = 3 !< v-momentum flux at the ocean surface    [kg/m/s2]
  integer, public, parameter :: ocn_sflx_sh_id = 4 !< sensible heat flux at the ocean surface  [W/m2]
  integer, public, parameter :: ocn_sflx_lh_id = 5 !< latent heat flux at the ocean surface    [W/m2]
  integer, public, parameter :: ocn_sflx_qv_id = 6 !< water vapor flux at the ocean surface    [kg/m2/s]
  integer, public, parameter :: ocn_sflx_num   = 6 !< Number of ocean surface fluxes
 
  ! Diagnostic variables
 
  !-----------------------------------------------------------------------------
  !
  !++ Private procedures & variables
  !
 
  type(variableinfo) :: prgvar_varinfo(prgvar_num)
  DATA prgvar_varinfo / &
    variableinfo( prgvar_therm_id , 'OCEAN_THERM', 'ocean temperature',     &
                  'K', 1, 'XYZ_O', 'sea_water_temperature'               ), &
    variableinfo( prgvar_salt_id , 'OCEAN_SALT', 'ocean salinity',          &
                  'PSU', 1, 'XYZ_O', 'sea_water_salinity'                ), &
    variableinfo( prgvar_w_id , 'OCEAN_WVEL', 'ocean w-velocity',           &
                  'm/s', 1, 'XYZ_O', 'vertical_sea_water_velocity'       ), &
    variableinfo( prgvar_u_id , 'OCEAN_UVEL', 'ocean u-velocity',           &
                  'm/s', 1, 'XYZ_O', 'eastward_sea_water_velocity'       ), &
    variableinfo( prgvar_v_id , 'OCEAN_VVEL', 'ocean v-velocity',           &
                  'm/s', 1, 'XYZ_O', 'northward_sea_water_velocity'      )  /
 
  type(variableinfo) :: auxvar2d_varinfo(auxvar2d_num)
  DATA auxvar2d_varinfo / &
    variableinfo( auxvar2d_sfc_temp_id , 'OCEAN_SFC_TEMP', 'ocean surface temperature', &
                  'K', 1, 'XY_O', 'sea_surface_temperature'                       ), &
    variableinfo( auxvar2d_sfc_alb_ir_dir_id , 'OCEAN_SFC_ALB_IR_DIR', 'ocean surface albedo IR (direct)',     &
                  '1', 1, 'XY_O', 'sea_surface_albedo_ir_dir'                     ), &
    variableinfo( auxvar2d_sfc_alb_ir_dif_id , 'OCEAN_SFC_ALB_IR_DIF', 'ocean surface albedo IR (diffuse)',    &
                  '1', 1, 'XY_O', 'sea_surface_albedo_ir_dif'                     ), &
    variableinfo( auxvar2d_sfc_alb_nir_dir_id , 'OCEAN_SFC_ALB_NIR_DIR', 'ocean surface albedo NIR (direct)',  &
                  '1', 1, 'XY_O', 'sea_surface_albedo_nir_dir'                     ), &
    variableinfo( auxvar2d_sfc_alb_nir_dif_id , 'OCEAN_SFC_ALB_NIR_DIF', 'ocean surface albedo NIR (diffuse)', &
                  '1', 1, 'XY_O', 'sea_surface_albedo_nir_dif'                     ), &
    variableinfo( auxvar2d_sfc_alb_vis_dir_id , 'OCEAN_SFC_ALB_VIS_DIR', 'ocean surface albedo VIS (direct)',  &
                  '1', 1, 'XY_O', 'sea_surface_albedo_vis_dir'                     ), &
    variableinfo( auxvar2d_sfc_alb_vis_dif_id , 'OCEAN_SFC_ALB_VIS_DIF', 'ocean surface albedo VIS (diffuse)', &
                  '1', 1, 'XY_O', 'sea_surface_albedo_vis_dif'                     )  /
 
    type(variableinfo) :: phytend_varinfo(phytend_num)
    DATA phytend_varinfo / &
      variableinfo( phytend_u_id, 'U_tp', 'U_tp',                                          &
                    'm2/s2'    ,  3, 'XYZ_O',  'tendency of physical process for U' ),     &
      variableinfo( phytend_v_id, 'V_tp', 'V_tp',                                          &
                    'm2/s2'    ,  3, 'XYZ_O',  'tendency of physical process for V' ),     &
      variableinfo( phytend_w_id, 'W_tp', 'W_tp',                                          &
                    'm2/s2'    ,  3, 'XYZ_O',  'tendency of physical process for W' ),     &
      variableinfo( phytend_therm_id, 'THERM_tp', 'THERM_tp',                              &
                    'K/s'      ,  3, 'XYZ_O',  'tendency of physical process for THERM' ), &
      variableinfo( phytend_salt_id, 'SALT_tp', 'SALT_tp',                                 &
                    'PSU/s'    ,  3, 'XYZ_O',  'tendency of physical process for SALT' ),  &
      variableinfo( phytend_rhoh_id,  'RHOH_p',  'RHOH_p',                                 &
                    'kg/m3.J/s',  3, 'XYZ_O',  'tendency of physical process for RHOH' )   /
 
 
contains
 
  !> Setup an object to manage variables with ocean component
  !!
  !! @param model_mesh Object to manage computational mesh of ocean model 
  !!
!OCL SERIAL
  subroutine oceanvars_init( this, ocean_mesh )
    use scale_file_monitor_meshfield, only:    &
      monitor_reg => file_monitor_meshfield_reg
    use scale_mesh_base3d, only: meshbase3d
    use scale_meshfield_base, only: meshfield3d
    implicit none
 
    class(oceanvars), target, intent(inout) :: this
    class(oceanmesh), target, intent(inout) :: ocean_mesh
 
    integer :: iv
    logical :: reg_file_hist
 
    character(len=H_LONG) :: in_basename           = ''        !< Basename of the input  file
    logical :: in_postfix_timelabel                = .false.   !< Add timelabel to the basename of input  file?
    character(len=H_LONG) :: out_basename          = ''        !< Basename of the output file
    logical :: out_postfix_timelabel               = .true.    !< Add timelabel to the basename of output file?
    character(len=H_MID) :: out_title              = ''        !< Title    of the output file
    character(len=H_SHORT) :: out_dtype            = 'DEFAULT' !< REAL4 or REAL8  
 
    namelist / param_ocean_vars_restart / &
      in_basename,           &
      in_postfix_timelabel,  &
      out_basename,          &
      out_postfix_timelabel, &
      out_title,             &
      out_dtype  
 
    integer :: ierr
    logical :: is_specified
 
    class(meshbase3d), pointer :: mesh3d
    class(meshbase2d), pointer :: mesh2d
 
    !---------------------------------------------------------
 
    this%mesh => ocean_mesh
    mesh3d => ocean_mesh%ptr_mesh
    call mesh3d%GetMesh2D( mesh2d )
 
    !-
    call this%PROGVARS_manager%Init()
    call this%AUXVARS2D_manager%Init()
    call this%PHYTENDS_manager%Init()
 
    this%PHYTEND_NUM_TOT = phytend_num
 
    allocate( this%PROG_VARS(prgvar_num) )
    allocate( this%AUX_VARS2D(auxvar2d_num) )
    allocate( this%OCN_SFLX(ocn_sflx_num) )
    allocate( this%PHY_TEND(phytend_num) )
    allocate( this%ATM_VARS2D(atmvar2d_num) )
    !$acc enter data create( this%PROG_VARS, this%AUX_VARS2D, this%PHY_TEND, this%ATM_VARS2D, this%OCN_SFLX )
 
    !- Initialize prognostic variables
 
    reg_file_hist = .true.
    do iv = 1, prgvar_num
      call this%PROGVARS_manager%Regist(  &
        prgvar_varinfo(iv), mesh3d,                           & ! (in) 
        this%PROG_VARS(iv),                                   & ! (inout)
        reg_file_hist,  monitor_flag=.true., fill_zero=.true. ) ! (out)
      !$acc update device( this%PROG_VARS(iv) )
    end do
 
    !- Initialize auxiliary variables (2D)
 
    reg_file_hist = .true.
    do iv = 1, auxvar2d_num
      call this%AUXVARS2D_manager%Regist( &
        auxvar2d_varinfo(iv), mesh2d,         & ! (in) 
        this%AUX_VARS2D(iv),                  & ! (inout)
        reg_file_hist, fill_zero=.true.       ) ! (in)
      !$acc update device( this%AUX_VARS2D(iv) )
    end do
 
    !- Initialize ocean surface fluxes sent to CPL buffer
    do iv = 1, ocn_sflx_num
      call this%OCN_SFLX(iv)%Init( "", "", mesh2d )
      !$acc update device( this%OCN_SFLX(iv) )
    end do
 
    !- Initialize tendency variables with physics
 
    reg_file_hist = .true.
    do iv=1, phytend_num
      call this%PHYTENDS_manager%Regist( &
        phytend_varinfo(iv), mesh3d,         & ! (in) 
        this%PHY_TEND(iv),                   & ! (inout)
        reg_file_hist, fill_zero=.true.      ) ! (in)
      !$acc update device( this%PHY_TEND(iv) )
    end do
 
    !- Initialize atmospheric variables (2D)
 
    do iv =1, atmvar2d_num
      call this%ATM_VARS2D(iv)%Init( "", "", mesh2d )
      !$acc update device( this%ATM_VARS2D(iv) )
    end do
 
    !-- Setup information for input/output restart files. 
 
    is_specified = .true.
    !- read namelist
    rewind(io_fid_conf)
    read(io_fid_conf,nml=param_ocean_vars_restart,iostat=ierr)
    if( ierr < 0 ) then !--- missing
       log_info("OceanVars_Init",*) 'Not found namelist PARAM_OCEAN_VARS_RESTART. Default used.'
       is_specified = .false.
    elseif( ierr > 0 ) then !--- fatal error
       log_error("OceanVars_Init",*) 'Not appropriate names in namelist PARAM_OCEAN_VARS_RESTART. Check!'
       call prc_abort
    endif
    log_nml(param_ocean_vars_restart)
 
    if (is_specified) then
      call ocean_mesh%Setup_restartfile( this%restart_file,         &
        in_basename, in_postfix_timelabel,                          &
        out_basename, out_postfix_timelabel, out_dtype, out_title,  &
        prgvar_num + auxvar2d_num, "_O" )
    else
      call ocean_mesh%Setup_restartfile( this%restart_file, &
        prgvar_num + auxvar2d_num, "_O" )
    end if
 
    return
  end subroutine oceanvars_init
 
  !> Finalize an object to manage variables with ocean component
  !!
!OCL SERIAL
  subroutine oceanvars_final( this )
    implicit none
    class(oceanvars), intent(inout) :: this
 
    integer :: iv
    !--------------------------------------------------
 
    log_info('OceanVars_Final',*)
 
    !$acc exit data delete( this%PROG_VARS, this%AUX_VARS2D, this%PHY_TEND, this%ATM_VARS2D )
 
    call this%PROGVARS_manager%Final()
    deallocate( this%PROG_VARS )
 
    call this%AUXVARS2D_manager%Final()
    deallocate( this%AUX_VARS2D )
 
    do iv=1, ocn_sflx_num
      call this%OCN_SFLX(iv)%Final()
    end do
    deallocate( this%OCN_SFLX )
 
    call this%PHYTENDS_manager%Final()
    deallocate( this%PHY_TEND )
 
    do iv=1, atmvar2d_num
      call this%ATM_VARS2D(iv)%Final()
    end do
    deallocate( this%ATM_VARS2D )
 
    call this%restart_file%Final()
    return
  end subroutine oceanvars_final
 
  !> Put data with oceanic variables to history file
  !!
!OCL SERIAL
  subroutine oceanvars_history( this )
    use scale_file_history_meshfield, only: file_history_meshfield_put
    implicit none
    class(oceanvars), intent(inout), target :: this
  
    integer :: v
    integer :: hst_id
 
    type(meshfield3d) :: tmp_field3d
    class(meshbase3d), pointer :: mesh3d
 
    type(meshfield2d) :: tmp_field2d
    class(meshbase2d), pointer :: mesh2d
    !-------------------------------------------------------------------------
 
    mesh3d => this%PROG_VARS(1)%mesh
    call mesh3d%GetMesh2D(mesh2d)
 
    do v = 1, prgvar_num
      hst_id = this%PROG_VARS(v)%hist_id
      if ( hst_id > 0 ) call file_history_meshfield_put( hst_id, this%PROG_VARS(v), this%hist_comp_id )
    end do
    do v = 1, auxvar2d_num
      hst_id = this%AUX_VARS2D(v)%hist_id
      if ( hst_id > 0 ) call file_history_meshfield_put( hst_id, this%AUX_VARS2D(v), this%hist_comp_id )
    end do
    
    return
  end subroutine oceanvars_history
 
!> Read data with oceanic variables from restart file
!!
!OCL SERIAL
  subroutine oceanvars_read_restart_file( this, ocean_mesh )
    use scale_meshfieldcomm_cubedom3d, only: meshfieldcommcubedom3d
    use scale_meshfieldcomm_base, only: meshfieldcontainer
    implicit none
    
    class(oceanvars), intent(inout), target :: this
    class(oceanmesh), intent(in) :: ocean_mesh
 
    integer :: iv
    class(meshbase3d), pointer :: mesh3d
    class(localmesh3d), pointer :: lcmesh3d
    !---------------------------------------
 
    log_newline
    log_info("OceanVar_Read_restart_file",*) 'Open restart file (OCEAN) '
        
    !- Open restart file
    call this%restart_file%Open()
 
    !- Read restart file
    
    do iv=1, prgvar_num
      call this%restart_file%Read_var( dimtype_xyz, this%PROG_VARS(iv)%varname, &
        this%PROG_VARS(iv)                                                      )
    end do
    do iv=1, auxvar2d_num
      call this%restart_file%Read_var( dimtype_xy, this%AUX_VARS2D(iv)%varname, &
        this%AUX_VARS2D(iv)                                                      )
    end do
 
    !- Close restart file
    log_info("OceanVar_Read_restart_file",*) 'Close restart file (OCEAN) '
    call this%restart_file%Close()
 
    !-- Prepare diagnostic variables
 
    !-- Check read data
    ! call this%Check( force = .true. )
 
    !-- Calculate diagnostic variables
    ! call this%Calc_diagnostics()   
 
    !-- Communicate halo data of diagnostic variables
    ! call this%AUXVARS_manager%MeshFieldComm_Exchange()
 
    return
  end subroutine oceanvars_read_restart_file
 
  !> Write data with oceanic variables to restart file
  !!
!OCL SERIAL
  subroutine oceanvars_write_restart_file_prep( this )
    ! use scale_ocn_dyn_dgm_nonhydro3d_common, only: &
    !   ocn_dyn_dgm_nonhydro3d_common_get_varinfo
    
    implicit none
    class(oceanvars), intent(inout) :: this
 
    ! type(VariableInfo) :: prgvar_info(PRGVAR_NUM)
    ! type(VariableInfo) :: auxvar2D_info(AUXVAR2D_NUM)
 
    integer :: iv, rf_vid 
    !---------------------------------------
    
    log_newline
    log_info("OceanVars_Write_restart_file",*) 'Create restart file (OCEAN) '
 
    !- Check data which will be written to restart file
    ! call this%Check( force = .true. )
 
    !- Create restart file
    call this%restart_file%Create()
    call prc_mpibarrier()
 
    !- Define variables
 
    ! call ocn_dyn_dgm_nonhydro3d_common_get_varinfo( prgvar_info, auxvar2D_info )
 
    do iv=1, prgvar_num
      rf_vid = iv
      call this%restart_file%Def_var( this%PROG_VARS(iv),  &
        prgvar_varinfo(iv)%DESC, rf_vid, dimtype_xyz       )
    end do
    do iv=1, auxvar2d_num
      rf_vid = prgvar_num + iv
      call this%restart_file%Def_var( this%AUX_VARS2D(iv),   &
        auxvar2d_varinfo(iv)%DESC, rf_vid, dimtype_xy        )
    end do
 
    return
  end subroutine oceanvars_write_restart_file_prep
 
  !> Write data with oceanic variables to restart file
  !!
!OCL SERIAL
  subroutine oceanvars_write_restart_file( this )
    ! use scale_ocn_dyn_dgm_nonhydro3d_common, only: &
    !   ocn_dyn_dgm_nonhydro3d_common_get_varinfo
    
    implicit none
    class(oceanvars), intent(inout) :: this
 
    ! type(VariableInfo) :: prgvar_info(PRGVAR_NUM)
    ! type(VariableInfo) :: auxvar2D_info(AUXVAR2D_NUM)
 
    integer :: iv, rf_vid 
    !---------------------------------------
 
    call this%restart_file%End_def()
 
    !- Write restart file
    do iv=1, prgvar_num
      rf_vid = iv
      call this%restart_file%Write_var( rf_vid, this%PROG_VARS(iv) )
    end do
    do iv=1, auxvar2d_num
      rf_vid = prgvar_num + iv
      call this%restart_file%Write_var( rf_vid, this%AUX_VARS2D(iv) )
    end do
    return
  end subroutine oceanvars_write_restart_file
 
  !> Close restart file for oceanic variables
!OCL SERIAL
  subroutine oceanvars_write_restart_file_post( this )
    implicit none
    class(oceanvars), intent(inout) :: this
    !---------------------------------------
    log_info("OceanVars_Write_restart_file",*) 'Close restart file (OCEAN) '
    call this%restart_file%Close()
    return
  end subroutine oceanvars_write_restart_file_post
 
!OCL SERIAL
!OCL SERIAL
  subroutine oceanvars_getlocalmeshprgvars( domID, mesh, prgvars_list, auxvars2D_list, &
    U, V, W, THERM, SALT,                                                            &
    SFC_TEMP, &
    SFC_ALB_IR_dir, SFC_ALB_IR_dif, SFC_ALB_NIR_dir, SFC_ALB_NIR_dif,                &
    SFC_ALB_VIS_dir, SFC_ALB_VIS_dif,                                                &
    lcmesh3D                                                                         )
    implicit none
    integer, intent(in) :: domid
    class(meshbase), intent(in) :: mesh
    class(modelvarmanager), intent(inout) :: prgvars_list
    class(modelvarmanager), intent(inout) :: auxvars2d_list
    class(localmeshfieldbase), pointer, intent(out) :: u, v, w, therm, salt
    class(localmeshfieldbase), pointer, intent(out) :: sfc_temp
    class(localmeshfieldbase), pointer, intent(out), optional :: sfc_alb_ir_dir, sfc_alb_ir_dif
    class(localmeshfieldbase), pointer, intent(out), optional :: sfc_alb_nir_dir, sfc_alb_nir_dif
    class(localmeshfieldbase), pointer, intent(out), optional :: sfc_alb_vis_dir, sfc_alb_vis_dif
    class(localmesh3d), pointer, intent(out), optional :: lcmesh3d
 
    class(meshfieldbase), pointer :: field
    class(localmeshbase), pointer :: lcmesh
    !-------------------------------------------------------
 
    !--
    call prgvars_list%Get(prgvar_u_id, field)
    call field%GetLocalMeshField(domid, u)
 
    call prgvars_list%Get(prgvar_v_id, field)
    call field%GetLocalMeshField(domid, v)
 
    call prgvars_list%Get(prgvar_w_id, field)
    call field%GetLocalMeshField(domid, w)
 
    call prgvars_list%Get(prgvar_therm_id, field)
    call field%GetLocalMeshField(domid, therm)
  
    call prgvars_list%Get(prgvar_salt_id, field)
    call field%GetLocalMeshField(domid, salt)
 
    call auxvars2d_list%Get(auxvar2d_sfc_temp_id, field)
    call field%GetLocalMeshField(domid, sfc_temp)
 
    if ( present(sfc_alb_ir_dir) ) then
      call auxvars2d_list%Get(auxvar2d_sfc_alb_ir_dir_id, field)
      call field%GetLocalMeshField(domid, sfc_alb_ir_dir)
    end if
    if ( present(sfc_alb_ir_dif) ) then
      call auxvars2d_list%Get(auxvar2d_sfc_alb_ir_dif_id, field)
      call field%GetLocalMeshField(domid, sfc_alb_ir_dif)
    end if
    if ( present(sfc_alb_nir_dir) ) then
      call auxvars2d_list%Get(auxvar2d_sfc_alb_nir_dir_id, field)
      call field%GetLocalMeshField(domid, sfc_alb_nir_dir)
    end if
    if ( present(sfc_alb_nir_dif) ) then
      call auxvars2d_list%Get(auxvar2d_sfc_alb_nir_dif_id, field)
      call field%GetLocalMeshField(domid, sfc_alb_nir_dif)
    end if
    if ( present(sfc_alb_vis_dir) ) then
      call auxvars2d_list%Get(auxvar2d_sfc_alb_vis_dir_id, field)
      call field%GetLocalMeshField(domid, sfc_alb_vis_dir)
    end if
    if ( present(sfc_alb_vis_dif) ) then
      call auxvars2d_list%Get(auxvar2d_sfc_alb_vis_dif_id, field)
      call field%GetLocalMeshField(domid, sfc_alb_vis_dif)
    end if  
 
    !---
    
    if ( present(lcmesh3d) ) then
      call mesh%GetLocalMesh( domid, lcmesh )
      nullify( lcmesh3d )
 
      select type(lcmesh)
      type is (localmesh3d)
        if (present(lcmesh3d)) lcmesh3d => lcmesh
      end select
    end if
 
    return
  end subroutine oceanvars_getlocalmeshprgvars
end module mod_ocean_vars