戻る|進む

DCL:ごくらくDCL:おまかせ二次元図

6.4 トーン付き等高線とベクトル場の重ね書き

最後にトーン付の等高線図とベクトル場を重ね書きした例を示します(U2D4). UGVECT, UDCNTR, UETONE のサブルーチンを順 に呼んでいます. ここでは, UESTLVルーチンでトーンをつけるレベルと パターンを指定しています. 

 
      PROGRAM U2D4 
 
      PARAMETER( NX=21, NY=21 ) 
      PARAMETER( XMIN=-10, XMAX=10, YMIN=-10, YMAX=10 ) 
      PARAMETER( KMAX=5, PMIN=0, PMAX=1 ) 
      REAL U(NX,NY), V(NX,NY), P(NX,NY) 
  
      DO 10 J=1,NY 
      DO 10 I=1,NX 
        X = XMIN + (XMAX-XMIN)*(I-1)/(NX-1) 
        Y = YMIN + (YMAX-YMIN)*(J-1)/(NY-1) 
        U(I,J) =  X 
        V(I,J) = -Y 
        P(I,J) = EXP( -X**2/64 -Y**2/25 ) 
   10 CONTINUE 

      WRITE(*,*) ' WORKSTATION ID (I)  ? ;' 
      CALL SGPWSN 
      READ (*,*) IWS 

      CALL GROPN( IWS ) 
      CALL SGLSET( 'LSOFTF', .TRUE. ) 
      CALL GRFRM 
 
      CALL GRSWND( XMIN, XMAX, YMIN, YMAX ) 
      CALL USPFIT 
      CALL GRSTRF 
 
      CALL USDAXS 
      CALL UGVECT( U, NX, V, NX, NX, NY ) 
      CALL UDCNTR( P, NX, NX, NY ) 
 
      DP = (PMAX-PMIN)/KMAX 
      DO 20 K=1,KMAX 
        TLEV1 = (K-1)*DP 
        TLEV2 = TLEV1 + DP 
        IPAT  = 600 + K - 1 
        CALL UESTLV( TLEV1, TLEV2, IPAT ) 
   20 CONTINUE 
 
      CALL UETONE( P, NX, NX, NY ) 
 
      CALL GRCLS 
 
      END
PROGRAM U2D4

\resizebox{10cm}{!}{\includegraphics{u2d/u2d4.eps}}
u2d4.f: frame1

戻る|進む

DCL:ごくらくDCL:おまかせ二次元図