dnl------------------------------------------------------------------
dnl      Copyright (C) GFD Dennou Club, 2005. All rights reserved.
dnl------------------------------------------------------------------
dnl
dnl= Definitions of Functions for configure
dnl
dnl  * Developers: Eizi TOYODA, Yasuhiro Morikawa
dnl  * Version: $Id: aclocal.m4,v 1.4 2005/06/21 17:00:05 morikawa Exp $
dnl  * Tag Name: $Name: gt4f90io-20050622 $
dnl  * Change History:
dnl
dnl== Overview
dnl
dnl  These functions are reflected to configure script by autoconf 2.13
dnl
dnl

#
#== DC_ARG_WITH(withname, description, varname, ifnot)
#
AC_DEFUN(DC_ARG_WITH, [
	AC_ARG_WITH($1, [  --with-$1=ARG: $2], [
		$3=$withval
	], [
		AC_CACHE_CHECK([$2], $3, [$4])
	])
])

#
#== DC_ARG_ENABLE(feature, description, varname, ifnot)
#
AC_DEFUN(DC_ARG_ENABLE, [
	AC_ARG_ENABLE($1, [  --enable-$1: $2], [
		$3=$enableval
	], [
		AC_CACHE_CHECK([$2], $3, [$4])
	])
])

############################################################
#== Set GT4DIR (current working directory)
#
# usage: DC_SET_GT4DIR
#
AC_DEFUN(DC_SET_GT4DIR,
[
#    AC_PATH_PROG(PWD, pwd)
    case "${PWD-}" in
        '')
            AC_MSG_WARN(*** WARN *** Please set environment variable GT4DIR by yourself)
            GT4DIR=
            ;;
        *)
            GT4DIR=${PWD-}
    esac
    AC_SUBST(GT4DIR)
])

############################################################
#== Check libfile and set LIBDIR and  LIBNAME
#
# Check existence of "libfile" file, and set LIBDIR, LIBNAME
# from "libfile".
#
# usage: DC_SET_LIBDIR_LIBNAME(libfile, LIBDIR, LIBNAME)
#
AC_DEFUN(DC_SET_LIBDIR_LIBNAME, [
	if test ! -f $1 ; then
		AC_MSG_ERROR(specified library file \"$1\" is not exist)
	fi

	$2=`dirname $1`
	$3=`basename $1 .a | sed 's/^lib//'`
])