[ English | Japanese ] [ Gt4f90io Reference Manual | Gt4f90io Tutorial ]

デバッグ補助

gt4f90io ライブラリには, デバッグ時の原因を追跡するサブルーチンを提供するモジュール dc_trace が用意され ています. これを用いるとデバッグ時のプログラムの追跡を比較的容易に 行うことが可能となります.

例として, Fortran 90/95 汎用モジュール: (2) メッセージの出力 で用いたサンプルプログラムに デバッグ出力を加えたプログラムを示します (ソースコードはこちら). 赤字(カラーがでない場合はボールド)が dc_trace に関係している箇所です.

!= Sample program for gt4_history/gt4f90io
!
! * 2007/06/27 M.Odaka
! * 2006/10/25 Y.Morikawa
! * 2003/08/21 M.Odaka
! * 2001/02/27 S.Takehiro
!
! Solving diffusion equation
! \[
!     du/dt = \kappa d^2 u/dx^2
! \]
! for giving values of $u$ at $x=[0,1]$.
!
program diffusion_6

  use gt4_history                                   ! Access module (モジュール指定)
  use dc_types, only : DP                           ! Access module (モジュール指定)
  use dc_message, only : MessageNotify              ! Access module (モジュール指定)
  use dc_trace, only : SetDebug, DbgMessage         ! Access module (モジュール指定)

  integer, parameter     :: nx=30                   ! Grid number (グリッド数)
  integer, parameter     :: nt=200                  ! Time step number (時間ステップ数)
  integer, parameter     :: ndisp=10                ! Output interval (出力間隔)
  real(DP), parameter    :: dx=1.0/(nx-1)           ! Grid interval (グリッド間隔)
  real(DP), parameter    :: dt=0.0005               ! Time step (時間間隔)
  real(DP), dimension(nx):: x=(/(dx*(i-1),i=1,nx)/) ! X coordinate (座標変数)
  real(DP), dimension(nx):: temp                    ! Temperature (温度)
  real(DP), parameter    :: kappa=1.0               ! Diffusion coefficient (熱拡散係数)
  real(DP)               :: sigma                   ! Parameter (計算安定条件パラメタ)

  call SetDebug                                     ! Debug mode on 
                                                    ! (デバッグモードオン)

  call DbgMessage(fmt="*** Debug Message [diffusion_6] *** Debug Message On")
                                                    ! Debug message dump 
                                                    ! (デバッグ出力)  

  tinit = 0.0                                       ! Set initial time 
                                                    ! (初期時刻設定)

  sigma = kappa*dt/dx**2.0d0

  if ( sigma >= 0.5d0 ) then
    call MessageNotify( "E", &                      ! Error mesage dump 
      &                 "diffusion_6", &            !(エラーメッセージ出力 )
      &                 "dt is too large: k*dt/(dx)^2 = %f", &
      &                  d=(/sigma/) )
  else if ( sigma >= 0.4d0 ) then
    call MessageNotify( "W", &                      ! Warning message dump
      &                 "diffusion_6", &            ! (警告メッセージ出力)
      &                 "dt is moderately large: k*dt/(dx)^2 = %f", &
      &                 d=(/sigma/) )
  else
    call MessageNotify( "M", &                      ! Message dump 
      &                 "diffusion_6", &            ! (メッセージ出力) 
      &                 "dt is sufficiently small: k*dt/(dx)^2 = %f", &
      &                  d=(/sigma/) )
  end if
    
  temp = exp(-((x-0.5)/0.1)**2)                     ! Set initial value 
                                                    ! (初期値設定)

  call HistoryCreate( &                             ! Create output file 
    & file='diffusion_6.nc', &                      ! (ヒストリー作成)
    & title='Diffusion equation',                        &
    & source='Sample program of gt4_history/gt4f90io',   &
    & institution='GFD_Dennou Club davis project',       &
    & dims=(/'x','t'/), dimsizes=(/nx,0/),               &
    & longnames=(/'X-coordinate','time        '/),       &
    & units=(/'m','s'/),                                 &
    & origin=real(tinit), interval=real(ndisp*dt) )

  call HistoryPut('x',x)                            ! Output 'x' (次元変数出力)

  call HistoryAddVariable( &                        ! Set output variable 
    & varname='temp', dims=(/'x','t'/), &           ! (変数定義)
    & longname='temperature', units='K', xtype='double')

  call HistoryAddAttr('temp','gt_graph_tick_all',1)
  call HistoryAddAttr('temp','gt_graph_contour_spacing',(/0.0,1.0,0.01/))
  call HistoryAddAttr('temp','+gt_user_davis_kappa',kappa)

  call HistoryPut('temp',temp)                      ! Output 'temp' (変数出力)

  
    call DbgMessage(fmt="*** Debug Message [diffusion_6] *** Begin time integration")
                                                    ! Debug message dump
                                                    ! (デバッグ出力) 
  
    do it=1,nt
  
      temp(2:nx-1) = temp(2:nx-1) &                 ! Time integration (時間積分)
        & + kappa*(temp(3:nx)-2*temp(2:nx-1)+temp(1:nx-2))/dx**2*dt
  
      if ( mod(it,ndisp) == 0 ) then
        call HistoryPut('temp',temp)                ! Output 'temp (変数出力)
      endif
  
      call DbgMessage(fmt="*** Debug Message [diffusion_6] *** it=%d, &
        &             i= (/it/) )               
                                                    ! Debug message dump
                                                    ! (デバッグ出力) 
  
    end do
  
    call DbgMessage(fmt="*** Debug Message [diffusion_6] *** End time integration")                           
                                                    ! Debug message dump
                                                    ! (デバッグ出力) 
  
  call HistoryClose
  
  stop
  end program diffusion_6
  

