!
!= 変数の印字
!
! Authors::   Yasuhiro MORIKAWA, Eizi TOYODA
! Version::   $Id: gtvarputline.f90,v 1.5 2007/06/15 04:59:09 morikawa Exp $
! Tag Name::  $Name: gt4f90io-20070628 $
! Copyright:: Copyright (C) GFD Dennou Club, 2000-2005. All rights reserved.
! License::   See COPYRIGHT[link:../../COPYRIGHT]
!
! 以下のサブルーチン、関数は gtdata_generic から gtdata_generic#PutLine
! として提供されます。

subroutine GTVarPutLine(var, err)
  !
  !== 変数の印字
  !
  ! 変数 *var* の内容を出力します。
  !
  ! Get と書式つき WRITE 文をあわせたような機能で、
  ! 変数 *var* の内容を標準出力 (正確には * で識別される装置) 
  ! に印字します。
  !
  ! エラーが生じた場合、メッセージを出力
  ! してプログラムは強制終了します。*err* を与えてある場合には
  ! の引数に .true. が返り、プログラムは終了しません。
  !
  use gtdata_types, only: GT_VARIABLE
  use dc_error, only: ErrorCode, StoreError, GT_ENOMEM
  use dc_string, only: toChar, Printf
  use gtdata_generic, only: Get, Inquire
  use dc_trace, only: beginsub, endsub, DbgMessage
  implicit none
  type(GT_VARIABLE), intent(inout):: var
  logical, intent(out), optional:: err
  real, allocatable:: rvalue(:)
  integer:: siz, stat, i
  logical:: myerr
continue
  call beginsub('gtvarputline', '%d', i=(/var%mapid/))
  call Inquire(var, size=siz)
  call DbgMessage('size = %d', i=(/siz/))
  stat = 0
  allocate(rvalue(siz), stat=stat)
  if (stat /= 0) then
    stat = GT_ENOMEM
    goto 950
  endif
  call Get(var, rvalue, size(rvalue), err=myerr)
  if (myerr) then
    stat = ErrorCode()
    goto 950
  endif
  do, i = 1, size(rvalue)
    call Printf(fmt='%r', r=(/rvalue(i)/))
  end do
  deallocate(rvalue, stat=stat)
  if (stat /= 0) stat = GT_ENOMEM
  !
950 continue
  call StoreError(stat, "GTVarPutLine", err)
  call endsub('gtvarputline', '%d stat=%d', i=(/var%mapid, stat/))
end subroutine GTVarPutLine
