*%表題   GTOOL データの入力
*%
*%履歴   91/04/27 佐藤正樹       C:\FORT\IO\READDATA.FOR
*%       91/05/16 佐藤正樹       C:\FORT\OORT\READDATA.FOR
*%       91/05/21 佐藤正樹       C:\FORT\OORT\RDGTDT.FOR
*%
*%
*-----------------------------------------------------------------------
      SUBROUTINE  RDGTDT
     I           ( JFILE,    HIFL,
     O             HHEAD,    GDATA,
     D             IDIM,     JDIM,     KDIM,     IJKDIM  )
*
      INTEGER  JFILE          ! 入力ユニット番号
      CHARACTER HIFL*(*)      ! 入力ファイル名
      LOGICAL   LIEX          ! 入力ファイルの存在

      INTEGER NCC
      INTEGER NDC
      PARAMETER  ( NCC=16, NDC=64 )
      CHARACTER  HHEAD ( NDC )*(NCC)  ! ヘッダー
      CHARACTER  HDFMT *(NCC)
      CHARACTER  HITEM *(NCC)

      INTEGER  IASTR1
      INTEGER  IAEND1
      INTEGER  IASTR2
      INTEGER  IAEND2
      INTEGER  IASTR3
      INTEGER  IAEND3

      INTEGER  IDIM
      INTEGER  JDIM
      INTEGER  KDIM
      INTEGER  IJKDIM

      REAL  GDATA(*)          ! 入力データ

      INTEGER N
      INTEGER I

*-----------------------------------------------------------------------
*     < 入力データファイルのオープン >

      INQUIRE(FILE=HIFL, EXIST=LIEX)
      IF( .NOT. LIEX ) THEN
        WRITE(6,*) '入力ファイルが存在しません'
        WRITE(6,*) ' ファイル名: ', HIFL
        STOP
      END IF

      OPEN ( JFILE, FILE=HIFL, STATUS='OLD' )



*     < 入力 >

      READ ( JFILE, '(A16)' ) (HHEAD(N), N=1, NDC)

      CALL  GHPGET( HHEAD, 'ASTR1', IASTR1 )
      CALL  GHPGET( HHEAD, 'AEND1', IAEND1 )
      CALL  GHPGET( HHEAD, 'ASTR2', IASTR2 )
      CALL  GHPGET( HHEAD, 'AEND2', IAEND2 )
      CALL  GHPGET( HHEAD, 'ASTR3', IASTR3 )
      CALL  GHPGET( HHEAD, 'AEND3', IAEND3 )
      CALL  GHCGET( HHEAD, 'DFMT',  HDFMT )

      IDIM = IAEND1 - IASTR1 + 1
      JDIM = IAEND2 - IASTR2 + 1
      KDIM = IAEND3 - IASTR3 + 1
      IJKDIM = IDIM*JDIM*KDIM

      READ ( JFILE, HDFMT )  ( GDATA( I ), I=1, IJKDIM )

      CALL  GHCGET( HHEAD, 'ITEM',  HITEM )
      WRITE(6,*) '入力データ', HITEM



*     < ファイルのクローズ >

      CLOSE(JFILE)



*-----------------------------------------------------------------------

       RETURN
       END