このプログラムでは, 時間積分ループ部分の前後とループ内にメッセージを出力 しています. メッセージは標準エラー出力に出力されます. 出力例は以下です. gt4f90io ライブラリの提供するサブルーチン内のデバッグ出力もオンになります.

#SetDebug: dbg = 0
#*** Debug Message [diffusion_5] *** Debug Message On
 *** WARNING [diffusion_6] ***  dt is moderately large: k*dt/(dx)^2 = 0.4205000231056476
#call HistoryCreate1 version=<$Name: gt4f90io-20080812 $$Id: dc_trace.rd,v 1.4 2007-08-31 05:13:19 odakker2 Exp $> : file=diffusion_6.nc ndims=2
#|-dims(:)=x, t, dimsizes(:)=30, 0, longnames(:)=X-coordinate, time, units(:)=m, s
#| call DCDateTimeCreate1 : current_time_used=<yes>
#| end DCDateTimeCreate1 : time (caltype=4, day=733253, sec=5976., zone=+09:00, day_seconds=86400.)
#| call DCDateTimeEval1
#| end DCDateTimeEval1
#| call GTVarCreateD version=<$Name: gt4f90io-20080812 $$Id: dc_trace.rd,v 1.4 2007-08-31 05:13:19 odakker2 Exp $> : url=<diffusion_6.nc@x> length=30
#| | call ANVarCreateD : url=<diffusion_6.nc@x>, xtype=<>, length=<30>
#| | | call ANFileOpen : writable=yes overwrite=yes file=diffusion_6.nc
 *** MESSAGE [ANFileOpen] ***  diffusion_6.nc is overwritten.
#| | | end ANFileOpen : id=4 stat=0
#| | |-anfiledefinemode 4
#| | |-an_vartable.add: added 1
#| | end ANVarCreateD : stat=0
#| |-[gt_variable 1: ndims=1, map.size=1]
#| |-[dim1 dimno=1 ofs=0 step=1 all=30 start=1 count=30 stride=1 url=]
#| |-[vartable 1: class=netcdf cid=1 ref=1]
#| |-[AN_VARIABLE(file=4, var=1, dim=1)]
#| end GTVarCreateD : class=netcdf mapid=1

以下では dc_trace モジュール サブルーチンが行っていることを大まかに説明します. ここで扱っていないサブルーチンの機能を含むより詳しい説明は リファレンスマニュアル を参照してください.

use dc_trace
モジュールの使用を宣言します. Fortran90 メインプログラムの先頭にいれ ましょう. ここでは only 文を用いて必要なブルーチンだけを参照します.
SetDebug
デバッグモードをオンにします. これにより, DbgMessage, BeginSub, EndSub などのサブルーチンが有効になります.
DbgMessage(fmt, [i], [r], [d], [L], [n], [c1], [c2], [c3], [ca])

SetDebug が call された場合に, 引数 fmt に与えられた文字列を 標準エラー出力に出力します. fmt 内に変数値を含めることもできます. その場合, オプション引数に対応する型の変数を指定します.

各引数の意味は以下の通りです.


$Id: dc_trace.rd,v 1.4 2007-08-31 05:13:19 odakker2 Exp $
gtool4 Development Group / GFD Dennou Staff dcstaff@gfd-dennou.org