*"表題 第３次元の部分切出し GTOOL3(GPZRDC)
*
*"履歴 90/08/18 沼口  敦
*
*
*********************************************************************
*"         << 第３次元の部分切出し >>
*********************************************************************
      SUBROUTINE GPZRDC
     I         ( HHEAD , GDATA , IZSEL1, IZSEL2,
     I           HEDIT , HETTL ,
     O           HHEADO, GDATAO                 )
*
      CHARACTER  HHEAD  ( * )*(*)        !" ヘッダー(入力)
      REAL       GDATA  ( * )            !" データ(入力)
      INTEGER    IZSEL1                  !" 切り出す第3次元の格子
      INTEGER    IZSEL2                  !" 切り出す第3次元の格子
      CHARACTER  HEDIT       *(*)        !" 編集略記号
      CHARACTER  HETTL       *(*)        !" 編集タイトル
      CHARACTER  HHEADO ( * )*(*)        !" ヘッダー(出力)
      REAL       GDATAO ( * )            !" データ(出力)
*
#ifdef SYS_IBMS
      INCLUDE    (GZSIZE)                !" NCC, NDC
#else
#include         "gzsize.F"              !" NCC, NDC
#endif
      CHARACTER  HAXIS         *(NCC)
      CHARACTER  HEDITD      *(NCC)      !" 編集略記号
      CHARACTER  HETTLD      *(NCC)      !" 編集タイトル
      LOGICAL    OCYCL                   !" サイクリックか？
*
*"         < 1. 大きさの取得 >
*
      CALL GUSMIS ( HHEAD )
*
      CALL GUQSIZ
     I         ( HHEAD ,
     O           IXSTR , IXEND , IXDIM ,
     O           IYSTR , IYEND , IYDIM ,
     O           IZSTR , IZEND , IZDIM  )
*
      IZDIMC = IZSEL2-IZSEL1+1
      CALL GUSZCK ( HHEADO, IXDIM*IYDIM*IZDIMC )
*
      CALL GHCGET( HHEAD, 'AITM3', HAXIS )
      CALL GUQAXD
     I         ( HAXIS ,
     O           IADIM , OCYCL  )
*
*"         < 2. データ詰め替え >
*
      CALL GHPGET ( HHEAD, 'MISS', VMISS )
*
      DO 2100 IZ = IZSEL1, IZSEL2
         IF ( OCYCL ) THEN
            IZI = MOD( IZ-IZSTR, IADIM ) + 1
         ELSE
            IZI = IZ-IZSTR+1
         ENDIF
*
         IF ( ( 1.LE.IZI ).AND.( IZI.LE.IZDIM ) ) THEN
            CALL VRSET
     I         ( GDATA ( IXDIM*IYDIM*(IZI-1) +1 ),
     O           GDATAO( IXDIM*IYDIM*(IZ-IZSEL1)+1 ),
     I           IXDIM*IYDIM, 1     , 1                )
         ELSE
            CALL RSET
     O         ( GDATAO( IXDIM*IYDIM*(IZ-IZSEL1)+1 ),
     I           IXDIM*IYDIM, 1    , VMISS               )
         ENDIF
*
 2100 CONTINUE
*
*"         < 3. ヘッダー変更 >
*
      CALL GHCOPY ( HHEAD, HHEADO )
      CALL GHPSET ( HHEADO, 'ASTR3', IZSEL1 )
      CALL GHPSET ( HHEADO, 'AEND3', IZSEL2 )
*
      IF ( ( IZSTR .EQ. IZSEL1 ).AND.( IZEND .EQ. IZSEL2 ) ) RETURN
*
      IF      ( HEDIT .EQ. ' ' ) THEN
         CALL GUEAXN
     I               ( HAXIS , 'ZR'   , '-reduce',
     I                 IZSEL1, IZSEL2 ,
     O                 HEDITD, HETTLD          )
         CALL GHEADD ( HHEADO, HEDITD, HETTLD )
      ELSE IF ( HEDIT .NE. 'NUL' ) THEN
         CALL GHEADD ( HHEADO, HEDIT  , HETTL   )
      ENDIF
*
      RETURN
      END
*********************************************************************
*"         << 第３次元の部分切出し >>
*********************************************************************
      SUBROUTINE GMZRDC
     M         ( HHEAD , GDATA ,
     I           IZSEL1, IZSEL2,
     I           HEDIT , HETTL  )
*
      CHARACTER  HHEAD  ( * )*(*)        !" ヘッダー(入力)
      REAL       GDATA  ( * )            !" データ(入力)
      INTEGER    IZSEL1                  !" 切り出す第3次元の格子
      INTEGER    IZSEL2                  !" 切り出す第3次元の格子
      CHARACTER  HEDIT       *(*)        !" 編集略記号
      CHARACTER  HETTL       *(*)        !" 編集タイトル
*
      COMMON     /GMWORK/ GDATAW
      REAL       GDATAW ( 1 )            !" データ(ワーク)
#ifdef SYS_IBMS
      INCLUDE    (GZSIZE)                !" NCC, NDC
#else
#include         "gzsize.F"              !" NCC, NDC
#endif
      CHARACTER  HHEADW ( NDC )*(NCC)    !" ヘッダー(ワーク)
*
      CALL       GMCSIZ ( HHEADW )
      CALL       GPZRDC
     I         ( HHEAD , GDATA , IZSEL1, IZSEL2,
     I           HEDIT , HETTL ,
     O           HHEADW, GDATAW                 )
*
      CALL       GPFSET
     I         ( HHEADW, GDATAW,
     I           ' '   , ' '   ,
     O           HHEAD , GDATA   )
*
      RETURN
      END