!--
!----------------------------------------------------------------------
!     Copyright (c) 2024-2025 SPMODEL Development Group.
!----------------------------------------------------------------------
!表題  w_zonal_interpolate_module
!
!  spml/w_zonal_interpolate_module モジュールは球面上での 
!  2 次元流体運動を球面調和函数を用いたスペクトル法によって
!  東西 1 波数数値計算するためのモジュール w_zonal_module の
!  下部モジュールであり, スペクトル法による補間計算のための 
!  Fortran90 関数を提供する. 
!
!  補間計算の方法については doc/w_module.tex を参照のこと. 
!  このサブルーチンは内部で ISPACK3 の LXPACK のサブルーチンを
!  呼んでいない. 
!
!履歴  2024/02/15  竹広真一 w_zonal_module_interpolate より改造
!      2025/11/27  竹広真一  w_base_initial interface を変更
!
!
!++
module w_zonal_module_interpolate
  !
  !=  w_zonal_interpolate_module
  !
  ! Authors:: Shin-ichi Takehiro, Youhei SASAKI
  ! Version:: $Id: w_zonal_interpolate_module.f90 590 2013-08-19 08:48:21Z uwabami $
  ! Copyright&License:: See COPYRIGHT[link:../COPYRIGHT]
  !
  !== 概要
  !
  !  spml/w_zonal_interpolate_module モジュールは球面上での 
  !  2 次元流体運動を球面調和函数を用いたスペクトル法によって
  !  東西 1 波数数値計算するためのモジュール w_zonal_module の
  !  下部モジュールであり, スペクトル法による補間計算のための 
  !  Fortran90 関数を提供する. 
  !
  !  このサブルーチンは内部で ISPACK3 の LXPACK のサブルーチンを
  !  呼んでいない. 
  !
  use dc_message, only : MessageNotify
  use spml_utils, only : gammaln
  use w_zonal_module_base, only : nm=>nn, l_nm
  implicit none
  private

  public Interpolate_w                        ! 補間関数

  interface Interpolate_w
     !
     ! 緯度 alon, 経度 alat における関数値を
     ! その球面調和変換係数 w_data から補間計算する
     !
     ! 入力する緯度経度座標は, 
     !       １点, 経度1点緯度複数点, 経度複数点緯度1点, 経度緯度複数点
     ! の 4 種類
     !
     module procedure Interpolate_array00_w
  end interface

!!$  interface alpha
!!$     module procedure alpha_array0
!!$  end interface alpha
!!$
!!$  interface Pmm
!!$     module procedure Pmm_array0
!!$  end interface Pmm

contains

  !--------------- 補間計算 -----------------    
  function Interpolate_array00_w(w_data,alon,alat)
    !
    ! 緯度 alat, 経度 alon における関数値を
    ! その球面調和変換係数 w_data から補間計算する
    !
    real(8), intent(IN) :: w_data(nm+1)           ! スペクトルデータ
    real(8), intent(IN) :: alon                   ! 補間する位置(経度)
    real(8), intent(IN) :: alat                   ! 補間する位置(緯度)
    real(8)             :: Interpolate_array00_w  ! 補間した値

    real(8) :: mu
    real(8) :: y0, y1, y2
    integer :: k

    mu = sin(alat)
    Interpolate_array00_w = 0.0D0

    !---- Σa_n^0 L_n^0 の計算
    y2 = 0 ; y1 = 0
    do k=nm,1,-1
       y0 = alpha(k,mu) * y1 + beta(k+1)*y2 + w_data(l_nm(k,0))
       y2 = y1 ; y1 = y0
    enddo
    Interpolate_array00_w = beta(1) * y2 + mu*sqrt(3.0D0) * y1 + w_data(l_nm(0,0)) 

  end function Interpolate_array00_w

  !--------------- 下部ルーチン -----------------
  function alpha(n,x)
    !
    !  漸化式の P_n の係数
    !
    integer, intent(IN) :: n
    real(8), intent(IN) :: x
    real(8)             :: alpha

    alpha = sqrt( (2.0D0*n+3)*(2.0D0*n+1)/((n+1)*(n+1)) ) * x
  end function alpha

  function beta(n)
    !
    !  漸化式の P_{n-1} の係数
    !
    integer, intent(IN) :: n
    real(8)             :: beta

    beta = - sqrt( (2.0D0*n+3)*n*n/((2*n-1)*(n+1)*(n+1)) )
  end function beta

end module w_zonal_module_interpolate