*"表題 第１次元の拡大 GTOOL3(GPXEXT)
*
*"履歴 91/01/19 沼口  敦
*
*
*********************************************************************
*"         << 第１次元の拡大 >>
*********************************************************************
      SUBROUTINE GPXEXT
     I         ( HHEAD , GDATA ,
     I           HAITMX, IXSTR , IXEND ,
     I           HEDIT , HETTL ,
     O           HHEADO, GDATAO )
*
      CHARACTER  HHEAD  ( * )*(*)        !" ヘッダー(入力)
      REAL       GDATA  ( * )            !" データ(入力)
      CHARACTER  HAITMX      *(*)        !" 拡大する第1次元の軸名
      INTEGER    IXSTR                   !" 第1次元の軸の格子始め
      INTEGER    IXEND                   !" 第1次元の軸の格子終り
      CHARACTER  HEDIT       *(*)        !" 編集略記号
      CHARACTER  HETTL       *(*)        !" 編集タイトル
      CHARACTER  HHEADO ( * )*(*)        !" ヘッダー(出力)
      REAL       GDATAO ( * )            !" データ(出力)
*
#ifdef SYS_IBMS
      INCLUDE    (GZSIZE)                !" NCC, NDC
#else
#include         "gzsize.F"              !" NCC, NDC
#endif
      CHARACTER  HEDITD      *(NCC)      !" 編集略記号
      CHARACTER  HETTLD      *(NCC)      !" 編集タイトル
*
*"         < 1. 結合準備 >
*
      CALL GPXCMI
     I         ( HHEAD , HAITMX, IXSTR , IXEND ,
     I           'NUL' , ' '   ,
     O           HHEADO, GDATAO )
*
*"         < 2. 大きさの取得 >
*
      CALL GUSMIS ( HHEADO )
*
      CALL GUQSIZ
     I         ( HHEADO,
     O           IXSTR1, IXEND1, IXDIM ,
     O           IYSTR , IYEND , IYDIM ,
     O           IZSTR , IZEND , IZDIM  )
*
*"         < 3. データ詰め替え >
*
      CALL GHPGET ( HHEAD, 'MISS', VMISS )
*
      DO 2100 IX = IXSTR1, IXEND1
            CALL VRSET
     I         ( GDATA                ,
     O           GDATAO( IX-IXSTR1+1 ),
     I           IYDIM*IZDIM, 1     , IXDIM  )
 2100 CONTINUE
*
*"         < 3. ヘッダー変更 >
*
      IF ( ( IXSTR1 .EQ. 1 ).AND.( IXEND1 .EQ. 1 ) ) RETURN
*
      IF      ( HEDIT .EQ. ' ' ) THEN
         CALL GUEAXN
     I               ( HAITMX, 'XE'   , '-extend',
     I                 IXSTR1, IXEND1 ,
     O                 HEDITD, HETTLD          )
         CALL GHEADD ( HHEADO, HEDITD, HETTLD )
      ELSE IF ( HEDIT .NE. 'NUL' ) THEN
         CALL GHEADD ( HHEADO, HEDIT  , HETTL   )
      ENDIF
*
      RETURN
      END
*********************************************************************
*"         << 第３次元の拡大 >>
*********************************************************************
      SUBROUTINE GMXEXT
     I         ( HHEAD , GDATA ,
     I           HAITMX, IXSTR , IXEND ,
     I           HEDIT , HETTL           )
*
      CHARACTER  HHEAD  ( * )*(*)        !" ヘッダー(入力)
      REAL       GDATA  ( * )            !" データ(入力)
      CHARACTER  HAITMX      *(*)        !" 拡大する第1次元の軸名
      INTEGER    IXSTR                   !" 第1次元の軸の格子始め
      INTEGER    IXEND                   !" 第1次元の軸の格子終り
      CHARACTER  HEDIT       *(*)        !" 編集略記号
      CHARACTER  HETTL       *(*)        !" 編集タイトル
*
      COMMON     /GMWORK/ GDATAW
      REAL       GDATAW ( 1 )            !" データ(ワーク)
#ifdef SYS_IBMS
      INCLUDE    (GZSIZE)                !" NCC, NDC
#else
#include         "gzsize.F"              !" NCC, NDC
#endif
      CHARACTER  HHEADW ( NDC )*(NCC)    !" ヘッダー(ワーク)
*
      CALL       GMCSIZ ( HHEADW )
      CALL       GPXEXT
     I         ( HHEAD , GDATA ,
     I           HAITMX, IXSTR , IXEND ,
     I           HEDIT , HETTL ,
     O           HHEADW, GDATAW )
*
      CALL       GPFSET
     I         ( HHEADW, GDATAW,
     I           ' '   , ' '   ,
     O           HHEAD , GDATA   )
*
      RETURN
      END